"gemalte" Linie zeichen

[susan00]

Hallo,

gibt es eine Möglichkeit in AS3 eine Linie nicht nur normal zu zeichen sondern in so einem sketched-Stil? Also so dass es so aussieht als ob man es mit der Hand gezeichnet hätte.

[figure8]

hallo im forum!
hmm, auf einfachen weg sicherlich nicht. wie fit bist du denn in actionscript?

[webxvideo]

mit curveTo und einigen Zufallswerten lässt sich da bestimmt was programieren.

[hmpf]

Möglich ist anscheinend alles irgendwie.

[figure8]

Zitat von hmpf

Möglich ist anscheinend alles irgendwie.

ja, das ist mir bis heute auch ein rätsel..

[susan00]

Zu dotted/dashed Lines hatte ich auch etwas gefunden:
AS3 Dotted Line and Dashed Line Class Flash Source Code | Warm Forest Flash Blog

Dachte, dass es so etwas vielleicht auch schon für "sketched"-Lines geben würde.

[salazar]

das thema ist halb so wild
hab dir da mal was schnelles gescriptet... geht sicher auch schöner, aber ich wollt nur schnell ein bsp schreiben.

zum probieren einfach eine leere fla generieren als AS3 projekt und den folgenden code einfügen:

PHP-Code:

//---
            
var line:Sprite = new Sprite();

this.addChild( line );
            
//---        
            
function drawSketchedLine( xS:Number, yS:Number, xE:Number, yE:Number, lineHolder:Sprite, lineThickness:Number, lineColor:uint = 0, lineAlpha:Number = 1, linePartition:int = 10, lineRandomFaktor:int = 5 ):void {

    var dirs:Array = new Array( 1, -1 );
    var dir:Number;

    var a:int = 0;
    var b:int = linePartition - 1;
    
    var xL:Number = xE - xS;
    var yL:Number = yE - yS;
    
    var xF:Number = xL / linePartition;
    var yF:Number = yL / linePartition;
    
    var xP:Number;
    var yP:Number;

    lineHolder.graphics.lineStyle( lineThickness, lineColor, lineAlpha );
    lineHolder.graphics.moveTo( xS, yS );
    
    while ( a++ < b ) {
        
        dir = dirs[ Math.floor( Math.random() * dirs.length ) ];
        
        xS += xF;
        yS += yF;
        
        xP = xS + ( Math.random() * lineRandomFaktor ) * dir;
        yP = yS + ( Math.random() * lineRandomFaktor ) * dir;

        lineHolder.graphics.lineTo( xP, yP );

    }
    
    lineHolder.graphics.lineTo( xE, yE );

}

//---

//zeichnet ein viereck
drawSketchedLine( 50, 50, 300, 50, line, 3, 0x000000, 1, 10, 3 );
drawSketchedLine( 300, 50, 300, 300, line, 3, 0x000000, 1, 10, 3 );
drawSketchedLine( 300, 300, 50, 300, line, 3, 0x000000, 1, 10, 3 );
drawSketchedLine( 50, 300, 50, 50, line, 3, 0x000000, 1, 10, 3 );

//--- 


dieser zeichnet dir ein viereck/rechteck.
wie stark eine linie "unpräzise" sein soll bestimmst du über die beiden parameter linePartition und lineRandomFaktor.
linePartition gibt an in wieviel abschnitte eine linie unterteilt werden soll und mit lineRandomFaktor bestimmst du wie groß die verzerrung an den unterteilten punkten der linie max sein kann.

viel spaß damit... hoffe das ist das was du brauchst

cheers,
sal

edit: hab den code der function nochmal ein bisschen aufgräumt und optimiert.

[susan00]

Super. Vielen vielen Dank. Das funktoniert gut.