eigener Eventhandler

[1tomtom]

Hallo allerseits,
ich möchte einen eigenen Eventhandler für ein Drap und Drop Event erstellen. Aber leider funktioniert das nicht so wie ich mir das denke. Das Event wird zwar getriggert, aber der handler im der Dokumentenklasse wird nicht aufgerufen. was mach ich falsch?

Hier der Code, im Anhand findet sich das ganze Kunstwerk.

Danke im voraus,
thomas

// Eventklasse
public class DragEvent extends Event{
	public static const START_DRAG_EVENT:String = "START_DRAG_EVENT";
	public static const STOP_DRAG_EVENT:String = "STOP_DRAG_EVENT";

	public var data;

	public function DragEvent(type:String, data) {
		super(type);
		this.data = data;
		trace('Event:'+type);
	}
	
	public override function clone():Event{
		return new DragEvent(this.type,this.data);
	}
	
	public override function toString():String{
		return formatToString("DragEvent", "type", "bubbles", "cancelable", "eventPhase", "data");
	}

}
// Klasse des MovieClip der über die Bühne gezogen werden kann
public class Kasten extends MovieClip
{
	public function Kasten() 
	{
		this.addEventListener(MouseEvent.MOUSE_DOWN, this.startDragEvent);
		this.addEventListener(MouseEvent.MOUSE_UP, this.stopDragEvent);

	}
	private function startDragEvent(event:MouseEvent):void {
		this.startDrag();
		var dragEvent:DragEvent=new DragEvent(DragEvent.START_DRAG_EVENT, this)
		this.dispatchEvent(dragEvent);
	}

	private function stopDragEvent(event:MouseEvent):void {
		this.stopDrag();
		var dragEvent:DragEvent=new DragEvent(DragEvent.STOP_DRAG_EVENT, this)
		this.dispatchEvent(dragEvent);
	}
}

// Dokumentenklasse
public class MainClass extends MovieClip{
	public function MainClass() {
		this.addEventListener(DragEvent.START_DRAG_EVENT, this.handleStartDrag);
		this.addEventListener(DragEvent.STOP_DRAG_EVENT, this.handleStopDrag);
	}
	
	private function handleStartDrag(event:DragEvent){
		trace("Eventhandler MainClass:Sprite wurde hier angefassr:"+event.data.x);
	}
	private function handleStopDrag(event:DragEvent){
		trace("Eventhandler MainClass:Sprite wurde hier losgelassen:"+event.data.x);
	}
}

[the binary]

leider fehlt die .fla in deinem zip..

[1tomtom]

Zitat von the binary

leider fehlt die .fla in deinem zip..

ups, doch nur ein teilkunstwerk ... dann jetzt aber .. ;-)

[herrmannplatz]

also ich denke du musst der instanz von dem kasten den eventListener adden nicht der MainClass. Die MainClass dispatcht ja nicht das event. Da gibt es also nichts zu hören.

hoffe es hilft

ps: also gib dem MovieClip einen Instanznamen und dann kannst du ihn so ansprechen

mcBox.addEventListener(DragEvent.START_DRAG_EVENT, this.handleStartDrag);
mcBox.addEventListener(DragEvent.STOP_DRAG_EVENT, this.handleStopDrag);

[1tomtom]

hmm, wenn ich doch aber der MainClass ein Event auffangen und behandeln möchte, welches durch das loslassen oder anfassen eines Kasten-Objektes ausgelöst wird? Wie stelle ich das an, dass in in einer Klasse ein Event aulöse, welches ich in einer anderen Klasse behandle?

[Linowitch]

suchst Du das?

package
{
    import flash.events.Event;
    import flash.events.EventDispatcher;
    
    public class EventWerfen extends EventDispatcher
    {
        public function EventWerfen()
        {
            
        }
        
        public function wirf():void
        {
            this.dispatchEvent(new Event("ichFliege"));
        }
    }
} 

