Proportionale Größenänderung von geladenen Bildern

[magic_al]

Ich möchte Bilder von extern laden. Das klappt auch wunderbar. collection.php gibt dabei nen String zurück mit den ganzen Bildern die geladen werden sollen.

PHP-Code:

pictureLoader.dataFormat = URLLoaderDataFormat.VARIABLES
pictureLoader.load(new URLRequest("collection.php"))
pictureLoader.addEventListener(Event.COMPLETE, loadPicturesToArray)


function loadPictures(CollectionPictures)
{    
    for(var i:int=0; i<CollectionPictures.length; i++) {
        
        var pictureLoader:Loader = new Loader(); 
        var pictureUrlReq:URLRequest = new URLRequest(CollectionPictures[i]); 
        pictureLoader.load(pictureUrlReq); 
        
        pictureLoader.name = CollectionPictures[i];
        
        if(CollectionPictures.length>4) //if less than 4 pictures degreace the space
        {
            pictureLoader.x = 130*i;
        } else {
            pictureLoader.x = 400+130*i;
        }
        
        pictureLoader.y = 300;
        
        // add new event for every picture
        pictureLoader.addEventListener(MouseEvent.MOUSE_OVER,makeBigger);
        pictureLoader.addEventListener(MouseEvent.MOUSE_OUT,makeSmaller);
        pictureLoader.addEventListener(MouseEvent.CLICK,showBigPicture);
        
        collectionSlideshow.addChild(pictureLoader); // load picture on stage
        
        collectionSlideshow.getChildByName(CollectionPictures[i]).scaleY = .5;
        collectionSlideshow.getChildByName(CollectionPictures[i]).scaleX = .5;
        collectionSlideshow.getChildByName(CollectionPictures[i]).alpha = .5;
    }
} 


Ich würde jetzt gerne jedem Bild einen bestimmten Instance-Name zuweisen um den später weiter zu verwenden. Dafür muss ich das Bild ja in ein MC umwandeln. Geht das und wenn ja, wie? Oder würde man dafür besser einen MC designen und das Bild in eine Instance von diesem MC laden?

Danke!

[Martin Kraft]

Zitat von magic_al

Ich würde jetzt gerne jedem Bild einen bestimmten Instance-Name zuweisen um den später weiter zu verwenden. Dafür muss ich das Bild ja in ein MC umwandeln. Geht das und wenn ja, wie?

Nein, das geht nicht (MovieClips und Loader bzw. Bitmaps sind nicht kompatibel)! Das ist aber auch garnicht nötig, weil MCs (genauso wie Instanznamen und getChildByName) in diesem Fall genauso wie 99% aller Fälle in AS3 unnötig sind.

Das geladene Bild (pictureLoader.content) bzw. die Loader-Instanz (pictureLoader), mit der du es lädst, sind doch bereits Referenzen. Mit diesen kannst Du arbeiten:

pictureLoader.scaleY = .5;
pictureLoader.scaleX = .5;
pictureLoader.alpha = .5; 

Und sie zur späteren Verwendung direkt in ein Array schreiben:

var pictures:Array = [];
 
// In Deiner Schleife:
pictures.push(pictureLoader); 

P.S.: Methoden- und Variablennamen sollten in AS3 immer mit einem Kleinbuchstaben anfangen. Große Anfangsbuchstaben sind den Klassen vorbehalten.

Zudem sollten Variablen und Funktionen immer typisiert werden. Also:

function loadPictures( collectionPictures:Array ):void  {
//... 
 

[magic_al]

Danke für die Antwort, hat mir sehr geholfen.

[magic_al]

Ich habe folgenden Code um Bilder auf meine Stage zu laden:

PHP-Code:

for (var i:int = 0; i<galleryXML.IMAGE.length(); i++){
                
                pictureLoader = new Loader(); 
                pictureUrlReq = new URLRequest(galleryXML.IMAGE[i].URL); 
                pictureLoader.load(pictureUrlReq); 
                pictureLoader.name = galleryXML.IMAGE[i].URL;
                pictureLoader.x = addPictureToX;
                addPictureToX = addPictureToX + 10 + Number(galleryXML.IMAGE[i].WIDTH);
                
                sec_gallery_slide.addChild(pictureLoader); // load picture on stage
                
            }; 


Ich würde jetzt gerne jedes Bild was rein geladen wird verkleinern.

pictureLoader.width und height funktionieren beide nicht bei mir. Mit ScaleX und ScaleY kann ich nur relative angaben machen. Das Problem ist, dass die Bilder alle unterschiedliche groß sind.

Ich möchte jetzt, dass alle Bilder, auf eine Höhe von 150 Pixel scaliert werden und die Breite proportional dazu angepasst wird. Gibt es da einen einfachen Weg?

[hgseib]

// zuerst das event abwarten, das dir meldet, dass das bild komplett geladen wurde,
// danach die gewünschte breite setzen
xxx.width = 150;
// die dazu passende höhe hat die selbe scalierung wie die breite
xxx.scaleY = xxx.scaleX;

// bzw. natürlich
xxx.height = 150;
xxx.scaleX = xxx.scaleY;

[magic_al]

Danke, das ist genau das was ich brauche. Ich habe den complete Event jetzt so eingerichtet:

PHP-Code:

pictureLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, adjustChild); 


