local3DToGlobal und PerspectiveProjection

[edding950]

Verstehe ich da etwas grundsätzlich falsch, oder projiziert local3DToGlobal nicht in Abhängigkeit zu den in DiplayObject.transform vorliegenden Infos zur Perspektive?

Irgendwie kommen hier nur Müllwerte bei raus:

package 
{
    import flash.display.*;
    import flash.geom.*;
    
    [SWF(width = "900", height = "900", backgroundColor = "#000000", framerate = "60")]
    
    public class PerspTest extends Sprite 
    {
        public function PerspTest():void 
        {
            var spr:Sprite = new Sprite();
            var inner:Sprite = new Sprite();
            
            with (spr.graphics)
            {
                lineStyle(0, 0x00, 0);
                beginFill(0xFF00000);
                drawRect(-100, -50, 200, 100);
                endFill();
            }
            
            spr.x = stage.stageWidth / 2;
            spr.y = stage.stageHeight / 2;
            spr.rotationX = -10;
            
            inner.x = spr.width / 2;
            inner.y = -spr.height / 2;
            
            with (inner.graphics)
            {
                lineStyle(0, 0x00, 0);
                beginFill(0xFFFF00);
                drawCircle(0, 0, 3);
                endFill();
            }
            
            addChild(spr);
            spr.addChild(inner);
            
            var pp:PerspectiveProjection = new PerspectiveProjection();
            pp.fieldOfView = 120;
            pp.projectionCenter = new Point(0, 0);
            pp.focalLength = 300;
            
            spr.transform.perspectiveProjection = pp;
            
            var pt:Point = inner.local3DToGlobal(new Vector3D(inner.x, inner.y, inner.z));
            
            trace(pt);
        }
    }
} 

[edding950]

Scheint irgendwie nur zu klappen, wenn PerspectiveProjection im DisplayObject unangetastet bleibt, man es also bei den Defaultwerten belässt - das kann es doch nicht sein, oder?

Ich kotz gleich.

[Janoscharlipp]

Musst du vielleicht das transform nochmal neu schreiben?

[edding950]

Nee, irgendwie macht das keinen Unterschied..Was mich echt aufregt ist der Umstand, dass es ohne PerspectiveProjection funktioniert:

package 
{
    import flash.display.*;
    import flash.events.Event;
    import flash.geom.*;
    
    [SWF(width = "900", height = "900", backgroundColor = "#000000", framerate = "60")]
    
    public class PerspTest extends Sprite 
    {
        public function PerspTest():void 
        {
            var spr:Sprite = new Sprite();
            var inner:Sprite = new Sprite();
            
            with (spr.graphics)
            {
                lineStyle(0, 0x00, 0);
                beginFill(0xFF00000);
                drawRect(-100, -50, 200, 100);
                endFill();
            }
            
            spr.x = stage.stageWidth / 2;
            spr.y = stage.stageHeight / 2;
            
            
            inner.x = spr.width / 2;
            inner.y = -spr.height / 2;
            
            with (inner.graphics)
            {
                lineStyle(0, 0x00, 0);
                beginFill(0xFFFF00);
                drawCircle(0, 0, 3);
                endFill();
            }
            
            addChild(spr);
            spr.addChild(inner);
            
            
            var transf:Transform = new Transform(spr);
            /*transf.perspectiveProjection = new PerspectiveProjection();
            transf.perspectiveProjection.fieldOfView = 120;
            transf.perspectiveProjection.projectionCenter = new Point(0,0);
            transf.perspectiveProjection.focalLength = 300;*/
            transf.matrix3D = new Matrix3D();
            transf.matrix3D.appendTranslation(100,100,0);
            transf.matrix3D.appendRotation(45, Vector3D.Y_AXIS);
            transf.matrix3D.appendTranslation(100,100,0);
            
            // Marker auf die globale 2D-Position von spr.inner setzen
            
            var pt:Point =  spr.local3DToGlobal(new Vector3D(inner.x, inner.y, inner.z));
            
            var mrk:Sprite = new Sprite();
            
            with (mrk.graphics)
            {
                lineStyle(0, 0x00, 0);
                beginFill(0x0000ff);
                drawCircle(0, 0, 2);
                endFill();
            }
            
            mrk.x = pt.x;
            mrk.y = pt.y;
            
            addChild(mrk);
            
        }
    }
} 

...aber mit PerspectiveProjection der Marker immer falsch positioniert ist:

package 
{
    import flash.display.*;
    import flash.events.Event;
    import flash.geom.*;
    
    [SWF(width = "900", height = "900", backgroundColor = "#000000", framerate = "60")]
    
    public class PerspTest extends Sprite 
    {
        public function PerspTest():void 
        {
            var spr:Sprite = new Sprite();
            var inner:Sprite = new Sprite();
            
            with (spr.graphics)
            {
                lineStyle(0, 0x00, 0);
                beginFill(0xFF00000);
                drawRect(-100, -50, 200, 100);
                endFill();
            }
            
            spr.x = stage.stageWidth / 2;
            spr.y = stage.stageHeight / 2;
            
            
            inner.x = spr.width / 2;
            inner.y = -spr.height / 2;
            
            with (inner.graphics)
            {
                lineStyle(0, 0x00, 0);
                beginFill(0xFFFF00);
                drawCircle(0, 0, 3);
                endFill();
            }
            
            addChild(spr);
            spr.addChild(inner);
            
            
            var transf:Transform = new Transform(spr);
            transf.perspectiveProjection = new PerspectiveProjection();
            transf.perspectiveProjection.fieldOfView = 120;
            transf.perspectiveProjection.projectionCenter = new Point(0,0);
            transf.perspectiveProjection.focalLength = 300;
            transf.matrix3D = new Matrix3D();
            transf.matrix3D.appendTranslation(100,100,0);
            transf.matrix3D.appendRotation(45, Vector3D.Y_AXIS);
            transf.matrix3D.appendTranslation(100,100,0);
            
            // Marker auf die globale 2D-Position von spr.inner setzen
            
            var pt:Point =  spr.local3DToGlobal(new Vector3D(inner.x, inner.y, inner.z));
            
            var mrk:Sprite = new Sprite();
            
            with (mrk.graphics)
            {
                lineStyle(0, 0x00, 0);
                beginFill(0x0000ff);
                drawCircle(0, 0, 2);
                endFill();
            }
            
            mrk.x = pt.x;
            mrk.y = pt.y;
            
            addChild(mrk);
            
        }
    }
} 

