Flashgame Safe knacken

[CarterC]

Ich habe für ein Flashgame ein Rätsel programmiert welches ein Tastenfeld mit den Tasten 0-9 hat. Jetzt soll der richtige Code herausgefunden werden.
Bei richtiger Eingabe bleibt die Zahl stehen bei falscher Eingabe kommt "falsch" und man muss von vorne anfangen.
Wenn man aber die erste Zahl 2 mal drückt bleibt die 1 stehen und ich weiss nicht wie ichs ändern kann

Hier mal der Code

public function Safe():void
		{
			Eins.addEventListener(MouseEvent.CLICK, clicked);
			Zwei.addEventListener(MouseEvent.CLICK, clicked);
			Drei.addEventListener(MouseEvent.CLICK, clicked);
			Vier.addEventListener(MouseEvent.CLICK, clicked);
			Fuenf.addEventListener(MouseEvent.CLICK, clicked);
			Sechs.addEventListener(MouseEvent.CLICK, clicked);
			Sieben.addEventListener(MouseEvent.CLICK, clicked);
			Acht.addEventListener(MouseEvent.CLICK, clicked);
			Neun.addEventListener(MouseEvent.CLICK, clicked);	
			
			Text.width = 150;
			Text.height = 40;
			Text.x = 60;
			Text.y = 20;
			addChild(Text);
			format.align = TextFormatAlign.CENTER;
			Text.text = " ";
		}
	public function clicked ( event : MouseEvent ): void { 	
	switch(event.target)
	{
		case Eins:
			Text.text = "1";
			Text.setTextFormat(format);
			if(Text.text == "1")
			{
				Text.text = "Falsch";
			}
			break;
		case Zwei:
				Text.text = "Falsch";
				Text.setTextFormat( format );
			break;
		case Drei:
			if (Text.text == "1")
			{
				Text.text = "13";
				Text.setTextFormat( format );
			}
			else
			{
				Text.text = "Falsch";
				Text.setTextFormat( format );
			}
			break;

usw...

Kann mir jemand sagen wie ich beim 2ten Buttonklick ein falsch ausgeben kann?

Danke und Mfg, Carter

[milchreis]

Und wenn du den Code ändern willst, schreibst du dann diese komplette switch case konstrukt noch mal?

nee

Du solltest deinen Code (welche Reichenfolge der Knöpfe zum Erfolg führt) variabel halten.

//Hier flux ein Schrank aus Berlin

PHP-Code:

package 
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    
    /**
     * Ein Kleiderschrank der Frima Franz Jäger, Berlin für einen gewissen dänischen Herren.
     * @author milchreis
     */
    public class Main extends Sprite 
    {
        private var code:Array;
        private var currentIndex:int = 0;
        
        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }
        
        private function init(e:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);
            // entry point
            
            code = [1, 3, 2, 4, 5, 6, 7, 9, 8];
            
            var s:Sprite;
            for (var i:int = 0; i < 9; ++i)
            {
                s = new Sprite();
                s.graphics.beginFill(0);
                s.graphics.drawRect(0, 0, 30, 30);
                s.graphics.endFill();
                
                s.name = (i+1).toString();
                
                s.x = 10;
                s.y = 10 + i * 40;
                
                addChild(s);
                
                s.addEventListener(MouseEvent.CLICK, buttonclicked);
            }
            
            
        }
        
        private function buttonclicked(e:MouseEvent):void 
        {
            if (code[currentIndex] == int(e.currentTarget.name))
            {
                currentIndex++;
                trace("richtiger button");
            }
            else
            {
                currentIndex = 0;
                trace("falscher button, von vorne anfangen!");
            }
            
            if (currentIndex == code.length) trace ("code komplett richtig");
        }
        
    }
    
} 


Der code ist in meinem Beispiel aus Zahlen aufgebaut.
Jedem Knopf ist eindeutig eine Zahl zugeordnet und in dessem Namen abgelegt.
Das ist nicht sonderlich sauber. In deinem Fall könntest du dort direkt die vorhandenen Instanznamen eintragen und die Referenzen direkt vergleichen.

[CarterC]

