Papervision3D: einfaches Beispiel mit Material erzeugt unerwarteten Output

[unique23]

Hallo zusammen,

ich hatte schon unter Sorftware > 3D gepostet, aber das war wohl der Falsche Ort, daher ein erneuter Versuch ;-)

Ich arbeite mich gerade durch das Papervision3D Essentials Buch und in auf Seite 99 bei Movie Materials angekommen.
Leider wird mir sobald ich den Film exportiere das Material doppelt angezeigt. Einmal mit der Position 0,0 und ein zweites mal wird das Material auf das Shape gelegt, so wie gewünscht.

Hier ist der Screenshot
.

package 
{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.text.TextField;
	import flash.text.TextFormat;
	import flash.text.TextFieldAutoSize;

	import org.papervision3d.objects.primitives.Plane;
	import org.papervision3d.view.BasicView;
	import org.papervision3d.materials.MovieMaterial;

	public class SmartHome extends BasicView
	{

		private var plane:Plane;

		public function SmartHome()
		{
			stage.frameRate = 40;
			viewport.interactive = true;

			init();
			startRendering();

		}
		private function init():void
		{
			var materialSprite:Sprite = new Sprite();
			materialSprite.graphics.beginFill(0xebebeb);
			materialSprite.graphics.drawRect(0,0,200,200);
			
			var textfield:TextField = new TextField();
			textfield.text = "Hello 3d world";
			textfield.autoSize = TextFieldAutoSize.LEFT;
			textfield.setTextFormat(new TextFormat("Arial", 25));
			textfield.x = (materialSprite.width - textfield.width/2);
			textfield.y = (materialSprite.height - textfield.height/2);
			
			materialSprite.addChild(textfield);
			addChild(materialSprite);
			
			var material:MovieMaterial = new MovieMaterial(materialSprite);
			material.smooth = true;
			material.doubleSided = true;
			
			plane = new Plane(material);
			scene.addChild(plane);

		}
		override protected function onRenderTick(e:Event=null):void
		{
			plane.localRotationY++;
			super.onRenderTick();
		}
	}

}

Kann mir jemand den Output erklären?
Oder weiß was ich falsch gemacht habe?

Besten Dank und schöne Grüße!

[padavan]

addChild ist überflüssig - denn das bringt dir das bild auf die Bühne - aber du brauchst es ja nur im Material

[unique23]

Danke, vor lauter addChilds habe ich das komplett übersehen.
Danke nochmals!