Event-Funktion mit Parametern

[Vokator]

Stellt euch vor ihr hättet einen Eventlistener mit einer Funktion:

addEventListener(Event.ENTER_FRAME, funktion);

Die Funktion hat aber auch mehrere Parameter:

funktion(evt:Event,p1:Number,p2:Number){

}

IST ES MÖGLICH PARAMETER WEITERZUGEBEN ?
Wie hier :

addEventListener(Event.ENTER_FRAME, funktion(parameter1,parameter2));

Es funktioniert aber auch rein garnichts
Wenn es nicht möglich ist...
Gibt es einen Workaround?

Greets
Vokator

[Vokator]

Hilfe

[figure8]

warum willst du bei 'nem enterframe parameter mitgeben? dann kann man sich nen workaround überlegen.
ps: um halb5 schlafen normale menschen. da hilft auch kein bold "hilfe". und benutz bitte die code-tags.

[tazka]

mahlzeit...

soweit ich weiß funktioniert die parameter übergabe folgendermaßen:

addEventListener ( Event.ENTERFRAME, function () : void { funktion(p1,p2,p3); } );

function funktion (p1:*,p2:*,p3:*) : void {

}


vielleicht hilft dir das.

tschuuus

[[RK]]

Ansich sollte es eigentlich immer möglich sein auch andere Wege zu finden. Die wohl am häufigsten passende wäre die target Eigenschaft des ohnehin übergebenen Event-Object zu verwenden um das Dispatcher-Object zu erhalten, welches wiederum Eigenschaften bereithält auf die man öffentlich zugreifen kann. So kannst du innerhalb des Callbacks auf Eigenschaften zugreifen, ohne den Dispatcher explizit zu kennen. (Typecasten musst du evt.)

Andere Möglichkeit wäre (und das ist wohl die hübschere) ein eigenes Event zu schreiben, welches die zu übergebenen Eigenschaften bereithält. Das eigene Event kann ja auch von den vorgegebenen Events erben (MouseEvent zb)

Ansonnsten könnte man sich sowieso einen eigenes langsames EventHandling-System basteln, wo man dann allerdings auch der Callback-Funktion Parameter übergeben kann x)

[Vokator]

test

[Vokator]

Zitat von [RK]

Ansich sollte es eigentlich immer möglich sein auch andere Wege zu finden. Die wohl am häufigsten passende wäre die target Eigenschaft des ohnehin übergebenen Event-Object zu verwenden um das Dispatcher-Object zu erhalten, welches wiederum Eigenschaften bereithält auf die man öffentlich zugreifen kann. So kannst du innerhalb des Callbacks auf Eigenschaften zugreifen, ohne den Dispatcher explizit zu kennen. (Typecasten musst du evt.)

Andere Möglichkeit wäre (und das ist wohl die hübschere) ein eigenes Event zu schreiben, welches die zu übergebenen Eigenschaften bereithält. Das eigene Event kann ja auch von den vorgegebenen Events erben (MouseEvent zb)

Ansonnsten könnte man sich sowieso einen eigenes langsames EventHandling-System basteln, wo man dann allerdings auch der Callback-Funktion Parameter übergeben kann x)

Zitat von tazka

mahlzeit...

soweit ich weiß funktioniert die parameter übergabe folgendermaßen:

addEventListener ( Event.ENTERFRAME, function () : void { funktion(p1,p2,p3); } );

function funktion (p1:*,p2:*,p3:*) : void {

}


vielleicht hilft dir das.

tschuuus

Zitat von figure8

warum willst du bei 'nem enterframe parameter mitgeben? dann kann man sich nen workaround überlegen.
ps: um halb5 schlafen normale menschen. da hilft auch kein bold "hilfe". und benutz bitte die code-tags.

Okay ein BEISPIEL :

Loader laden ein Bilder aus einem Array

loader.addEventListener(Event.COMPLETE, zeigeBild);

woher soll die funktion zeigeBild wissen welches Bild genau gezeigt werden soll?
Was ist wenn das Laden der Bilder unterschiedlich ist bei jedem Bild
und das letzte oder das mittlere vorher COMPLETE sagt...

Man bräuchte etwas wie :

loader.addEventListener(Event.COMPLETE, zeigeBild(bildID));

function zeigeBild(bildID){
// ich weiß welches bild ich anzeigen soll(bildID);
}

PRAXISBEISPIEL :

www.aeiko.net

siehe die thumbnails werden getrennt geladen <<<

[[RK]]

var myloader:Loader = new Loader();
    myloader.contentLoaderInfo.addEventListener( Event.INIT, this.onComplete, false, 0, true );
    
 
private function onComplete( a_event:Event ):void
{
    // Direkt:
    var loaded_data_direct:DisplayObject = myloader.content; 
    
    // Indirekt:
    var loader:Loader = a_event.target as Loader;
    var loaded_data_target:DisplayObject = loader.content;
} 

Du könntest aber auch den Loader in einer eigenen Klasse kapseln, welches wiederum ein eigenes Event dispatched das die Referenz zum geladene DisplayObject als Eigenschaft besitzt. Diese eigene Event-Klasse kann dann auch weitere Informationen bereithalten die pro geladenem Bild relevant erscheinen. Zb. Titel, Beschreibung oder ähnliches.

Aber wie gesagt funktioniert es immer ohne Parameterübergabe.
Zumin. behaupte ich das jetzt mal aalglatt. x)

[figure8]

Zitat von Vokator

Okay ein BEISPIEL :

Loader laden ein Bilder aus einem Array

loader.addEventListener(Event.COMPLETE, zeigeBild);

