eventListener mit Parameter?

[burki]

Hallöchen!

Möchte gern das bei click auf ein Thumb der Name des dazugehörgen Ordners an die EventFunktion übergeben wird, aus dem dan die großen Bilder nachgeladen werden. Parameterübergaben sind bei eventlistener aber nicht möglich...oder?
Freue mich über jeden Tipp.

[SpecOps-12]

An einem Event hängt das auslösende Objekt als target oder currentTarget.

Sollen Eigenschaften im Listener abrufbar sein, müssen sie also nur öffentlich im anklickbaren Objekt liegen.

[rendner[i]]

Entweder über das versendete Event auf das jeweilige Objekt zugreifen un die Daten auslesen. Oder dein Objekt fängt intern das Event ab und erstellt ein eigenes mit den benötigten Informationen und versendet dieses.

[mildesign]

Gibt die Daten dem Event in Form eines CustomEvents (push) mit, oder caste dein Target und als Thumb und hol dir die entsprechenden Informationen (pull)

Beispiel für Push:

PHP-Code:

package
{
    import flash.events.Event;
    
    public class ThumbEvent extends Event
    {
        /**
         *  folder of Thumb
         */
        public var folder:String
        
        public function ThumbEvent(type:String, bubbles:Boolean=false, cancelable:Boolean=false)
        {
            super(type, bubbles, cancelable);
        }
        
        /**
         * @inheritDoc
         * 
         */
        
        override public function clone() : Event
        {
            var clonedEvent:ThumbEvent = new ThumbEvent(type,bubbles,cancelable)
                clonedEvent.folder = folder;
            return clonedEvent;
        }
            
    }
} 


Beispiel für Pull:

PHP-Code:

private function Eventhandeler(event:Event):void
{
var thumb:Thumb = Thumb(event.target)
doSomething(thumb.folder);
} 


[Sir Freako]

Du kannst dir auch dein eigenes Event bauen :

PHP-Code:

package mat3d.yugopReel.model.events {
    import flash.events.*;
    public class ScrollReelEvent extends Event {
        public static const DEFAULT_NAME : String = "com.mat3d.yugopReel.model.events.ScrollReelEvent";
        // event constants
        public static const ON_CLICKED : String = "onClicked";
        public static const ON_MOVED : String = "onMoved";        
        public var params : Object;        

        public function ScrollReelEvent($type : String, $params : Object, $bubbles : Boolean = false, $cancelable : Boolean = false) {

            super($type, $bubbles, $cancelable);
            this.params = $params;
        }

        public override function clone() : Event {

            return new ScrollReelEvent(type, this.params, bubbles, cancelable);
        }

        public override function toString() : String {

            return formatToString("CustomEvent", "params", "type", "bubbles", "cancelable");
        }
    }
} 


im aufruf sowas :

PHP-Code:

        public function clickHandler(id : String,selector : String) {
            REEL.dispatchEvent(new ScrollReelEvent(ScrollReelEvent.ON_CLICKED, {param1: id, param2: selector})); 
        }

        public function moveHandler(id : String,selector : String) {
            REEL.dispatchEvent(new ScrollReelEvent(ScrollReelEvent.ON_MOVED, {param1: id, param2: selector})); 
        }

xt.addEventListener(ScrollReelEvent.ON_MOVED, doTestCase);
xt.addEventListener(ScrollReelEvent.ON_CLICKED, doTestCase);


function doTestCase($e:ScrollReelEvent) {
    switch ($e.type) {
        case "onClicked" :
            trace("TYPE: " + $e.type );
            break;
        case "onMoved" :
            trace("TYPE: " + $e.type );
            break;
    }
    //trace("TYPE: " + $e.type + "\nTARGET: " + $e.target + "\nFIRST CUSTOM PARAM: " + $e.params.param1 + "\nSECOND CUSTOM PARAM: " + $e.params.param2);
} 


[burki]

Danke!
Blick bei euren Antworten nciht ganz durch
Also ihr schlagt folgendes vor, wenn ich das richtig verstehe. Zwei eventListener die von einer Funktion abgefangen werden.

[Sir Freako]

hi Burki ,

das sollte dir eigentlich nur veranschaulichen wie du mehrere EventTypen
in deinem Custom Event abhandeln kannst

Dir gings ja eher um die parameter oder

[burki]

Dankeschön! Ganz lieb