Load externe SWF und totalframes ähnlich von AS 2 ?

[provie]

Ich habe vor nicht all zu langer Zeit in Actionscript 2 den folgenden Code geschrieben:

sportbutton.onRelease=function(){
	this.createEmptyMovieClip("halter",0);
    this.halter.loadMovie("stadion.swf");
	this.halter._x = -200;
	this.halter._y = -150;
	this.onEnterFrame = function() {
		if(this.halter._width) {
			if(this.halter._currentframe == this.halter._totalframes) {
				_root.nextFrame();
				delete this.onEnterFrame;
			}
		}
	}   
}

Da ich jetzt eine Anwendung in Actionscript 3 geschrieben habe, müßte ich einen ähnlichen code in Actionscript 3 schreiben.
Ich habe bereits gesucht und weißt das man extere SWF Dateinen mit der Loader Klasse lädt, aber wie erfahre ich das ich die SWF Datei am letzen Frame bzw. zuende gespielt wurde ?
Ich kann auch nicht in die SWF Datei gehen und in dem letzen Frame etwas reinschreiben.
Also gibt es in Actionscript 3 soetwas wie totalframes bzw. currentframe ?

[T.Decay]

Flash weiß nicht welchen Typ die Ressource hat, die Du geladen hast. Mit einem Loader kannst Du ja Bilder und SWFs gleichermaßen laden und selbst eine SWF kann MovieClip oder nur Sprite als Basisklasse haben. Da Du aber weißt, dass dein SWF ein MovieClip ist, kannst Du dafür sorgen, dass dieser auch als solcher ansprechbar ist, indem Du einen cast in eine MovieClip Variable machst:

var ldr:Loader = new Loader();
ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, handleLoaderInfo);
addChild(ldr);
ldr.load(new URLRequest('loadme.swf'));

function handleLoaderInfo(e:Event) :void
{
	trace('handleLoaderInfo()');
	addEventListener(Event.ENTER_FRAME, handleEnterFrame);
}

function handleEnterFrame(e:Event) :void
{
	var mc:MovieClip = ldr.content as MovieClip
	if(mc.currentFrame == mc.totalFrames){
		trace('lastFrame');
		removeEventListener(Event.ENTER_FRAME, handleEnterFrame);
		mc.stop();
	}
}