Flas 3d Seiten mit Mausbewegung steuern

[office@el-media]

Wie lautet das Action Script, damit ich ein Bild in Flash CS4 AS3 als 3D Objekt mit der Maus entlang der x und y Achse kippen und drehen kann?
So wie in diesem Beispiel: Soft Whiteroom

Vielleicht kennt jemand ein Tutorial oder einen Anleitungsfilm.

Thx für die Hilfe

[Linowitch]

Wenn Du das mit Flash Hauseigenen mitteln lösen möchtest, dann so

package {
    import flash.display.DisplayObject;
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.geom.Point;
 
    public class Test3D extends Sprite
    {
        //-----------------------------------------------------------------------------------------
        
        private var sp:Sprite;
        
        private const MAX_ROT_X:int = 30;
        private const MAX_ROT_Y:int = 30;
        
        //-----------------------------------------------------------------------------------------
        
        public function Test3D()
        {         
            stage.align = StageAlign.TOP_LEFT;
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.addEventListener(Event.RESIZE, this.resizeHandler);
            stage.addEventListener(MouseEvent.MOUSE_MOVE, this.mouseHandler);
            
            this.sp = new Sprite();
            this.sp.graphics.beginFill(0x0000ff);
            this.sp.graphics.drawRect(-150,-50,300,100);
            this.sp.graphics.endFill();
            
            this.addChild(this.sp);
            this.resizeHandler(null);
        }
        
        //-----------------------------------------------------------------------------------------
        // listener
        //-----------------------------------------------------------------------------------------
        
        private function resizeHandler(e:Event):void
        {
            this.sp.x = stage.stageWidth/2;
            this.sp.y = stage.stageHeight/2;
            this.root.transform.perspectiveProjection.projectionCenter = new Point(stage.stageWidth/2,stage.stageHeight/2);
        }
        
        //-----------------------------------------------------------------------------------------
        
        private function mouseHandler(e:MouseEvent):void
        {
            var dO:DisplayObject = DisplayObject(e.currentTarget);
            var psX:Number = dO.mouseX / stage.stageWidth;
            var psY:Number = dO.mouseY / stage.stageHeight;
            this.sp.rotationX = this.MAX_ROT_X - psY*this.MAX_ROT_X*2;
            this.sp.rotationY = this.MAX_ROT_Y - psX*this.MAX_ROT_Y*2;
        }
        
        //-----------------------------------------------------------------------------------------
    }
} 

Bei komplexeren 3D Geschichten würd ich aber lieber auf Papervision3D, Away3D oder andere zurückgreifen.

[office@el-media]

Zitat von office@el-media

Wie lautet das Action Script, damit ich ein Bild in Flash CS4 AS3 als 3D Objekt mit der Maus entlang der x und y Achse kippen und drehen kann?
So wie in diesem Beispiel: Soft Whiteroom

Vielleicht kennt jemand ein Tutorial oder einen Anleitungsfilm.

Thx für die Hilfe

Vielen Dank für die Antwort, jedoch klappt es bei mir leider nicht.
Ich hab ein Rechteck gezeichnet, dieses als MC gespeichert und das AS
in der selben Szene eine ebene höher eingefügt. Was mach ich wohl falsch?
Hättest Du vielleicht ein Tut für mich?

Liebe Grüße, Joe

[Linowitch]

Sorry, ein Tut hab ich leider nicht.

Du darfst aber das Script nicht in die Zeitleiste kopieren.

Speicher das Script mal in einer eigenen Datei die Du Test3D.as nennst und im selben Verzeichnis wie deine .fla liegt.
Dann gehst Du in die Eigenschaften der Bühne (dort wo die Höhe und Breite der stage festgelegt werden) und schreibst Test3D in das Feld Dokumentklasse:
Alles andere bleibt leer.

Veröffentlichen und fertig.

[office@el-media]

Zitat von Linowitch

Sorry, ein Tut hab ich leider nicht.

Du darfst aber das Script nicht in die Zeitleiste kopieren.

Speicher das Script mal in einer eigenen Datei die Du Test3D.as nennst und im selben Verzeichnis wie deine .fla liegt.
Dann gehst Du in die Eigenschaften der Bühne (dort wo die Höhe und Breite der stage festgelegt werden) und schreibst Test3D in das Feld Dokumentklasse:
Alles andere bleibt leer.

Veröffentlichen und fertig.

