parent / root

[4DD]

Guten Tag,

ich hab ein problem mit meinem Flash-Projekt:

ich habe eine SWF, in die eine zweite SWF hineingeladen wird. In der zweiten SWF ist nun ein Button, der die Mutter-SWF ansprechen soll (ein klassischer Zurück-Button halt). Dieses funktioniert nicht so richtig:

btnzurueck.addEventListener(
  MouseEvent.MOUSE_DOWN,
  function(evt:MouseEvent):void {
  MovieClip(parent.root).gotoAndPlay(15);
 }
  )

Das funktioniert, allerdings nur lokal (wenn ich die SWF aufrufe, nicht in eine HTML site eingebunden). Online tut es nix. Kann mir einer hierzu Hilfe geben? Das root würde ich eigentlich gerne vermeiden, aber mit this.parent.parent tut es auch nicht.

Danke schonmal im Vorraus

[Martin Kraft]

• Liegen die SWFs beide online und auf demselben Server?
• Hast Du Dir mal traceb lassen worauf parent und root zeigen?
• Kann man sich das irgendwo online ansehn?

• Das parent vor dem root ist übrigens überflüssig. Wenn parent mit root verbunden ist, ist es das Objekt selbst auch!
• Sollte Aufwärtszugriffe aus nachgeladen SWFs (insbesondere über eine globale Referenz wie root) sollte man übrigens vermeiden! Stattdessen empfielt es sich in der 'UnterSWF' eine Event zu dispatchen, auf das man in der 'HauptSWF' einen Listener registriert, der dann die gewünschten Aktionen ausführt!

[4DD]

Danke für die Antwort, hab ich gemacht, aber funktioniert wieder nur offline, nicht online.

Hauptfilm:

addEventListener("ButtonKlick", buttonEvent);  
function buttonEvent(e:Event):void { 
    this.gotoAndPlay(15); 
}

Geladene SWF

btnzurueck.addEventListener(
  MouseEvent.MOUSE_DOWN,
  function(evt:MouseEvent):void {
  dispatchEvent(new Event("ButtonKlick", true, true)); 
 }
  )

[Martin Kraft]

Du musst den Listener natürlich bei dem Anzeigeobjekt registrieren, in dem Du später auch das Event dispatchst. In diesem Fall ist das wahrscheinlich:

deinLoader.content.addEventListener(... 

P.S.: Beantworte mal meine Fragen von oben!

[4DD]

Die SWFs sind beide online und auf dem selben Server.

Wenn ich es registriere erhalte ich den Fehler #1009: Der Zugriff auf eine Eigenschaft oder eine Methode eines null-Objektverweises ist nicht möglich.

var request:URLRequest=new URLRequest("swf/serie11.swf");
var loader:Loader = new Loader();
loader.content.addEventListener("buttonKlick", buttonEvent);
loader.load(request);
addChild(loader);
swapChildren(loader, swapper);
loader.x=290;
loader.y=-218;



function buttonEvent(evt:Event):void { 
    this.gotoAndPlay(15); 
}

Online Angucken kann ich dir bei bedarf per PM schicken.
Bin leider nicht so firm in AS3, daher bitte ich um verständnis.

[4DD]

Habs gelöst, vielen Dank nochmal für deine Hilfe.

[Martin Kraft]

Zitat von 4DD

Wenn ich es registriere erhalte ich den Fehler #1009: Der Zugriff auf eine Eigenschaft oder eine Methode eines null-Objektverweises ist nicht möglich.

Klar, wäre ja auch ziemlich unlogisch, wenn man auf etwas zugreifen könnte, was noch garnicht geladen wurde Versuch's mal so:

Haupt-SWF:

import flash.display.Loader;
import flash.events.Event;
import flash.net.URLRequest;
 
var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.INIT, initLoaderContent);
loader.load(new URLRequest("swf/serie11.swf"));
 
function initLoaderContent(e:Event):void {
    trace(loader+" inited, content "+loader.content);
    loader.content.addEventListener("buttonClick", handleButtonClick);
    
    addChildAt(loader, getChildIndex(swapper));
    loader.x = 290;
    
    loader.y = -218;    
}
 
function handleButtonClick(evt:Event):void {
    trace("button was clicked");
    gotoAndPlay(15); 
} 

Nachgeladene SWF:

import flash.events.Event;
import flash.events.MouseEvent;
 
btnzurueck.addEventListener(MouseEvent.CLICK, handleBtnzurueckClicked);
 
function handleBtnzurueckClicked(e:MouseEvent):void {
    dispatchEvent(new Event("buttonClick", true, true));
} 

Und immer auf die Groß-Klein-Schreibungachten

Zitat von 4DD

Online Angucken kann ich dir bei bedarf per PM schicken.

Mach das.