Ich weiß aber nicht, wie ich in adjustChild() auf das entsprechende Child zugreifen kann.

PHP-Code:

getChildByName(pictureLoader.name) 


Gibt mir einen Fehler aus, dass der Wert nicht existiert, wobei ich vor dem Laden die name-Eigenschaft mit

PHP-Code:

pictureLoader.name = galleryXML.IMAGE[i].URL; 


gesetzt habe.

Wie handel ich das?

[milchreis]

Die Funktion erhält einen Parameter, der ein Event Objekt ist, dieses kennt den ".target" also Auslöser des Events.

[hgseib]

Zitat von magic_al

Ich weiß aber nicht, wie ich in adjustChild() auf das entsprechende Child zugreifen kann.

und ich weiss nicht, warum du das möchtest ;-)
die referenz auf deinen loader heisst pictureLoader - fertig. mit namen arbeitet man möglichst garnicht und wohin du deinen loader zur ansicht add'est ist erstmal wurscht.

zur programmierung allgemein:
immer ein auge in der flash-hilfe lassen. die ist beim programm dabei und im internet
flash.display.Loader - ActionScript® 3.0 Referenzhandbuch für die Adobe® Flash®-Plattform
da hat's auch immer beispiele dabei, an denen man sich ganz gut orientieren kann.



nur am rande, auf die bühnenobjekte greift man z.b. so zu (wenn man die referenzen nicht mehr hat):
sec_gallery_slide.addChild(pictureLoader);
trace(sec_gallery_slide.numChildren); // wieviele bühnenobjekte gibt es in sec_gallery_slide
trace(sec_gallery_slide.getChildAt(0)); // das wäre dann das unterste in sec_gallery_slide
usw.

pictureLoader.name="fritz";
// du kannst dem kind einen namen geben und danach den namen auch wieder auslesen, aber wozu? du hast die referenz auf das objekt!
// du versuchst das url als einen namen zu verwenden. mit all den sonderzeichen könnte das problematisch sein .. und nochmal, ist vollkommen unnötig.

xxx.getChildByName( pictureLoader.name );
// bei welchem xxx-bühnenobjekt fragst du nach einem objekt mit diesem namen nach?
// wegen
sec_gallery_slide.addChild( pictureLoader );
// sollte gehen
sec_gallery_slide.getChildByName( pictureLoader.name );
// und das ist - wie wir inzwischen alle wissen - niemand anderes als: pictureLoader :-)



private var pictureLoader:Loader;
..
pictureLoader.addEventListener(Event.COMPLETE, completeHandler); // lass contentLoaderInfo weg

