Lade Bilder in MC-Instanzen

[pixelsadist]

Ich versuch 6 Bilder aus einem Verzeichnis in seperate Instanzen von einem MovieClip zu laden . Das MC befindet sich in der Bibliothek und export für AS "jop"

Als ersetzes erzeuge ich in eine Schleife 6 Instanzen dieses MC und versuche zu jeder das neugeladene Bild zuzuweisen, leider wird nur das letzte Bild in der letzten Instanz geladen. Offensichtlich klappt die zuweisung nicht mit newMC .

public function load_gallery_ordner(){


		var current_adr:String="";		
		var ClassDefinition:Class = Class(getDefinitionByName(getQualifiedClassName(jop)));   
			
			
			
			for (var i:Number=1;i<=6;i++){  
			
				var newMC:MovieClip = new ClassDefinition;
               	                newMC.name = "test"+String(i); ;       
                                addChild(newMC);
				newMC.x=(i-1)*(newMC.width+20);
				newMC.y=i*30;
				
				
			
				current_adr="http://localhost/hp/bilder/"+i+".jpg";		
				var lid:Loader=new Loader();
        		        lid.load(new URLRequest(current_adr));	
	     		        lid.contentLoaderInfo.addEventListener(Event.COMPLETE,function (){   
								newMC.addChild(lid.content);  
								newMC.width=100;
								newMC.height=100;
													   
						                 });		
				
			}
			
			
}

Habs auch so versucht :

this["test"+i].addChild(lid.content);

Falls jemand ne Idee hat wäre ich dankbar ^^

[thomas_E]

paar Anmerkungen zu deinem Code:
- KlassenNamen fangen mit Grossbuchstaben an, also "Jop" statt "jop"
- namen sind imo in AS3 überholt, arbeite mit Referenzen
- solche durchnummerierten Namen sind weder sehr dynamisch, noch schnell; nimm Arrays
- erst Event-Listener hinzufügen, dann die Operation ausführen, die dieses Event auslöst
- dynamische funktionen als Event-listener sind nicht gut, die bekommst du (fast) garnicht mehr weg
- Event-Listener bitte wieder wegräumen, wenn sie nicht mehr benötigt werden, sonst können Objekte nicht gelöscht werden

PHP-Code:

var images:Array = [];
public function load_gallery_ordner()
{
    for (var i:int=0; i<6; ++i){  
        var lid:Loader=new Loader();
            lid.contentLoaderInfo.addEventListener(Event.COMPLETE, imageLoaded);
            
        var mc:MovieClip = new jop();
            mc.x = i * (mc.width + 20);
            mc.y = (i+1) * 30;
            mc.addChild(lid);
        addChild(mc);
        images[i] = mc;
        
        lid.load(new URLRequest("http://localhost/hp/bilder/"+ (i+1) +".jpg"));    
    }
}

function imageLoaded(e:Event):void
{
    e.currentTarget.removeEventListener(e.type, imageLoaded);
    
    var lid:Loader = e.currentTarget.loader;
    var mc:MovieClip = lid.parent as MovieClip;
        
    if(mc){
        mc.width = 100;
        mc.height = 100;
        
        //im mc: lid durch lid.content ersetzen
        mc.addChildAt(lid.content, mc.getChildIndex(lid));
        mc.removeChild(lid);
    }
} 


[pixelsadist]

ich würde es gern noch verstehen.
Punkt1: Also du erzeugst eine neue MC instanz in der du dem leader lid einfügst.

 mc.addChild(lid);

Punkt2: Sobald Bild fertiggeladen ist wird der listener gelöscht

e.currentTarget.removeEventListener(e.type, imageLoaded);

Punkt3: In der Funktion ImageLoaded erzeugst du einen neuen Loader und weist dem den alten zu:

var lid:Loader = e.currentTarget.loader;

Punkt4: und wandelst sein parent in ein MC um:

var mc:MovieClip = lid.parent as MovieClip;

