Netstream time

[Nico B.]

Hi,

ich bräuchte mal kurz Hilfe bei der time Eigenschaft des Netstreams...

Meine Funktion ist

public function changePath( path:String ):void
        {
            // Saves the current Position
            var currentPos:Number = this._ns.time;
            // Kill current NetStream
            this._ns.removeEventListener(NetStatusEvent.NET_STATUS, onNetStatus);
            this._ns.close();
            this._ns = null;
            
            
            
            this._ns = new NetStream( this._nc );   
            this.attachNetStream( this._ns );
            // init new netstream
            this._ns.addEventListener(NetStatusEvent.NET_STATUS, onNetStatus);  
            this._ns.play( path );
            this._ns.seek(currentPos);
        } 

Das Problem ist, dass das Ganze nur beim 1. funktioniert... die "time" Eigenschaft ist dann immer wieder fast gleich, sodass das Video immer dahin zurück springt, wo ich e sbeim ersten Mal geändert habe... Jemand eine Idee?

[andrelehnert]

Hallo Nico,

ich denke, es liegt daran, daß die time des alten videos u.U. größer ist,
als die bereits vorgeladene Zeit des neuen Videos. Dann kannst Du den Zeitpunkt/Frame noch nicht anspringen -
umständlich gesagt, aber du verstehst was ich meine?

Du müßtest die bufferTime üfr das neue Video mindestens so hoch setzen wie die anzuspringende Zeit und wenn dann der Buffer voll ist (netStatus.-Event) die Zielzeit anspringen.

LG ANdré

[Nico B.]

Hi,

ich weiß, wie Du das meinst, haste da evtl. nen Code Beispiel zu? Bin mir da gerade nicht ganz sicher vom Ablauf her.

[andrelehnert]

SRY, hab keine Zeit - heute abend aber, da mach ich ein Bsp fertig, falls das Problem noch besteht -

LG ANdré

[Nico B.]

Ja wäre super - besteht nämlich noch... :/

Hätte jetzt die buffertime per hand auf den Wert des alten Videos gesetzt, dami er so lange wartet, wie er springen muss. ABer klappen tut das leider nicht^^

[andrelehnert]

hi, hatte viel zu tun...

ALso hier mal ein Ansatz:

PHP-Code:

const VIDEO_PATH:String = "videos/";
var videoUrls:Array=["vid1.flv","vid2.f4v","vid3.flv","vid4.f4v"];
var currentVideo:int=-1;
var globalVideoTime:Number = 0;
var isBuffering:Boolean = true;

var cont:Sprite = new Sprite();
var vid:Video = new Video();
var nc:NetConnection = new NetConnection(); 
nc.connect(null);

var ns:NetStream = new NetStream(nc); 

vid.attachNetStream(ns); 
cont.addChild(vid);
addChild(cont);

var statusText:TextField = new TextField();
statusText.background=0xffffff;
statusText.multiline=false;
statusText.height=20;
addChild(statusText);

ns.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
ns.addEventListener("netStatus",netStatusHandler);
cont.addEventListener(MouseEvent.CLICK, nextVideo);
addEventListener(Event.ENTER_FRAME, updateVideoStatus);
function asyncErrorHandler(event:AsyncErrorEvent):void 
{ 
    // Mach nüscht!
}
function updateVideoStatus(e:Event):void{
    statusText.htmlText = ns.time.toString();    
}
function netStatusHandler(e:NetStatusEvent):void{
  switch (e.info.code){
    case "NetStream.Play.Start":
        trace("netstream started to play");
        isBuffering=true;
    break;
    case "NetStream.Buffer.Full":
        trace("netstream buffer full");
        if(isBuffering){
            ns.seek(globalVideoTime);
            isBuffering=false;
        };
    break;
  } 
}
function nextVideo(e:MouseEvent = null):void{
    globalVideoTime = ns.time;
    currentVideo += currentVideo<videoUrls.length-1 ? 1 : -currentVideo;
    ns.bufferTime = globalVideoTime;    
    ns.play(VIDEO_PATH + videoUrls[currentVideo]);
}

nextVideo(); 


Beim Klick aufs Video lädt das nächste. Dafür setzte ich die buffertime so hoch,
wie weit das alte Video bereits gespielt war und merke mir die aktuelle Zeit. Wenn der Buffer dann voll ist, führe ich ein seek() auf den zuvor abgespeicherten Zeitpunkt aus.

Das Beispiel verdeutlicht nur das Prinzip. Fallen sind noch:

• Ungleich lange videos
• unterschiedliche frameraten
• unterschiedliche Bitraten
• ...

Wenn Du red5 oder FMS verwendest, kannst Du den Stream ab dem konkreten Zeitpunkt anfordern,
sprich: dann würde man das einfacher lösen können.

Was genau hast Du vor? Wie groß sind die Videodateien?

Wenn es zum Beispiel um unterschiedliche Perspektiven ein und derselben Szenerie ginge und es sich um kleine Videos handelte,
könnte man vllt sogar alle videos übereinander parallel abspielen und mit visible das benötigte sichtbar machen und den Rest verbergen...

LG ANdré

[Nico B.]

Hi,

danke für Dein Beispiel! Werd es wohl erst morgen testen können...


Es geht darum, dass ich eine Anwendung baue, in der mehrere Videos vorhanden sind. Jetzt soll man zwischen 3 Qualitäten wechseln können - daher das neuladen der Videos an der gleichen Stelle.

[andrelehnert]

dann scheidet die Variante mit dem Übereinanderlegen auf jeden Fall aus.

Beim FMS oder red5 wäre die dynamische Bandbreitenwahl auch schon integriert...

LG ANdré

[Nico B.]

Hi,

danke für den TIpp.


Ist nur ne Kleinigkeit auf einer Website, ein extra Server für die Videos wäre also etwas to much.

Evtl. werde ich das Ding dann eben einfach neustarten lassen. Mal sehen was das morgen gibt ... ;-)


dange