woher soll die funktion zeigeBild wissen welches Bild genau gezeigt werden soll?

kuckst du hier:
http://www.flashforum.de/forum/showt...98#post1858198

[Vokator]

Zitat von figure8

kuckst du hier:
http://www.flashforum.de/forum/showt...98#post1858198

hey da gehts garnicht darum
ich habe ja bereits eine slideshow
sie lädt aber jede thumb NACHEINANDER

d.h COMPLETE => nächstesBild => COMPLETE => nächstesBild...

aber wie kriegt man das so hin :

lade alle bilder gleichzeitig();
gebe jedem loader eventlistener
und die funktion revealImage

aber jedes mal wenn COMPLETE auftritt
zeigt er das erst gestartete bild
auch wenn es nicht KOMPLETT GELADEN IST

weil er ja nicht weiß welches bild genau geladen wurde

deswegen braucht man etwas wie...

revealImage(imageID);

aber das kann man nicht in den (Event.COMPLETE, "...()");
reintun oder?

[maschka]

Zitat von Vokator

Okay ein BEISPIEL :

Loader laden ein Bilder aus einem Array

loader.addEventListener(Event.COMPLETE, zeigeBild);

woher soll die funktion zeigeBild wissen welches Bild genau gezeigt werden soll?
Was ist wenn das Laden der Bilder unterschiedlich ist bei jedem Bild
und das letzte oder das mittlere vorher COMPLETE sagt...

Man bräuchte etwas wie :

loader.addEventListener(Event.COMPLETE, zeigeBild(bildID));

function zeigeBild(bildID){
// ich weiß welches bild ich anzeigen soll(bildID);
}

PRAXISBEISPIEL :

www.aeiko.net

siehe die thumbnails werden getrennt geladen <<<

Also dein Beispiel könntest du mit einem CustomEvent-lösen: CustomEvent in AS3

dem kannst du ja beliebige Eigenschaften einbauen, wie bspw. die Bildnummer. Du darfst dann natürlich nicht auf COMPLETE, sondern nur auf deinen eigenen CustomEvent hören, den du auch selbst werfen musst.

[darobbe]

IST ES MÖGLICH PARAMETER WEITERZUGEBEN ?
Wie hier :

addEventListener(Event.ENTER_FRAME, funktion(parameter1,parameter2));

jo, isses mit ner anonymen funktion, die du als proxy verwendest, wie tatzka schon angedeutet hat, allerdings muss die anonyme funktion die parameter-signatur des events realiseren.. also so:

addEventListener( Event.Complete, function ( e : Event ) : void { handlerFunction( e, p1, p2, p3); } );

public function handlerFunction( e : Event, p1:*, p2:*,p3:* ) : void {
}
}

zu beachten ist, das du in der anonymen funktion nicht auf this zugreifst ( da anderer kontext ).

diesem konstrukt sollte man aber custom-events aufgrund der besseren lesbarkeit vorziehen.

gruss,
robbe.

[Vokator]

Zitat von darobbe

jo, isses mit ner anonymen funktion, die du als proxy verwendest, wie tatzka schon angedeutet hat, allerdings muss die anonyme funktion die parameter-signatur des events realiseren.. also so:




zu beachten ist, das du in der anonymen funktion nicht auf this zugreifst ( da anderer kontext ).

diesem konstrukt sollte man aber custom-events aufgrund der besseren lesbarkeit vorziehen.

gruss,
robbe.

GENAU DAS HAB ICH GESUCHT !
Danke Genie ;D !

[sebastian]

Wie schon gesagt wurde:

-Ein eigenes Event, das eine entsprechende Eigenschaft hat
-Den Wert irgendwo im Model speichern und über das Event nur informieren,
dass sich was geändert hat

[Omega Psi]

Anonyme Funktionen sind schlecht... die Listener wird man nicht mehr los -> schlechter Programmierstil.

package
{
 
    import flash.display.Sprite;
    import flash.events.IEventDispatcher;
    
    import fs.examples.events.DataEvent;
 
    public class SimpleEventExample extends Sprite
    {
 
        public function SimpleEventExample()
        {
            super();
            addEventListener(DataEvent.DATA, dataEventListener);
            dispatchEvent(new DataEvent(DataEvent.DATA, 1, 2, 3));
        }
 
        protected function dataEventListener(event:DataEvent):void
        {
            IEventDispatcher(event.target).removeEventListener(
                    DataEvent.DATA, dataEventListener);
            switch(event.type)
            {
                case DataEvent.DATA:
                {
                    processData(event.argument1, event.argument2,
                            event.argument3);
                }
            }
        }
 
        protected function processData(argument1:int, argument2:int,
                argument3:int):void
        {
            trace("argument1:", argument1, ", argument2:", argument2,
                ", argument3:", argument3);
        }
    }
} 

package fs.examples.events
{
 
    import flash.events.Event;
 
    public class DataEvent extends Event
    {
 
        public static const DATA:String = "data";
 
        private var _argument1:int;
 
        private var _argument2:int;
 
        private var _argument3:int;
 
        public function DataEvent(type:String, argument1:int, argument2:int,
                argument3:int, bubbles:Boolean=false,
                cancelable:Boolean=false)
        {
            super(type, bubbles, cancelable);
            _argument1 = argument1;
            _argument2 = argument2;
            _argument3 = argument3;
        }
 
        public function get argument1():int
        {
            return _argument1;
        }
 
        public function get argument2():int
        {
            return _argument2;
        }
 
        public function get argument3():int
        {
            return _argument3;
        }
    }
}