Punkt5: danach ersetzt im mc den leader lid durch sein inhalt bzw sein Bild und löscht lid

 mc.addChildAt(lid.content, mc.getChildIndex(lid));
 mc.removeChild(lid);

Das Array machst du um den zufriff auf die jeweiligen MCs effizienter zu machen und um keine namen zu verwenden

Punkt 3 und 4 ist keine wirklich umwandlung sondern eher eine verknüpfung zu dem bereits existierendem mc und lid

Bei Punkt5 verstehe ich nicht warum lid durch lid.content ersetzt werden soll.

Gibt es eine möglichkeit abzufragen welche listener noch aktiv sind ?

[thomas_E]

Punkt 1: ja, war für mich grad der einfachste Weg, jedem Loader einen MovieClip zuzuordnen, und umgekehrt.

Punkt 2: das meine ich mit "Event-Listener bitte wieder wegräumen, wenn sie nicht mehr benötigt werden". dieser spezielle Loader brauch den Event-Listener nicht mehr, da er kein weiteres Bild mehr laden wird. (das werden andere Loader sein)

Punkt 3: ich erzeuge hier keinen neuen Loader, sondern Event.currentTarget enthält das Objekt, dem ich mit addEventListener einen Event-Listener hinzugefügt habe.
also, ich suche nur den Loader raus, der gerade die Funktion aufgerufen hat. (wie der Absender bei einem Brief)

Punkt 3 und 4:
da wird nix umgewandelt, das wird gecastet, der Unterschied ist:
ich kann aus nem Huhn keinen Fisch machen, aber, wenn jemand sagt ich bring ein Tier zum essen mit, und ich weiss dass es ein Huhn ist, kann ich es auch wie ein Huhn behandeln (lecker hähnchenswchenkel in einer Paprika-Marinade, dazu Bratkartoffeln und etwas Gemüse, und es wird ein richtig leckeres Essen, aber ich bin etwas abgeschweift )
Also, Event.currentTarget ist vom Typ Object, und das kann so ziemlich alles sein (äquivalent zum Tier). wenn ich aber weiss, dass es ein Loader ist (Huhn), kann ich es auch als solchen behandeln, und alle Methoden eines Loaders benutzen.
(Hahnchenschenken geht schlecht wenn ich nen Fisch vor mir hab)

Punkt 5: der Loader hat seinen Dienst getan, der wird jetzt nicht mehr benötigt, ich brauch nur das Bild/die SWF die geladen wurde.
Ich hab Loader.content hinzugefügt, weil du das so gemacht hast. du kannst die beiden Zeilen genauogut weglassen, und den Content samt Loader in den Movieclip packen. dann solltest du dir aber bewusst sein, dass dort ein Loader im Movieclip steckt, und kein Bitmap (das ist im Loader drin).
Das macht dann einen Unterschied, wenn du bspw auf das BitmapData-Objekt des Bildes zugreifen willst, over MovieClip.play() bei einer nachgeladenen swf ausführen willst, ...


das Array ist in diesem Code bislang überflüssig. ich hab es nur eingebaut, damit du siehst, wie ich das meine, bzw wie das geht, und wo du dann die einzelnen Movieclips herholen kannst, wenn sie einmal erzeugt sind.
mit images hast du hier also immer eine Liste der Movieclips, incl Bilder, die gerade auf der Bühne sind.

[pixelsadist]

ich kann aus nem Huhn keinen Fisch machen, aber, wenn jemand sagt ich bring ein Tier zum essen mit, und ich weiss
 dass es ein Huhn ist, kann ich es auch wie ein Huhn behandeln (lecker hähnchenswchenkel in einer Paprika-Marinade, 
dazu Bratkartoffeln und etwas Gemüse, und es wird ein richtig leckeres Essen, aber ich bin etwas abgeschweift )

lol nur ganz wenig, dacht scho ich lese gleich ein rezept ^^