MC aus Klasse heraus aufrufen

[magic_al]

Ich habe einen Button der von der Main Timeline folgenden Pfad hat:

mainMenu.btnAbout

Weise ich diesem Objekt ein Event zu, ist das kein Problem solange sich der Code auf der Main Timeline befindet.

Aus einer Klasse heraus geht das nicht und Flash jammert, dass es das Objekt nicht finden kann. Hier der Code der Klasse:

PHP-Code:

package classes{
    
    // MOUSE EVENT EVENT LISTENER
    import flash.events.MouseEvent;
    // TWEEN LITE PACKAGE
    import com.greensock.*;
    import com.greensock.plugins.*;
    
    public class mainMenu {

        public function mainMenu() {
            
            // Aktivieren des Tint-Tween Plugin
            TweenPlugin.activate([TintPlugin]);
            
            setOverEffekts();
            
        }
        
        private function setOverEffekts():void {
            
            mainMenu.btnAbout.addEventListener(MouseEvent.MOUSE_OVER,AboutOver);

            
            function AboutOver(evt:MouseEvent):void {
                TweenLite.to(mainMenu.btnAbout, 1, {tint:0x000000});

            
        }

    }
    
} 


Ich habe schon MovieClip(root).mainMenu.btnAbout versucht - kein Erfolg.

[Martin Kraft]

Wenn Du Deine Klasse mit einem Symbol in der Bibliothek verbunden hast(?), sollte sie auch eine Anzeigeklasse erweitern (z.B. Sprite).

Dann sind Klasse und Symbol quasi identisch. D.h. wenn in dem Symbol eine Objekt mit dem Instanznamen btnAbout liegt, solltest Du auch in der Klasse mit diesem Namen darauf zugreifen könne (und zwar ohne mainMenu davor).

P.S.: KlassenNamen sollte man immer mit einem Großbuchstaben beginnen und "classes" ist IMHO ein ziemlich überflüssiger Name für ein Klassenpaket.

[magic_al]

Guten Morgen und danke für deine Antwort.

Ich habe die Klasse nicht mit dem Button verknüpft (ich nehme an du meinst in der Bib).

Die Klasse binde ich so ein:

PHP-Code:

import classes.mainMenu; 


Eigentlich will ich in der Klasse nur den Code auslagern, den ich benötige um allen meinen Buttons gewisse Events zuzuweisen. Das soll dann passieren wenn ich

PHP-Code:

var mainMenu:mainMenu = new mainMenu(); 


auslöse. Die Instancen der Button-MCs sind bereits auf die Stage gezogen. Der About-Butten trägt in diesem Fall den Instance-Name "btnAbout". Darum müsste ich halt jeden Button aus der Klasse heraus ansprechen können.

Ich hatte mal eine andere Klasse, der ich den Button, dem ich Events zuweisen möchte als MC übergebe. Diesen dann in der Klasse zu verwenden war dann kein Problem.

Geht das nicht? Danke!

[thomas_E]

PHP-Code:

var mainMenu:mainMenu 


fällt dir da was auf?
wenn du "mainMenu.irgendwas" (bspw mainMenu.btnAbout) aufrufst, wie soll Flash da wissen, ob es da auf die Klasse oder die Instanz zugreifen soll?
Und bitte auch keine Funktionen verschachteln.

V1: MainMenu als Controller (so wie du es gebaut hast):

PHP-Code:

package 
{    
    import flash.display.InteractiveObject;
    import flash.events.MouseEvent;    
    import com.greensock.*;
    import com.greensock.plugins.*;
    
    public class MainMenu 
    {
        private var _buttons:Vector.<InteractiveObject> = new Vector.<InteractiveObject>();
    
        public function MainMenu(buttons:Array)
        {
            // Aktivieren des Tint-Tween Plugin
            TweenPlugin.activate([TintPlugin, RemoveTintPlugin]);
            
            for each(var btn:InteractiveObject in buttons){
                _buttons.push(btn);
                btn.addEventListener(MouseEvent.MOUSE_OVER, onOver);
                btn.addEventListener(MouseEvent.MOUSE_OUT, onOut);
            }
        }
        
        private function onOver(e:MouseEvent):void
        {
            TweenLite.to(e.currentTarget, 1, {tint:0x000000});
        }
        
        private function onOut(e:MouseEvent):void
        {
            TweenLite.to(e.currentTarget, 1, {removeTint:true});
        }
        
        public function dispose():void
        {
            for each(var btn:InteractiveObject in _buttons){
                btn.removeEventListener(MouseEvent.MOUSE_OVER, onOver);
                btn.removeEventListener(MouseEvent.MOUSE_OUT, onOut);
            }
            _buttons = null;
        }
    }
} 


PHP-Code:

var mainMenu:MainMenu = new MainMenu([btnAbout, btnImpressum, ...]); 


MainMenu kümmert sich lediglich um das ein/ausfaden der Elemente.
du kannst das ganze auch um paar Methoden zum nachträglichen hinzufügen und löschen von Buttons ergänzen.

V2: MainMenu als Container:
hierfür musst du in der Bibliothek einen leeren MovieClip anlegen, und ihm die folgende Klasse zuweisen, nun kommen alle Buttons in diesen MovieClip rein:

PHP-Code:

package
{
    import flash.display.DisplayObject;
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import com.greensock.*;
    import com.greensock.plugins.*;
    
    public class MainMenu extends Sprite
    {
        public function MainMenu()
        {
            // Aktivieren des Tint-Tween Plugin
            TweenPlugin.activate([TintPlugin, RemoveTintPlugin]);
            addEventListener(MouseEvent.MOUSE_OVER, onOver);
            addEventListener(MouseEvent.MOUSE_OUT, onOut);
        }
        
        private function onOver(e:MouseEvent):void
        {
            TweenLite.to(realTarget(e.target), 1, {tint:0x000000});
        }
        
        private function onOut(e:MouseEvent):void
        {
            TweenLite.to(realTarget(e.target), 1, {removeTint:true});
        }
        
        
        private function realTarget(target:DisplayObject):DisplayObject
        {
            while(target.parent != this) 
                target = target.parent;
            return target;
        }

        public function dispose():void
        {
            removeEventListener(MouseEvent.MOUSE_OVER, onOver);
            removeEventListener(MouseEvent.MOUSE_OUT, onOut);
        }
    }
} 


es fällt sonst nichts an Code an, um das ganze einzubinden. wenn du Objekte zu diesem Movieclip hinzufügst werden diese automatisch auch als Bouttons behandelt.
Anmerkung: so wie der Code momentan aussieht, geht dieses MainMenu weder davon aus, dass du da Objekte reinzeichnest, noch, dass eines der Objekte darin kein Button ist, also ausgenommen werden soll, dass müsstest du ergänzen. ebenso geht es davon aus, dass sich die Buttons direkt im MainMenu befinden, sprich bei sowas

PHP-Code:

mainMenu.group1.btnAbout 


wird das MainMenu davon ausgehen dass group1 der Button ist, nicht btnAbout, und group1 einfärben!

wie du das im einzelfall ändern musst, kommt halt darauf an, wie du das ganze zusammenbaust

[magic_al]

Zitat von thomas_E

PHP-Code:

var mainMenu:mainMenu 


fällt dir da was auf?
wenn du "mainMenu.irgendwas" (bspw mainMenu.btnAbout) aufrufst, wie soll Flash da wissen, ob es da auf die Klasse oder die Instanz zugreifen soll?
Und bitte auch keine Funktionen verschachteln.

V1: MainMenu als Controller (so wie du es gebaut hast):

PHP-Code:

package 
{    
    import flash.display.InteractiveObject;
    import flash.events.MouseEvent;    
    import com.greensock.*;
    import com.greensock.plugins.*;
    
    public class MainMenu 
    {
        private var _buttons:Vector.<InteractiveObject> = new Vector.<InteractiveObject>();
    
        public function MainMenu(buttons:Array)
        {
            // Aktivieren des Tint-Tween Plugin
            TweenPlugin.activate([TintPlugin, RemoveTintPlugin]);
            
            for each(var btn:InteractiveObject in buttons){
                _buttons.push(btn);
                btn.addEventListener(MouseEvent.MOUSE_OVER, onOver);
                btn.addEventListener(MouseEvent.MOUSE_OUT, onOut);
            }
        }
        
        private function onOver(e:MouseEvent):void
        {
            TweenLite.to(e.currentTarget, 1, {tint:0x000000});
        }
        
        private function onOut(e:MouseEvent):void
        {
            TweenLite.to(e.currentTarget, 1, {removeTint:true});
        }
        
        public function dispose():void
        {
            for each(var btn:InteractiveObject in _buttons){
                btn.removeEventListener(MouseEvent.MOUSE_OVER, onOver);
                btn.removeEventListener(MouseEvent.MOUSE_OUT, onOut);
            }
            _buttons = null;
        }
    }
} 


PHP-Code:

var mainMenu:MainMenu = new MainMenu([btnAbout, btnImpressum, ...]); 


MainMenu kümmert sich lediglich um das ein/ausfaden der Elemente.
du kannst das ganze auch um paar Methoden zum nachträglichen hinzufügen und löschen von Buttons ergänzen.

V2: MainMenu als Container:
hierfür musst du in der Bibliothek einen leeren MovieClip anlegen, und ihm die folgende Klasse zuweisen, nun kommen alle Buttons in diesen MovieClip rein:

PHP-Code:

package
{
    import flash.display.DisplayObject;
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import com.greensock.*;
    import com.greensock.plugins.*;
    
    public class MainMenu extends Sprite
    {
        public function MainMenu()
        {
            // Aktivieren des Tint-Tween Plugin
            TweenPlugin.activate([TintPlugin, RemoveTintPlugin]);
            addEventListener(MouseEvent.MOUSE_OVER, onOver);
            addEventListener(MouseEvent.MOUSE_OUT, onOut);
        }
        
        private function onOver(e:MouseEvent):void
        {
            TweenLite.to(realTarget(e.target), 1, {tint:0x000000});
        }
        
        private function onOut(e:MouseEvent):void
        {
            TweenLite.to(realTarget(e.target), 1, {removeTint:true});
        }
        
        
        private function realTarget(target:DisplayObject):DisplayObject
        {
            while(target.parent != this) 
                target = target.parent;
            return target;
        }

        public function dispose():void
        {
            removeEventListener(MouseEvent.MOUSE_OVER, onOver);
            removeEventListener(MouseEvent.MOUSE_OUT, onOut);
        }
    }
} 


es fällt sonst nichts an Code an, um das ganze einzubinden. wenn du Objekte zu diesem Movieclip hinzufügst werden diese automatisch auch als Bouttons behandelt.
Anmerkung: so wie der Code momentan aussieht, geht dieses MainMenu weder davon aus, dass du da Objekte reinzeichnest, noch, dass eines der Objekte darin kein Button ist, also ausgenommen werden soll, dass müsstest du ergänzen. ebenso geht es davon aus, dass sich die Buttons direkt im MainMenu befinden, sprich bei sowas

PHP-Code:

mainMenu.group1.btnAbout 


wird das MainMenu davon ausgehen dass group1 der Button ist, nicht btnAbout, und group1 einfärben!

wie du das im einzelfall ändern musst, kommt halt darauf an, wie du das ganze zusammenbaust

Hallo und Danke! ich habe mich jetzt an deiner V2 versucht. Habe also einen leeren MC erstellt, mal zwei Buttons rein gezogen und die Klasse an den neuen MC verlinkt. Allerdings bekomme ich folgenden Fehler:

PHP-Code:

C:UsersAlexDocumentsAbubu Websitecomabububtn_BottomMenu.as, Line 20    1118: Implicit coercion of a value with static type Object to a possibly unrelated type flash.display:DisplayObject.
C:UsersAlexDocumentsAbubu Websitecomabububtn_BottomMenu.as, Line 25    1118: Implicit coercion of a value with static type Object to a possibly unrelated type flash.display:DisplayObject. 


Die Klasse hat diesen Code:

PHP-Code:

package com.abubu {
    
    import flash.display.DisplayObject; 
    import flash.display.Sprite; 
    import flash.events.MouseEvent; 
    import com.greensock.*; 
    import com.greensock.plugins.*; 
    
    public class btn_BottomMenu extends Sprite {

        public function btn_BottomMenu() { 
            // Aktivieren des Tint-Tween Plugin 
            TweenPlugin.activate([TintPlugin, RemoveTintPlugin]); 
            addEventListener(MouseEvent.MOUSE_OVER, onOver); 
            addEventListener(MouseEvent.MOUSE_OUT, onOut); 
        } 
         
        private function onOver(e:MouseEvent):void 
        { 
            TweenLite.to(realTarget(e.target), 1, {tint:0x000000}); 
        } 
         
        private function onOut(e:MouseEvent):void 
        { 
            TweenLite.to(realTarget(e.target), 1, {removeTint:true}); 
        } 
         
         
        private function realTarget(target:DisplayObject):DisplayObject 
        { 
            while(target.parent != this)  
                target = target.parent; 
            return target; 
        } 

        public function dispose():void 
        { 
            removeEventListener(MouseEvent.MOUSE_OVER, onOver); 
            removeEventListener(MouseEvent.MOUSE_OUT, onOut); 
        } 
    } 
    

    
} 


Die Buttons haben keinerlei Bennenung o.ä. Vll liegt es daran? Danke für deine Hilfe!

[thomas_E]

Die Buttons haben keinerlei Bennenung o.ä. Vll liegt es daran? Danke für deine Hilfe!

nein, es liegt an folgendem code, da hab ich noch nen Fehler drin:

PHP-Code:

realTarget(e.target) 


e.target ist vom Typ Object, realTarget erwartet aber ein DisplayObject; und Flash meckert, weil es das nicht automatisch umwandeln kann.
Weil ein DisplayObject ist immer auch ein Objekt, aber ein Object muss nicht zwangsläufig ein DisplayObject sein. kann bspw auch ein Timer sein.

also musst du casten:

PHP-Code:

realTarget( DisplayObject(e.target) );
//oder
realTarget( e.target as DisplayObject); 


in diesem Code macht das keinen Unterschied, da e.target hier immer ein DisplayObject ist. In anderen Codes würde es durchaus einen Unterschied machen, ob du die erste, oder die zweite Variante zum casten nimmst.

edit, nachtrag: es ist wirklich nicht nötig komplette Posts zu zitieren, besonders wenn du direkt darauf antwortest

[Martin Kraft]

@thomas_E: Wieso verwendest Du eigentlich nicht einfach e.currentTarget oder schlicht this statt dieser seltsamen realTarget-Konstruktion.

[thomas_E]

weil du dann addChild, removeChild, etc überschreiben musst, um die Event-Listener an die einzelnen children anzuhängen bzw wieder zu entfernen, und ich bin mir grad nicht sicher, ob addChild für Zeitleistenobjekte überhaupt ausgeführt wird.

und this ist ja der Container selber, ich brauch aber das Kindelement auf das geklickt wurde.

mir schien es die einfachere Lösung hier auf das Event-Bubbling zu setzen, und das Event direkt beim Container abzufangen. (ich benutz sonst wirklich nicht oft e.target)
der Workaround mit realTarget fängt "fehler" ab, wenn die Objekte verschachtelt sind (und mouseChildren=false ggf "vergessen" wurde)

fällt dir spontan was eleganteres ein? oder denk ich mal wieder viel zu kompliziert?

[magic_al]

Vielen dank!

Könntest du/ihr versuchen mir zu erklären, was ein Sprite ist? Ich habe mal gesucht und heraus gefunden, dass es ein abgespreckter MC sein soll. Was ist der Sinn davon?

Und was macht die Funktion realTarget() im obrigen Beispiel genau? Ich würde das gerne verstehen, bevor ich es verwende.

Ein Container stelle ich mir jetzt mal vor als ein MC oder Sprite der ander MCs umfasst und von dem ausgehend ich die unterelemente (Childs?!?) aufrufen kann.

Lieg ich damit in etwa richtig?

PS: könnte ich das hier auch verwenden um alle MCs in dem MC auf einmal auszublenden?

[thomas_E]

Ich habe mal gesucht und heraus gefunden, dass es ein abgespreckter MC sein soll.

eher andersherum, ein MC ist ein aufgebohrtes Sprite. MC ist ein Sprite + Zeitleiste, und Funktionen um die Zeitleiste zu bedienen.

Was ist der Sinn davon?

andersherum, der einzige Grund einen MC zu benutzen ist die Zeitleiste. In der Programmierung brauch ich die aber garnicht, somit sind dort MCs eher überflüssig.

Und was macht die Funktion realTarget() im obrigen Beispiel genau? Ich würde das gerne verstehen, bevor ich es verwende.

kein Problem, da muss ich aber erst etwas ausholen.
Der Hintergrund des ganzen ist die Art und weise wie Events funktionieren.
(google mal nach Event-Bubbling) es geht darum, wenn du bspw auf menu.level1.level2.level3 klickst wird das Event erst für level3 gefeuert, dann für level2, level1, menu, root und stage. Eas Event wandert langsam die DisplayList (eher Baum) hoch.
nun steht in Event.target das Objekt, dass das Event ausgelöst hat (hier level3), und in Event.currentTarget das objekt, bei dem su das abgefangen hast.

auf den obigen Code bezogen:
der Event-Listener liegt auf menu, das Event wird evtl von level2, level3, oder noch tiefer gefeuert.
für den Code brauch ich aber immer level1.
realTarget nimmt nun e.target, also level1, 2, 3, etc und wandert dann die DL so lange hoch, bis es bei level1 landet, und gibt dann dieses Objekt zurück.

das schien mir eine gute vorgehensweise, Martin findet das seltsam.

Das Problem ist für mich hier die Unberechenbarkeit der Zeitleiste, und deines Programmierstils.
wenn ich programmiere, benutz ich fast nur Code, und die Zeitleiste höchstens um "grafiken" zu erstellen.
dann kann ich bspw für die Buttons mouseChildren = false setzen, dadurch würde hier in e.target immer das richtige Objekt drinstehen.
oder wie Martin geschrieben hat: beim hinzufügen eines Buttons zum Menu, direkt ein EventListener auf das Kindelement setzen, und ich in e.currentTarget steht nun immer der korrekte Button drin.

da ich hier nicht genau weiss, wie sich deine Buttons verhalten werden, hab ich (erstmal) diesen Workaround über die Funktion realTarget gewählt.

Ein Container stelle ich mir jetzt mal vor als ein MC oder Sprite der ander MCs umfasst und von dem ausgehend ich die unterelemente (Childs?!?) aufrufen kann.

ja. "container" beschreibt dabei vor allen dingen ein MC||Sprite das dazu genutzt wird um gleiche/gleichartige Objekte als Einheit zusammenzuhalten und bspw zusammen zu bewegen/transformieren.

könnte ich das hier auch verwenden um alle MCs in dem MC auf einmal auszublenden?

ja

[Martin Kraft]

Zitat von thomas_E

das schien mir eine gute vorgehensweise, Martin findet das seltsam.

Ne, ist schon ok. Ich hatte das Script nur überflogen und übersehen, dass Du das RollOver vom Container aus in die Buttons injezierst....

[thomas_E]

puh, schwein gehabt
mal abwarten, bis Omega Psi hierüber stolpert *g

[magic_al]

Ok das habe ich verstand. Wie ich jetzt aber alle MC in dem MC ausblenden könnte wüsste ich nicht. Ich müsste ja iwie auslesen, welche sich darin befinden.

[thomas_E]

am einfachsten ist, das menü selber auszublenden, und garnicht die Kindelemente selber.

ansonsten, so kommst du an die Kind-Elemente:

PHP-Code:

for(var i:int = numChildren; i--; ){
    var child:DisplayObject = getChildAt(i);
    trace(i, child);
}

//oder
for(var i:int=0; i<numChildren; ++i){
    var child:DisplayObject = getChildAt(i);
    trace(i, child);
} 


[magic_al]

Achso, während Parent das übergeordnete Objekt beschreibt, beschreibt Child die untergeordneten? Danke!

EDIT:

PHP-Code:

            for(var i:int=0; i<numChildren; ++i){
                var child:DisplayObject = getChildAt(i);
                child.alpha = 0;
                trace(i, child);
            } 


Jetzt blendet er mir aber mein Menu aus mit dem ich die Klasse verlinkt habe. Iwas verstehe ich an dem Child/Parent Ding wohl grundsätzlich nicht.