Vielen Dank, hat jetzt super funktioniert. Wenn ich jetzt aber Innhalte in dieses Feld schreiben möchte (Texte, Bilder, Buttons) dann kann ich das wohl auch nur in der .as Datei. oder?

LG, Joe

[redwhitedesign]

ich hab auch versucht das in der as datei zu ändern, aber ich seh nicht genau wo, bzw wie. und kann man da eine ebene einfügen, die nicht nur bild ist sondern auch funktionen haben kann?

LG redwhite

[joeydee]

Naja, die komplette Klasse mit Resize und so mag zwar brauchbar sein, war aber für einen Designer vielleicht ein wenig erschlagend für die Beantwortung der Frage Ich ziehe nochmal das Wesentliche raus.
Drei Dinge muss man grundsätzlich machen, um automatisch die Seite mit der Maus zu bewegen: a) einen über AS ansprechbaren Container erstellen (z.B. ein MovieClip), der alle Elemente enthält, b) einen Eventlistener auf die Mausbewegung, c) die beiden Rotationsfunktionen im Eventhandler, in die dann die aktuelle Mausposition eingeht.

Also erstelle einen leeren MC auf der Bühne, benenne ihn "my3DContainer" und ziehe in diesen MC alle Elemente rein die sich mitbewegen sollen.
Der folgende Code (in der Timeline) ist dann erstmal alles was du zum Experimentieren brauchst:

//Eventlistener auf Mausbewegung erstellen
stage.addEventListener(MouseEvent.MOUSE_MOVE,move3D);
 
//Eventhandler
function move3D(event:Event){
    my3DContainer.rotationY=-(stage.mouseX-stage.stageWidth/2)/10;
    my3DContainer.rotationX=(stage.mouseY-stage.stageHeight/2)/10;
    } 

[redwhitedesign]

erstmal vielen dank für deine vereinfachende hilfe ich hab jetzt auf meiner hauptzeitleiste einmal die ebene für as, mit deinem script für den leeren MC. Den hab ich wiederum auf der 2. ebene und my3DContainer genannt. in den MC hab ich dann was reingezogen und das ganze getestet.

jetzt gibt mir der compiler aber für


my3DContainer.rotationY=-(stage.mouseX-stage.stageWidth/2)/10;

und

my3DContainer.rotationX=(stage.mouseY-stage.stageHeight/2)/10;

den fehler

1120: Zugriff auf eine nicht definierte Eigenschaft my3DContainer.

Wärs möglich, dass du mir hier auch weiterhelfen könntest?

LG redwhite

[Linowitch]

Du must für FlashPlayer 10 Veröffentlichen, der 9er hat die 3D Funktionalität noch nicht.

Einstellungen zur Veröffentlichung => Flash => Version => FlashPlayer 10 einstellen.

Vorraussetzung ist mindestens Flash CS4.

[redwhitedesign]

das hab ich jetzt auch probiert, aber es klappt nicht. darf ich eigentlich das as des movieclips in der ebene des mc haben?

was könnte denn nicht definiert sein?

LG und danke für die hartnäckigkeit mir zu helfen

[Linowitch]

Ich glaub am leichtesten ist es wenn Du mal die fla rauf lädst, sonst haben wir hier eine fröhliche Ratestunde.

[redwhitedesign]

hier ist, was ich bis jetzt erstellt habe. nicht viel, hoffentlich findet ihr das was LG

[joeydee]

Hab grad nur CS3 hier, aber ich vermute du hast nur einen Bibliotheksnamen vergeben, nicht den Instanznamen. Denn laut Fehlermeldung kennt AS das Objekt nicht. Markiere mal den MC wenn er auf der Bühne ist und schau mal nach dem Feld "Instanzname", da muss der Name rein.

[Linowitch]

aber ich vermute du hast nur einen Bibliotheksnamen vergeben

Genau so war's!

@redwhitedesign: Besorg Dir bitte ein Buch, oder mach ein paar Tutorials durch, Du hast einen, nicht zu vernachlässigenden, Mangel an Grundlagen.

Ohne Buch/Tut wird das Forum wahrscheinlich dein 2tes zu Hause.

[redwhitedesign]

Ja ich stehe gerade erst am anfang dessen was ich mir noch erarbeiten will. trotzdem großen dank an euch beide(!), immerhin hats jetzt so bei mir funktioniert wies sollte. nen netten abend noch & LG