Im gesamten XML-Tree suchen

[jaygroove]

Hallo!

Zuerst einmal muss ich sagen, dass ich sehr positiv überrascht bin von den Neuerungen die E4X mit sich bringen. Sieht so aus, als könnte ich ab jetzt auf XPath verzichten Es gibt nur eine Sache, die ich bis jetzt noch nicht geschafft habe aber benötigen würde...

Folgende Situation: ich hab ein XML mit
<sitemap> <mainnavi> <subnavi id="#" /> </mainnavi> </sitemap>
usw...

ich brauche eine Methode, mit der ich eine XMLList mit allen subnavi elementen mit einer bestimmten id erstellen kann. Mein Ansatz funktioniert bereits, allerdings nur wenn ich den gesamten Tree angebe, also zb xmlData.sitemap.mannavi.elements() und dann mit if abfrage, ob das attribut übereinstimmt.

es gibt ja auch die Syntax xmlData..subnavi - so würde es funktionieren. doch ich brauche eine Möglichkeit, das 'subnavi' dynamisch durch _xmlNode zu ersetzen.

gibt es da eine möglichkeit? bei xpath ging das nämlich recht easy... danke für eure hilfe!!

PHP-Code:

public function getSpecificXMLNode 
( _xmlNode : String, _attrib : String, _val : String ) : XMLList
{
    
    var itemList : XMLList = xmlData.elements();
    var foundItems : XML = <navigation/>;
    var specList : XMLList = new XMLList();
    var itemCount : uint = itemList.length();
    trace (itemCount + " results found");

    for (var i:uint = 0; i<itemCount; i++)
    {
        if (itemList[i].attribute(_attrib) == _val) 
        {
            foundItems = foundItems.appendChild( itemList[i] );    
        }
    }
    
    specList = foundItems.elements();
    trace (specList);
    return specList; 
    
} 


[hazy fantazy]

myXML..subnavi.(@id==123) liefert dir eine Liste mit allen subnavi Elementen, deren id Attribut den Wert 123 hat.

[jaygroove]

danke, aber das hilft mir in der situation nicht, denn:

var itemList : XMLList = xmlData.._xmlNode.(@_attrib==_val);

funktioniert nicht.. gibts ne möglichkeit, das abgefragte attribut sowie den target node dynamisch einzusetzen, da _xmlNode, _attrib und _val ja parameter der methode sind...

ich würd da gern ne universelle methode draus machen, sofern es möglich ist...

[Omega Psi]

So als fixes Beispiel:

package {
 
    import flash.display.Sprite;
 
    public class E4XExample extends Sprite
    {
 
        private var _xml:XML =  <root>
                                    <nodes>
                                        <node id="001" label="Node 1" />
                                        <node id="002" label="Node 1" />
                                        <node id="003" label="Node 3" />
                                    </nodes>
                                </root>
 
        public function E4XExample()
        {
            super();
            trace(getItemByLabel(_xml, "node", "Node 1"));
        }
 
        public function getItemByLabel(xml:XML, nodeName:String, label:String):XMLList
        {
            return xml.children().child(nodeName).(@label==label);
        }
    }
} 

[jaygroove]

danke Omega!

dein Beispiel funktioniert soweit, allerdings wenn das XML so modifiziert ist:

PHP-Code:

private var _xml:XML =  <root>
                              <nodes>
                                  <node id="001" label="Node 1" />
                                  <node id="002" label="Node 1">
                                      <node id="004" label="Subnode" />
                                      <node id="005" label="Subnode" />
                                  </node>
                                  <node id="003" label="Node 3" />
                              </nodes>
                          </root> 


dann kann man zB nicht nach Node 3 oder Subnode suchen.

Weiters, wäre es super, wenn man den Attribut Namen auch dynamisch verwenden kann, folgender Code funktioniert nicht:

PHP-Code:

    public function E4XXample() 
    {
          super();
          trace(getItemByLabel(_xml, "node", "label", "Node 1"));

    }

    public function getItemByLabel
    (xml:XML, nodeName:String, attribute:String, label:String):XMLList
    {

        return xml.children().child(nodeName).(@attribute==label);

    } 


[Omega Psi]

So in etwa?

package {
 
    import flash.display.Sprite;
 
    public class E4XExample extends Sprite
    {
 
        private var _xml:XML =  <root>
                                    <nodes id="1">
                                        <node id="2" label="Node 1" />
                                        <node id="3" label="Node 1" />
                                        <node id="4" label="Node 1">
                                            <node id="6" label="Node 1" />
                                        </node>
                                        <leave id="5">
                                            <node id="7" label="Node 1" />
                                        </leave>
                                    </nodes>
                                </root>
 
        public function E4XExample()
        {
            super();
            trace(getItemByLabel(_xml, "node", "label", "Node 1").
                    toXMLString());
        }
 
        public function getItemByLabel(xml:XML, nodeName:String,
                attribute:String, value:String):XMLList
        {
            return xml..*.child(nodeName).(@[attribute]==value);
        }
    }
} 

[jaygroove]

aaah, da gibt es auch einen * platzhalter sowie die [] Syntax.. sehr cool - danke!

heisst das jetzt, dass eine XMLList quasi fix mehrere Elemente enthalten muss, ansonsten ist sie leer?

[Omega Psi]

Was meinst du mit fix?

[jaygroove]

Naja es ist so:

wenn ich .toXMLString() verwende, dann sieht man auch Listen mit nur einem Element bei einem trace. Allerdings ist es ja dann wirklich ein String und ich kann auf diesen dann keine XML Eigenschaften ansprechen. Inzwischen bin ich draufgekommen, dass ein trace auf eine XMLListe nur dann etwas anzeigt, wenn mehr wie ein Element vorhanden ist oder zumindest Unterknoten da sind. Aber die Eigenschaften einer XMLList mit nur einem Element sind trotzdem ansprechbar.

Hab ich das soweit richtig verstanden? Ich denke es sollte kein Problem in der Verwendung darstellen, wenn man das bedenkt...

[Omega Psi]

Eine XMLList ist in etwa wie ein Array für XML zu betrachten. Wenn natürlich keine Elemente enthalten sind, macht auch eine String-Representation keinen Sinn -> steht ja nichts drin.

[jaygroove]

ok - danke vielmals für deine hilfe!
jetzt bin ich mit meinem 200. post wieder um einiges klüger geworden