mit xml bilder auf die Bühne laden

[_-danie-_]

Hi, ich bin am verzweifeln!

Ich versuche mit xml Bilder in mein AS3 Script zu laden dies Funktioniert auch nur die Ausgabe will nicht so ganz.

Wäre cool wenn mir jemand helfen könnte!

Ich bekomme immer diese Fehlermeldung:
Error #2044: IOErrorEvent unverarbeitet. text=Error #2035: Die URL wurde nicht gefunden.

<bilder>
    <bild>\bilder\bild1.jpg</bild>
    <bild>\bilder\bild2.jpg</bild>
</bilder>

var bilder_xml:XML;
var bilder_load:URLLoader = new URLLoader();
bilder_load.load(new URLRequest("bilder/bilder.xml"));
bilder_load.addEventListener(Event.COMPLETE, loadComplete);

function loadComplete(e:Event):void{
	
	bilder_xml = new XML(e.target.data);
	var posX:int = 10;
	var container:Sprite 
	
	for (var i:int = 0; i<bilder_xml.*.length(); i++){
		
		container = new Sprite;
		addChild(container);
		var bilder_ldr:Loader = new Loader();
		var bilder:URLRequest = new URLRequest("/bilder/" + bilder_xml[i]);
		bilder_ldr.load(bilder);
		bilder_ldr.x = posX + i * 10;
	}
}

[Martin Kraft]

Willkommen im FlashForum!

Zum Einen dürften bei Dir ziemlich seltsame Pfade rauskommen, wenn Du die URL so zusammensetzt:

"/bilder/\bilder\bild2.jpg"

Im Web sollte man immer "/" verwenden und keine "\".
Da die Pfade dann absolut sind und mit einen "/" beginnen, werden sie nur auf einem Webserver funktionieren und nicht lokal.

Zum anderen ist bilder_xml ein XML-Objekt und kein Array. Du kannst Deshalb auf die UnterElemente nicht einfach über einen numerischen Index zugreifen.

Versuch's mal so:

PHP-Code:

import flash.display.Loader;
import flash.display.Sprite;
import flash.events.Event;
import flash.net.URLLoader;
import flash.net.URLRequest;

var bilderXml:XML;
var bilderLoader:Array;
var bilderXmlLoader:URLLoader = new URLLoader();

bilderXmlLoader.addEventListener(Event.COMPLETE, loadComplete);
bilderXmlLoader.load(new URLRequest("bilder/bilder.xml"));

function loadComplete(e:Event):void{    
    bilderXml = new XML(e.target.data);
    bilderLoader = [];
    
    var posX:int = 10;
    var container:Sprite = new Sprite();
    var bildLoader:Loader;

    for each (var bildXml in bilderXml.bild) {        
        bildLoader = new Loader();
        bildLoader.load( new URLRequest( bildXml.toString() ) );
        
        container.addChild(bildLoader);
        bilderLoader.push(bildLoader);
        
        bildLoader.x = posX;
        posX += 10
    }
    
    addChild(container);
} 


[medianetic]

Da sind verschiedene Dinge nicht optimal. Hab mal eine Lösung gemacht.

XML:

<?xml version="1.0" encoding="utf-8" ?>
<bilder>
    <bild>bild1.jpg</bild>
    <bild>bild2.jpg</bild>
</bilder>

import flash.events.Event;

var bilder_xml:XML;
var bilder_load:URLLoader = new URLLoader();
var bildArray:Array = new Array();
var aktLoadIndex:uint = 0;
var bilder_ldr:Loader = new Loader();
bilder_ldr.contentLoaderInfo.addEventListener(Event.COMPLETE,imageLoaded);
bilder_load.load(new URLRequest("bilder/bilder.xml"));
bilder_load.addEventListener(Event.COMPLETE, loadComplete);

function loadComplete(e:Event):void{
	bilder_xml = new XML(e.currentTarget.data);
	loadImage(aktLoadIndex);
}
function loadImage(index:uint):void {
	var bild:URLRequest = new URLRequest("bilder/" + bilder_xml.bild[index]);
	trace(bild.url);
	bilder_ldr.load(bild);
	
}
function imageLoaded(e:Event):void {
	bildArray.push(e.currentTarget.content);
	if(aktLoadIndex+1 <bilder_xml.bild.length()) {
		aktLoadIndex++;
		loadImage(aktLoadIndex);
	} else {
		trace("done");
	}
}

1. Bildpfade nicht in die XML aufnehmen, wenn der Pfad immer der gleiche ist. Redundanz .

2. Alles, was nicht mehrfach initialisiert werden muss, nicht in die for-Schleife, sondern außerhalb definieren.

... war wieder jemand schneller ... dann spare ich mir weitere Erläuterungen.

[_-danie-_]

Vielen Dank!

jetzt funktioniert es

[Omega Psi]

Zitat von medianetic

1. Bildpfade nicht in die XML aufnehmen, wenn der Pfad immer der gleiche ist. Redundanz.

Das ist eine URI, die sollte schon eindeutig sein, da man sonst de Client neu kompilieren darf, wenn sich die Bildpfade ändern.