[Janoscharlipp]

In meiner Doku steht, die focalLength sei read-only??

[edding950]

Die Doku taugt nichts

Nee, also ich kann focalLength schön ändern und der resultierende Effekt, was die perspektivische Ansicht angeht, kommt jeweils auch ganz gut hin.

Ich krieg es aber kein bißchen auf die Kette, die Koordinaten eines Sprites innerhalb eines 3D-transformierten Sprites zu 'globalisieren', wenn PerspectiveProjection auch nur instanziert wurde...Es ist noch nichtmal nötig, Werte zu vergeben - nur instanzieren reicht schon, damit local3DToGlobal nicht mehr funzt.

[edding950]

Was ich im übrigen auch nicht raffe:

var pp:PerspectiveProjection = new PerspectiveProjection();
     pp.fieldOfView = 120;
     pp.projectionCenter = new Point(450, 450);
     pp.focalLength = 1000;
 
     var v3:Vector.<Vector3D> = pp.toMatrix3D().decompose();
     var v4:Vector.<Vector3D> = new Matrix3D().decompose();
 
    trace(v3); 
    trace(v4); 

...wenn man sich das mal so anschaut, fällt einem auf, dass die Matrizen, abgesehen vom Scale-Vector absolut identisch sind. Da frag ich mich doch, was PerspectiveProjection eigentlich macht?!? Oder wo der eigentliche Wirkungsbereich von PerspectiveProjection ist. Ich bin doch einigermaßen ratlos, wo ich ansetzen soll, um ein local3DToGlobal mit perspektivischer Projektion hinzukriegen..

AS3 sucks again.

[edding950]

Der Groschen ist gefallen.

To whom it may concerns: Selbstverständlich sollte das jeweils übergeordnete DisplayObject die Werte für die PerspectiveProjection bekommen. Die Projektion des gewünschten Punkts im 3D-Raum erfolgt dann schematisch über:

childObject.local3DToGlobal(new Vector3D(x, y, z));

..wobei x, y und z keine Werte sein sollten, die sich in Abhängigkeit von einer Transformation auch schonmal ändern könnten, wie z.B. die Breite eines DisplayObjects innerhalb des 3D-Raums, von dem aus man zu projizieren versucht.


Hier mal ein funktionierendes Beispiel..Der blaue Kreis markiert dabei die globale 2D-Position der rechten oberen Ecke des roten Rechtecks.

package  
{
    import flash.display.Sprite;
    import flash.geom.PerspectiveProjection;
    import flash.events.Event;
    import flash.geom.*;
    
    [SWF(width = "900", height = "900", backgroundColor = "#FFFFFF", frameRate = "100")]
    
    public class Test006 extends Sprite
    {
        public var container:Sprite;
        public var spr:Sprite;
        public var mrk:Sprite;
        
        public function Test006() 
        {
            
            var pp:PerspectiveProjection = new PerspectiveProjection();
            pp.focalLength = 70;
            pp.projectionCenter = new Point(0, -10);
            
            container = new Sprite();
            spr = new Sprite();
            mrk = new Sprite();
            
            
            addChild(container);
            container.addChild(spr);
            addChild(mrk);
            
            spr.graphics.lineStyle(0, 0x00, 0);
            spr.graphics.beginFill(0xFF00000);
            spr.graphics.drawRect(-100, -50, 200, 100);
            spr.graphics.endFill();
            
            container.transform.perspectiveProjection = pp;
            container.x = 450;
            container.y = 450;
            
            
            mrk.graphics.lineStyle(0, 0x00, 0);
            mrk.graphics.lineStyle(0, 0x00, 0);
            mrk.graphics.beginFill(0x0000ff);
            mrk.graphics.drawCircle(0, 0, 5);
            mrk.graphics.endFill();
            
            addEventListener(Event.ENTER_FRAME, onEnterFrame);
            
        }
        public function onEnterFrame(event:Event):void
        {
            spr.rotationY++;
            spr.rotationX+=1.9;
            
            var pt:Point = spr.local3DToGlobal(new Vector3D(100, -50, 0));
            
            mrk.x = pt.x
            mrk.y = pt.y
        }
        
    }
    
} 

Achso: focalLength und fieldOfView können gleichermaßen gelesen und geschrieben werden, wobei es durch die Interdependanz der beiden Eigenschaften immer nur Sinn macht, jeweils eine zu ändern. Ihr könnt ja mal verschiedene Werte setzen und Euch den jeweils anderen austracen lassen.

So long...