PropertyChanged-Event wird nicht ausgelöst

[Lector]

Hallo,

Ich habe in meiner Model-Klasse viele Daten-Properties, welche alle Bindable sind. Die meisten davon haben getter und setter und sind mit [Bindable] deklariert. Bei diesen Properties funktioniert auch alles. Einige Properties, welche von anderen Werten abhängen, haben jedoch nur einen getter:

[Bindable("shapeChanged")]
public function get shape():String
{
	return ...;
}

Wenn sich dieses Property dann ändert gebe ich das über folgenden Code bekannt:

dispatchEvent(new PropertyChangeEvent("shapeChanged",
	false, false, PropertyChangeEventKind.UPDATE, 
	"shape", null, shape, this));

Wenn ich in MXML ein Binding auf ein soches Property mache aktualisiert sich die GUI automatisch. Wenn ich jedoch ein PropertyChangedEvent im Code auf ein Objekt registriere bekomme ich nur die Eigenschaftsänderungen mit bei denen es getter UND setter gibt. Die Variante in dem Beispielcode feuert hier kein Event. Was mache ich falsch?

[Omega Psi]

Die ganze Klasse oder zumindest mehr Code bitte.

[Lector]

Alles kann ich leider nicht posten da dies den Rahmen sprengen würde (~1000 Zeilen)
Hier ein relevanter Ausschnitt aus der Datenklasse:

public class ImageItem extends ItemBase implements IShaped //Leitet indirekt von EventDispatcher ab
{
        private var _imageShape:ImageShape;

	[Bindable]
	public function get imageShape():ImageShape
	{
		return _imageShape;
	}
	public function set imageShape(value:ImageShape):void
	{
		if(imageShape != null)
		{
			imageShape.removeEventListener(PropertyChangeEvent.PROPERTY_CHANGE, imageShape_PropertyChanged);
		}
		_imageShape = value;
		if(imageShape != null)
		{
			imageShape.addEventListener(PropertyChangeEvent.PROPERTY_CHANGE, imageShape_PropertyChanged);
		}
		notifyShapeChanged();
	}
	
	[Bindable("shapeChanged")]
	public function get shape():String
	{
		return _imageShape.normalizedPathData;
	}
	
	private function notifyShapeChanged():void
	{
		dispatchEvent(new PropertyChangeEvent("shapeChanged",
			false, false, PropertyChangeEventKind.UPDATE, 
			"shape", null, shape, this));
	}
	private function imageShape_PropertyChanged(e:PropertyChangeEvent):void
	{
		if(e.property == "normalizedPathData")
			notifyShapeChanged();
	}
}

Nun würde ich von ausserhalb dieser Klasse gerne mitbekommen wenn sich die Eigenschaft 'shape' ändert. Dadurch dass ich in der Funktion notifyShapeChanged dispatchEvent aufrufe sollte dies ja eigendlich kein Problem sein. Wenn in im MXML ein Binding auf diese Eigenschaft mache aktualisiert sich auch alles richtig. Folgender Code scheint aber nicht zu funktionieren:

private var _shaped:IShaped; //Es handelt sich im Beispielszenario um ein ImageItem

private function register():void
{
	_shaped.addEventListener(PropertyChangeEvent.PROPERTY_CHANGE, shaped_PropertyChanged);
}

private function shaped_PropertyChanged(e:PropertyChangeEvent):void
{
	trace(e.property);
}

Wenn ich mein Programm laufen lasse und sich der Shape ändert sehe ich in der Ausgabe dass sich 'imageShape' ändert. Von der Eigenschaft 'shape' fehlt allerdings jede Spur. Die notifyShapeChanged-Methode wird ausgeführt. Das habe ich im Debugger überprüft. Außerdem habe ich in der GUI Bindings an diese Eigenschaft gemacht und dort funktioniert auch alles. Es befinden sich in der ImageItem-Klasse noch mehrere Eigenschaften bei denen nicht das Standard-[Bindable] angegeben ist sondern die ausführliche Variante ohne Setter mit manuellen dispatchEvent. Bei all diesen Eigenschaften scheine ich über den Beispielcode weiter oben keine Änderung mitzubekommen obwohl die MXML-GUI keine Probleme damit hat. Ich hoffe dass mein Problem durch den Beispielcode jetzt ersichtlich ist. Was mache ich falsch?

[Omega Psi]

Eventhandler die an imageShape gebunden werden, hören nur auf PropertyChangeEvent.PROPERTY_CHANGE. Dich interessiert aber denke ich ja shapeChanged. Das bedeutet eine Anpassung á la

[Bindable("shapeChanged")]
public function get imageShape():ImageShape
{
  return _imageShape;
}

sollte es für den Fall tun.

[Lector]

Aber die Eigenschaft 'imageShape' kann ich doch ohne Probleme per PropertyChangeEvent überwachen. Das Problem tritt bei der Eigenschaft 'shape' auf bei der das PropertyChangeEvent nicht zu funktionieren scheint.

[Omega Psi]

Ich hab mal ein einfaches Beispiel zusammen geschraubt.

package net.icodeapps.examples.model
{
  import flash.events.Event;
  import flash.events.EventDispatcher;

  public class Person extends EventDispatcher
  {
    //---------------------------------------------------------------------
    //
    //          Properties
    //
    //---------------------------------------------------------------------

    //-----------------------------
    //          firstName
    //-----------------------------

    private var _firstName:String;

    [Bindable('firstNameChange')]
    public function get firstName():String
    {
      return _firstName;
    }

    public function set firstName(value:String):void
    {
      if (_firstName == value)
      {
        return
      }
      _firstName = value  || '';
      invalidateFullName();
      dispatchEvent(new Event('firstNameChange'));
    }

    //-----------------------------
    //          fullName
    //-----------------------------

    [Bindable('fullNameChanged')]
    public function get fullName():String
    {
      return _firstName + ' ' + _lastName
    }

    //-----------------------------
    //          lastName
    //-----------------------------

    private var _lastName:String;

    [Bindable('lastNameChange')]
    public function get lastName():String
    {
      return _lastName;
    }

    public function set lastName(value:String):void
    {
      if (_lastName == value)
      {
        return
      }
      _lastName = value  || '';
      invalidateFullName();
      dispatchEvent(new Event('lastNameChange'));
    }

    //---------------------------------------------------------------------
    //
    //          Constructor
    //
    //---------------------------------------------------------------------

    public function Person()
    {
      _firstName = _lastName = '';
    }

    //---------------------------------------------------------------------
    //
    //          Methods
    //
    //---------------------------------------------------------------------

    private function invalidateFullName():void
    {
      dispatchEvent(new Event('fullNameChanged'));
    }
  }
}

Das war der Gedankengang, den ich illustrieren wollte.

[Lector]

Ich habe jetzt herausgefunden an was es lag. Beim Feuern des Events benutze ich "shapeChanged". Später registriere ich mich dann allerdings nicht auf "shapeChanged" sondern auf "propertyChanged". Trotzdem danke für dein Beispiel.
Ist es eigentlich sauberer für solche Events "shapeChanged" zu benutzen oder wie bei den Default-Bindable "propertyChanged"?

[Omega Psi]

Siehe meinen Post#4