package
{
    import flash.display.MovieClip;
    import flash.events.Event;
    
    public class main extends MovieClip
    {
    
        public function main()
        {
            var ew:EventWerfen = new EventWerfen();
            ew.addEventListener("ichFliege", this.fangen);
            ew.wirf();
        }
        
        private function fangen(e:Event):void
        {
            trace("gefangen");
        }
    }
} 

[Linowitch]

und so wenn du auch noch eine eigene Eventklasse brauchst, z.B. um Werte zu übergeben.

package
{
    import flash.events.Event;
    
    public class EventWerfenEvent extends Event
    {
        
        public static const ICH_FLIEGE:String = "ichFliege";
        private var _weite:Number;
        
        public function EventWerfenEvent(type:String, weite:Number, bubbles:Boolean=false, cancelable:Boolean=false)
        {
            this._weite = weite;
            super(type, bubbles, cancelable);
        }
        
        public function get weite():Number { return this._weite; }
    }
} 

package
{
    import flash.events.Event;
    import flash.events.EventDispatcher;
    
    public class EventWerfen extends EventDispatcher
    {
        public function EventWerfen()
        {
            
        }
        
        public function wirf(m:Number):void
        {
            this.dispatchEvent(new EventWerfenEvent(EventWerfenEvent.ICH_FLIEGE, m));
        }
    }
} 

package
{
    import flash.display.MovieClip;
    import flash.events.Event;
    
    public class main extends MovieClip
    {
    
        public function main()
        {
            var ew:EventWerfen = new EventWerfen();
            ew.addEventListener(EventWerfenEvent.ICH_FLIEGE, this.fangen);
            ew.wirf(30.5);
        }
        
        private function fangen(e:EventWerfenEvent):void
        {
            trace(e.weite + "m weit geworfen");
        }
    }
} 

[herrmannplatz]

hmm jetzt bin ich etwas irritiert wo es hingehen soll.

du hast doch schon die Kastenklasse die DragEvents feuert. kannst ja auch instanzen der kastenklasse erstellen.

PHP-Code:

package{
    import flash.display.*;
    import flash.events.*;

    
    public class MainClass extends MovieClip{
        private var mcKasten : Kasten;
        
        public function MainClass() {
            mcKasten = new Kasten();
            mcKasten.addEventListener(DragEvent.START_DRAG_EVENT, this.handleStartDrag);
            mcKasten.addEventListener(DragEvent.STOP_DRAG_EVENT, this.handleStopDrag);
            this.addChild(mcKasten);
        }
        
        private function handleStartDrag(event:DragEvent){
            trace("Eventhandler MainClass:Sprite wurde hier angefassr:"+event.data.x);
        }
        private function handleStopDrag(event:DragEvent){
            trace("Eventhandler MainClass:Sprite wurde hier losgelassen:"+event.data.x);
        }
    }
} 


mensch hab ich auch mal den scriptkasten benutzt.

[Linowitch]

Sorry, wollte niemanden verwirren, meine Antwort kam auf Grund des folgenden Satzes.

Wie stelle ich das an, dass in in einer Klasse ein Event aulöse, welches ich in einer anderen Klasse behandle?

ist auch nur ein Beispiel wie man das macht, ohne Bezug zum eigentlichen Thema

[1tomtom]

Zitat von herrmannplatz

hmm jetzt bin ich etwas irritiert wo es hingehen soll.

du hast doch schon die Kastenklasse die DragEvents feuert. kannst ja auch instanzen der kastenklasse erstellen.

PHP-Code:


mcKasten.addEventListener(DragEvent.START_DRAG_EVENT, this.handleStartDrag);
mcKasten.addEventListener(DragEvent.STOP_DRAG_EVENT, this.handleStopDrag); 


ja, das wars. ich weise also den eventListener dem Objekt zu, welches das Event wirft, mit der Methode der Hauptklasse als Parameter, welche das Event behandelt. Mein Irrtum war, dass das Event global, sprich in der MainClass, durch Hinzufügen eines Handlers erkannt werden kann.

und nun werd ich mir noch der Vollständigkeit halber das Ding mit einer seperaten EventDispatcher-Klasse anschauen :-).

Danke erstmal für die Klarsicht!

Gruß,
Thomas