Rekursive Methoden..Aufruf der Methode nicht möglich

[Jaro_E]

Folgendes Skript soll via einer rekursiven Methode mehrere Bitmaps laden.
Kann eine Funktion überhaupt mehr als eine Unterfunktion haben? Innerhalb der makeBitmap()-Funktion ist die loadCover() - Funktion (erste Unterfunktion, nicht verwechseln mit er loadCovers()) nicht aufrufbar.

PHP-Code:

public function loadCovers():void {
            
            covers = new Array();
            var i:Number = 0;
            
            function loadCover():void {
            
                if (i <= discographyXML.record.length()-1) {
                    
                    var loadCover:Loader = new Loader();
                    var url:URLRequest = new URLRequest(discographyXML.record[i].coverURL)
                    
                    loadCover.load(url);
                    loadCover.contentLoaderInfo.addEventListener(Event.COMPLETE, makeBitmap);
                    
                    function makeBitmap(evt:Event):void {
                        
                        var cover:Bitmap;
                        cover = Bitmap(loadCover.content); 
                        covers[i] = cover;
                        
                        loadCover();
                        trace("Bitmap loaded");
                    }
                }
                
                //GO ON
                else { buildRecords(); }
            }
        } 


BTW: In einem Buch steht folgender etwas seltsam anmutende Aufruf des Bitmap-Konstrukturs.

PHP-Code:

var cover:Bitmap;
cover = Bitmap(loadCover.content); 


Also ohne das Schlüsselwort "new". Es funktioniert auch tatsächlich so und mit "new" nicht. Was steckt da dahinter?

[pixelslave]

Zitat von Jaro_E

BTW: In einem Buch steht folgender etwas seltsam anmutende Aufruf des Bitmap-Konstrukturs.

PHP-Code:

var cover:Bitmap;
cover = Bitmap(loadCover.content); 


Also ohne das Schlüsselwort "new". Es funktioniert auch tatsächlich so und mit "new" nicht. Was steckt da dahinter?

Das was da dahinter steckt ist Typcasting. Da cover eine Instanz der Klasse Bitmap erwartet und loadCover.content womöglich eine Instanz einer anderen DisplayObject Klasse ist.

Grüße

Martin

[thomas_E]

Kann eine Funktion überhaupt mehr als eine Unterfunktion haben?

ja, kann sie, du solltest aber darauf verzichten, das zu nutzen.
Funktionen in Funktionen bereiten dir idr mehr Probleme, als sie lösen.

du legst es aber auch wirklich darauf an, dass Flash durcheinander kommt, oder:

PHP-Code:

function loadCover():void 
// darin:
var loadCover:Loader
// und noch eine Etage tiefer:
cover = Bitmap(loadCover.content); 
//sowie:
loadCover(); 


PHP-Code:

private var _todo:Array = [];
private var _coverLoader:Loader;

public function loadCovers():void 
{
    covers = [];
    for each(var record:XML in discographyXML.record){
        _todo.push(record.coverUrl.toString());
    }
    
    if(!_coverLoader){
        _coverLoader = new Loader();
        _coverLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, makeBitmap);
    }
    loadNextCover();
}

private function loadNextCover():void
{
    var url:String = _todo.shift();    //hole ersten Eintrag aus dem todo-Array
    if(url){
        _coverLoader.load(new URLRequest(url));
    }else{
        //keine url mehr in der todo-liste
        
        //der Loader wird nicht mehr benötigt
        _coverLoader.contentLoaderInfo.removeEventListener(Event.COMPLETE, makeBitmap);
        _coverLoader = null;
        
        buildRecords();
    }
}

private function makeBitmap(e:Event):void
{
    var cover:Bitmap = Bitmap(_coverLoader.content);
    covers.push(cover);
    trace("Bitmap loaded");
    loadNextCover();
}