Externes Bild laden

[Eddie_Mc_Flash]

Heyho!
Gehe ich richtig in der Annahme, dass es keine andere, als die folgende Möglichkeit gibt, ein externes Bild zu laden? (Das sind immerhin 5 Zeilen für ein einziges Bild)

var laden:Loader = new Loader();
var url:URLRequest = new URLRequest();

addChild(laden)
url.url = "pic.jpg";

laden.load(url)

Kann man nicht irgendwie ein Bild in ein Sprite laden?

[Omega Psi]

Ne, die Informationen müssen schon sein.

[Eddie_Mc_Flash]

hmmm, schade...

ok, danke

[Nico B.]

Wieso schade ?

Schreib's in eine Klasse und Du bist bei 2 Zeilen.( Der Aufruf)

[Nico B.]

Da ich es selbst immer doof finde, Tipps ohne konkrete Beispiele zu bekommen, hier mal eine Bitmaploader Klasse:

PHP-Code:

package 
{
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.ProgressEvent;
    import flash.net.URLRequest;
    import flash.events.IOErrorEvent;
    
    public class BitmapLoader extends Sprite
    {
    static public const LOADER_READY:String = "BL_Ready";
    static public const LOADER_STILL_LOADING:String = "BL_IS_LOADING";
    static public const LOADER_FAILED:String = "BL_failed";
            
        
        private var _loader:Loader = new Loader(); 
        private var _image:Bitmap;
        private var _bitmap:BitmapData;
        
        public function BitmapLoader( source:String)
        {            
            _loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onComplete);
            _loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, stillLoading);
            _loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, onError);
            _loader.load( new URLRequest(source) );            
        }
        
        private function stillLoading(e:ProgressEvent):void 
        { 
            dispatchEvent( new ProgressEvent ( LOADER_STILL_LOADING, 
                                              false, false, e.bytesLoaded, e.bytesTotal ) );
        }    
        
        
        private function onComplete(e:Event):void
        {
            _image    = Bitmap(_loader.content);
            _bitmap    = _image.bitmapData; 
            this.addChild(_image);
            dispatchEvent( new Event( LOADER_READY ) );
        }
        
        private function onError( e:IOErrorEvent ):void 
        {
            dispatchEvent( new Event(LOADER_FAILED)); 
        }  
    }
} 


Die klasse ist nich zu 100% von mir, sondern glaube ich vom user "Lukas..." Bin mir aber nicht Sicher.
Habe noch einen Preloader miteingebaut, da ich ihn für mein Projekt gebraucht habe.


Aufrufen tust Du das Ganze so:

PHP-Code:

package 
{
    import flash.display.Sprite;
    import BitmapLoader;
    import flash.events.Event;
    
    import flash.events.ProgressEvent;
    
    
    public class Main extends Sprite
    {
        
        private var _myImage:BitmapLoader;
        private var balken:Sprite;
        private var _percent:Number;

        
        
        public function Main():void
        {    drawBalken();
           
            _myImage              = new BitmapLoader("test.jpg");
            _myImage.addEventListener( BitmapLoader.LOADER_READY, addImage);
            _myImage.addEventListener( BitmapLoader.LOADER_FAILED, showError);
            _myImage.addEventListener( BitmapLoader.LOADER_STILL_LOADING, loadingListener);
        }
        
        
        private function drawBalken():void 
        {
            balken = new Sprite();
            balken.graphics.beginFill(0xFFAAFF);
            balken.graphics.drawRect(0, 0, 200, 2);
            balken.x = 100;
            balken.y = 100;        
            balken.alpha = 0;
            addChild(balken);
        }
        
        
        private function loadingListener(e:ProgressEvent):void 
        {    
            _percent = Math.round((e.bytesLoaded / e.bytesTotal) * 100);
            balken.alpha = 1;
            balken.width = _percent;
            //trace("LOADING");
        }
            
        private function addImage(e:Event):void
        {
           addChild(_myImage); 
           //addChild(e.currentTarget);
        }  
        
        
        private function showError(e:Event):void 
        {
            trace("Fehler");
        }
        
    }
} 


Den Aufruf habe ich eben auf die Schnelle geschrieben, daher verzeiht mir Unsauberheiten. (Bsp. den Balken)

[Eddie_Mc_Flash]

Hey Nico!

Eigentlich hätte mir dein Tip schon gereicht, doch nun hab ich gleich die fertige Klasse auf der Hand.

-> Vielen Dank, sehr nützlich das Ganze

[Nico B.]

hehe, kein Problem.



lg, nico