Danke, könnte ich auch jeden button der geklickt wurde ausgeben?

[milchreis]

Zitat von CarterC

Danke, könnte ich auch jeden button der geklickt wurde ausgeben?

ja klar, das Prinzip ist das gleiche:
In der Event handler funktion wird über currentTarget auf den aktuell gedrückten button zugegriffen.

Die traces die ich ausgeben lassen seien nur exemplarisch und können natürlich durch das ersetzt werden, was eben passeiren soll, wenn ein richtiger, ein falscher Knopf oder der gesamte Code eingegeben wurden.

[CarterC]

ja aber ich mein das die gedrückten buttons nacheinander ausgegeben werden, also 132 usw

[milchreis]

Zitat von CarterC

ja aber ich mein das die gedrückten buttons nacheinander ausgegeben werden, also 132 usw

Ich verstehe das "aber" nicht. Deine Aussage steht doch in keinem Widerspruch zu dem was ich gesagt habe

Wie gesagt: ersetze oder ergänze die Aufrufe vom jeweiligen trace mit dem, was du tun möchtest.

Möchtest du also die bisherigen korrekten Tastenbetätigungen (also den bisher richtig eingegebenen Teil des Codes) ausgeben, so wäre es am einfachsten du gibstden Code bis zur aktuellen Stelle aus.

Also bei richtigem Knopf, Code bis zur aktuell richtigen Stelle ausgeben, bei falschen Knopf, Textfeld zurücksetzen.

Sollte dir das nicht weiterhelfen, versuche noch mal genau zu beschreiben, wo genau das Problem liegt.

[CarterC]

Mein Problem ist leider offensichtlich das ich zu starke Programmierdefizite hab.
Meine Einschätzung ist das ich die korrekten Tastenkombinationen("e.currentTarget.name") in einen String? übergeben muss der dann abspeichert und bis zur aktuellen Stelle ausgibt? Ich weiss nur nicht wie ich abspeicher bzw den letzten und nicht den aktuellen anspreche.
Sowas wie lastTarget.

[milchreis]

Zitat von CarterC

Meine Einschätzung ist das ich die korrekten Tastenkombinationen("e.currentTarget.name") in einen String? übergeben muss der dann abspeichert und bis zur aktuellen Stelle ausgibt?

Da hast du recht.
Du kannst dir natürlich alle richtig gedrückten Tasten abspeichern.
Wenn dann eine falsche Taste gedrückt wird, leerst du diesen Speicher.
So ein Speicher ließe sich durch eine String Variable realisieren.

ABER:

Das wäre nicht sonderlich clever.
Du hast ja den Code vorliegen! Also musst du dir die richtigen Tasten nicht merken, sondern kannst einfach aus einer aktuell gedrückten, richtigen Taste schlussfolgern, wie weit der Code schon richtig eingegeben wurde.

Ändere also die entsprechende Zeile so ab und führe das ganze aus, probiere herum.

PHP-Code:

trace("richtiger button, code bisher:" + code.join("").substring(0, currentIndex)); 


Die Zeile ist etwas kryptisch, zugegeben:
code -> wir nehmen das Array aus Zahlen, das den bekannten Code enthält
code.join("") -> alle Elemente werden zu einem String verbunden, das würde dem gesamten Code entsprechen, jetzt muss noch der Teil abgeschnitten werden, der noch nicht eingegeben wurde
code.join("").substring(0, currentIndex) -> das passiert hier. substring schneidet bei der aktuellen button nummer ab.

das Ergebnis ist ein String, du kannst diesen also der .text Eigenschaft des Textfeldes zuweisen.

[joeydee]

Wie soll das Spiel eigentlich ablaufen? Man probiert 1-9 für die erste Stelle durch bis er "richtig" sagt, dann dasselbe für die 2. Stelle usw.? So einen Safe hätt ich gern mal vor mir :-)

[milchreis]

Zitat von joeydee

So einen Safe hätt ich gern mal vor mir :-)

Wie gesagt, Franz Jäger

[CarterC]

Bin ja auch nicht beim Sicherheitsdienst angestellt

Danke @ Milchreis auf den join substring kram wär ich im Leben nicht von selbst gekommen