MovieClip zeigt Inhalt nicht an?

[Revoluzifer]

Hi, ich habe gerade ein eigenartiges Problem, das ich so garnicht nachvollziehen kann, stehe wahrscheinlich irgendwo auf dem Schlauch...
Zunächst mein Code:

Zunächst aus der .fla:

import level.*;

const LVL_WIDTH:int = 800;
const LVL_HEIGHT:int = 600;

var lvl_1_01:LevelContainer = new LevelContainer("images/lila.jpg", LVL_WIDTH, LVL_HEIGHT, 0);
lvl_1_01.addEventListener("LOADING_COMPLETED", ready);

function ready(e:Event):void {
	trace("loaded");
	addChild(lvl_1_01);
}

Und hier aus meiner AS-Klasse:

package level {
	
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.display.Loader;
	import flash.net.URLRequest;
	
	public class LevelContainer extends MovieClip {
		private var index:int;
		
		private var loader:Loader;
		private var req:URLRequest;
		
		public function LevelContainer(url:String, w:int, h:int, positionIndex:int = 0) {
			index = positionIndex;
			width = w;
			height = h;
			y = 0;
			x = index * width;
			loader = new Loader();
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completed);
			req = new URLRequest(url);
			loader.load(req);
			//addEventListener(Event.ENTER_FRAME, update);
		}
		
		private function update(e:Event):void {
			//update position...
		}
		
		private function completed(e:Event):void {
			loader.height = height;
			loader.width = width;
			loader.x = 0;
			loader.y = 0;
			addChild(loader);
			dispatchEvent(new Event("LOADING_COMPLETED"));
		}
	}
	
}

Das Event wird definitiv gesendet und empfangen, also sollte eigentlich auch der MovieClip bzw der "LevelContainer" auf der Stage landen denke ich.
Aber das Bild innerhalb des LevelContainers ist nicht zu sehen.
Was mache ich falsch?
Ich habe das in ähnlicher Weise schon öfter erfolgreich gemacht, aber hier zickt irgendetwas rum.

[mooseMash]

du weist width, bzw. height zu wo es noch keinen inhalt gibt, versuch mal so:

PHP-Code:

package level {
    
    import flash.display.MovieClip;
    import flash.events.Event;
    import flash.display.Loader;
    import flash.net.URLRequest;
    
    public class LevelContainer extends MovieClip {
        private var index:int;
        
        private var loader:Loader;
        private var req:URLRequest;
        private var h, w;
        
        public function LevelContainer(url:String, _w:int, _h:int, positionIndex:int = 0) {
            index = positionIndex;
            w = _w;
            h = _h;
            loader = new Loader();
            
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completed);
            req = new URLRequest(url);
            loader.load(req);
            
            //addEventListener(Event.ENTER_FRAME, update);
        }
        
        private function update(e:Event):void {
            //update position...
        }
        
        private function completed(e:Event):void {
            
            loader.height = h;
            loader.width = w;
            loader.x = 0;
            loader.y = 0;
            addChild(loader);
            dispatchEvent(new Event("LOADING_COMPLETED"));
        }
    }
    
} 


[Revoluzifer]

Sehr gut, funktioniert
Danke!
War mir zwar sicher das schon anders gemacht zu haben, aber gut, merk ich mir das mal...