private function completeHandler(event:Event):void {
var loader:Loader = Loader(event.target);
trace(event.target);
trace(loader); // wenn mehrere loader die selbe function benützen, dann den event auslösenden loader nehmen
trace(pictureLoader); // andernfalls diese referenz gilt in deiner kompletten klasse, also geht's hier natürlich auch noch
..
// und wichtig!! alle events müssen auch wieder entfernt werden. sonst wächst der speicherbedarf immer mehr.
pictureLoader.removeEventListener(Event.COMPLETE, completeHandler);

[Martin Kraft]

Ich muss hgseib an 2 Stellen korrigieren:

Zitat von hgseib

die referenz auf deinen loader heisst pictureLoader - fertig. mit namen arbeitet man möglichst garnicht und wohin du deinen loader zur ansicht add'est ist erstmal wurscht.

Da pictureLoader aber in dieser Schleife mehrfach überschrieben wird, dürfte man damit bei Event.COMPLETE nicht mehr viel anfangen können...

Nein, in diesem Fall ist man darauf angewiesen die Referenz auf den Loader aus dem Event zu rekonstruieren:[AS]var loader:Loader =

Zitat von hgseib

private var pictureLoader:Loader;
..
pictureLoader.addEventListener(Event.COMPLETE, completeHandler); // lass contentLoaderInfo weg

Nein. contentLoaderInfo ist hier notwendig, da Event.COMPLETE eben von der LoaderInfo-Instanz ausgelöst wird und nicht vom Loader selbst:

pictureLoader.addEventListener(Event.COMPLETE, completeHandler);
 
//...
 
function completeHandler(e:Event):void {
   var loader:Loader = LoaderInfo(e.target).loader;
   //...
} 

@magic_al:
Ich werde Diesen Thread mal mit Deinem letzten zusammenfassen, da es ja im Grunde noch um dasselbe Problem geht, und würde Dich bitte das in Zukunft genauso zu handhaben und nicht für jeden Aspekt einen neuen Thread aufzumachen - Danke!

[magic_al]

Danke an alle für die Antworten!

Martin mit deinem Code hats dann super geklappt, verstanden hab ichs auch. Danke.

[magic_al]

PHP-Code:

public function adjustChild(event:Event):void {
            
            var loader:Loader = LoaderInfo(event.target).loader;
} 


Wie kann ich jetzt die x und y Eigenschaften von meinem loader auslesen. Ich kann mir zwar loader.name ausgeben lassen. aber loader.x oder y ist immer 0.GetChildByName gibt einen Fehler.

[Martin Kraft]

Zeig mal den kompletten Code!

[magic_al]

PHP-Code:

package com.abubu {
    
    import flash.display.*;
    import flash.events.*; 
    import flash.net.*;
    import fl.transitions.*;
    
    public class sec_gallery extends flash.display.MovieClip {

        public function sec_gallery() {
            
        
            galleryXMLLoader.load(new URLRequest(galleryXMLURL));
            galleryXMLLoader.addEventListener(Event.COMPLETE, loadXML);
            
        }
        
        public var galleryXML:XML;
        public var galleryXMLLoader:URLLoader = new URLLoader();
        public var galleryXMLURL:String = "http://localhost/xml_collection.php";
        
        public var speed:Number;
        public var pictureLoader:Loader;
        public var pictureUrlReq:URLRequest;
        public var addPictureToX:Number = 0;
        public var letztesBildIstGeladen:Boolean = false;
        
        private function loadXML(event:Event):void {
            
            galleryXML = new XML(event.target.data);
            
            //bilder in slide laden
            for (var i:int = 0; i<galleryXML.IMAGE.length(); i++){
                
                pictureLoader = new Loader(); 
                pictureUrlReq = new URLRequest(galleryXML.IMAGE[i].URL); 
                pictureLoader.load(pictureUrlReq); 
                pictureLoader.name = String(i);

                pictureLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, adjustChild);
                
                sec_gallery_slide.addChild(pictureLoader);

            }
            
        }
        
        public function adjustChild(event:Event):void {
            
            var loader:Loader = LoaderInfo(event.target).loader;
        
        }
        

// ab hier ist ein scroll effekt eingefügt, der mit dem eigentlichen laden der bilder nichts zu tun hat.
    
        public function scrollEvent(evt:Event):void {
            
            if(mouseX<200){
                speed = (200 - mouseX)/10
            } else if(mouseX>700){
                speed = -1*(mouseX - 700)/10
            } else {
                speed = 0;
            }
            
            sec_gallery_slide.x += speed;
            if(sec_gallery_slide.x>50){
                sec_gallery_slide.x = 50;
            } else if(sec_gallery_slide.x< (stage.stageWidth - sec_gallery_slide.width - 50 )){
                sec_gallery_slide.x = (stage.stageWidth - sec_gallery_slide.width - 50)
            }
            
        }
                        
    }
    
} 


[Martin Kraft]

• Zitat von magic_al

  Wie kann ich jetzt die x und y Eigenschaften von meinem loader auslesen. Ich kann mir zwar loader.name ausgeben lassen. aber loader.x oder y ist immer 0.

  Logisch. Wenn Du x und y nicht auf andere Werte setzt, bleiben sie auf dem Standardwert 0 sein!
  
  

• Zitat von magic_al

  GetChildByName gibt einen Fehler.

  Mal abgesehen davon, dass man diese Methode (aus den oben genannten Gründen) eh nur in Ausnahmefällen verwenden sollte:
  Ihr Name beginnt zum einen einen kleinen Anfangsbuchstaben und zum anderen gibt es diese Methode nur bei DisplayObjectContaineren...
  
  Wo hast Du getChildByName denn wie (und warum) angewandt und welche Fehlermeldung hast Du bekommen?
  Fehlermeldungen sind zum lesen da!
  
  
• Wo deklarierst Du eigentlich sec_gallery_slide?
  
  
• Du solltest Dich mal mit den Coding Conventions beschäftigen! Wenn man die einhält, wird es wesentlich einfacher für andere den Code zu lesen. Darin steht dann z.B. dass Klassennamen immer mit einem Großbuchstaben beginnen und camelCased geschrieben werden sollten. _s gibt es eigentlich nur in KONSTANTEN_NAMEN.