Klasse muss für URLLoader erben?

[SpecOps-12]

Hab ne Klasse XMLLoader, die von EventDispatcher erbt und mit einer URLLoader-Instanz eine xml-Datei lädt.

Nutze ich diese Klasse XMLLoader in der Timeline, funktioniert alles.
Setze ich diese Klasse in eine andere Klasse (die von Sprite erbt), wird das Complete-Event der URLLoader-Instanz nicht mehr gefeuert.

Nach 20 min Fehlersuche und reduzierung auf's Kernproblem hab ich irgendwann die Klasse statt von EventDispatcher von Sprite erben lassen, und auf einmal ging es wieder.

Hat jemand eine Erklärung dafür?

[Omega Psi]

Code? Ich würde vermuten, du machst was falsch.

[SpecOps-12]

Ich vermute das auch. Aber ich verstehe es nicht.

Hab mal zum testen noch das ganze "Projekt" angehängt. Ist nicht viel, nur zwei Klassen à 20 Zeilen.

Lässt man wie gesagt in der XMLLoader-Klasse nicht von EventDispatcher sondern von Sprite erben, funktioniert alles.


Timeline:

PHP-Code:

var url:String = "xml/album.xml";

var xmlLoader:XMLLoader = new XMLLoader(url); // Funktioniert
var album:Album = new Album(url); // Funktioniert nicht 


Klasse "XMLLoader"

PHP-Code:

package {
    import flash.events.Event;
    import flash.events.EventDispatcher;
    import flash.net.URLLoader;
    import flash.net.URLRequest;

    public class XMLLoader extends EventDispatcher {

        private var urlLoader:URLLoader;

        public function XMLLoader(url:String) {
            loadXML(url);
        }

        private function loadXML(url:String):void {
            urlLoader = new URLLoader();
            urlLoader.addEventListener(Event.COMPLETE, completeHandler, false, 0, true);
            urlLoader.load(new URLRequest(url));
        }

        private function completeHandler(e:Event):void {
            trace('XMLLoader: completeHandler: e: ' + (e));
            this.dispatchEvent(new Event(Event.COMPLETE));
        }
    }
} 


Klasse "Album"

PHP-Code:

package {
    import flash.display.Sprite;
    import flash.events.Event;

    public class Album extends Sprite {

        public function Album(url : String) {
            init(url);
        }

        private function init(url : String) : void {
            var xmlLoad : XMLLoader = new XMLLoader(url);
            xmlLoad.addEventListener(Event.COMPLETE, loadCompleteHandler);
        }

        private function loadCompleteHandler(e : Event) : void {
        }
    }
} 


[mildesign]

ich würde die load Methode des URLLoaders nicht direkt beim instantiieren aufrufen, sondern diese nochmal von außen über eine zusätzlich Methode anstoßen.

Vermutlich kommt dein Listener zu spät in der Album Klasse.
Ich hoffe Florian korrigiert mich wenn ich da jetzt falsch vermute ;o)

PHP-Code:

private function init(url : String) : void {
            var xmlLoad : XMLLoader = new XMLLoader(url);
            xmlLoad.addEventListener(Event.COMPLETE, 
                        xmlLoad.load(); // <--ruft xmlload.urlloader.load() auf
loadCompleteHandler);
        } 


[SpecOps-12]

Das hatte ich zunächst auch vermutet. Aber das Complete-Event wird bereits in der XMLLoader-Klasse schon nicht gefeuert. (Jedoch schon, wenn ich XMLLoader direkt in der Timeline instanziere).

Und was hat es mit der Änderung des Verhaltens auf sich, wenn ich eine andere Erbschaft angebe? Das macht für mich keinen Sinn.

[astrocreep]

änder mal:

PHP-Code:

        public function XMLLoader(url:String) {
            loadXML(url);
        } 


nach

PHP-Code:

        public function XMLLoader(url:String) {
            super(this);
            loadXML(url);
        } 


[Janoscharlipp]

Den Ladevorgang solltest du definitiv über eine eigene Methode anstoßen, egal ob es nun daran liegt, oder nicht.

Hast du mal versucht, das useWeakReference wegzulassen? (warum ist es überhaupt da?) Vielleicht werden DisplayObject Instanzen später eingesammelt? Nur am rumraten ...

[SpecOps-12]

@Janoscharlipp

Das war der richtige Tip.
Es lag am useWeakReference.

Das hab ich mir angewöhnt, das quasi immer auf true zu setzen.

Edit: Ich versteh auch nicht, warum hier der Listener gekickt wird. Die Referenz, auf die der Listener angemeldet wird, bleibt doch bestehen. Der Garbage-Collector dürfte den Listener doch gar nicht einsammeln.

[Omega Psi]

Der Listener ist nur eine Funktion. Es geht um das aufrufende Objekt, dass dann schon weg ist und der Listener nicht mehr aufgerufen werden kann -> es gibt ja keinen Aufrufer mehr.

[SpecOps-12]

Ach Alter, die Funktion in der Album-Klasse *vor den Kopf hau*
Die Instanz der XMLLoader-Klasse existiert ja nur im Gültigkeitsbereich der Funtion "init" und ist dann natürlich wieder fort.

Ich habs kapiert.

Eine Frage bleibt noch: Warum funktioniert das ganze trotzdem, wenn die XMLLoader-Klasse von Sprite erbt?

[Janoscharlipp]

Hatte oben ja schon vermutet, dass DisplayObject's später eingesammelt werden, vielleicht haben sie intern eine Gnadenfrist von einem Frame (da ist sicher auch irgendein init, added, enterFrame oder sonstwas Listener am Werk)