Eigenen Event auslösen?

[silentx]

Weiss jemand wo ich Informationen finde wie ich eigene Events auslösen kann?

Ich möchte so etwas nutzen:

 myCl:myclass = new myclass();
 myCl.addEventListener(Event.Complete, goOnFunction);

aber irgendwie weiss ich nicht wie ich dies in myclass implementieren muss?

[Omega Psi]

Bitte etwas an die Konventionen für ActionScript halten. Das macht die Sache einfacher zu lesen.

package
{
 
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.IEventDispatcher;
    
    import fs.examples.events.MyDispatcher;
    import fs.examples.events.events.MyEvent;
 
    public class Events extends Sprite
    {
 
        public function Events()
        {
            var dispatcher:MyDispatcher = new MyDispatcher();
            dispatcher.addEventListener(MyEvent.MY_TYPE, eventListener);
            dispatcher.someAsyncMagic();
        }
 
        protected function eventListener(event:Event):void
        {
            trace("eventListener");
            IEventDispatcher(event.target).removeEventListener(
                    MyEvent.MY_TYPE, eventListener);
        }
    }
} 

package fs.examples.events
{
 
    import flash.events.EventDispatcher;
    
    import fs.examples.events.events.MyEvent;
 
    [Event(name="myType", type="fs.examples.events.events.MyEvent")]
 
    public class MyDispatcher extends EventDispatcher
    {
 
        public function MyDispatcher()
        {
            super();
        }
 
        public function someAsyncMagic():void
        {
            dispatchEvent(new MyEvent(MyEvent.MY_TYPE));
        }      
    }
} 

package fs.examples.events.events
{
 
    import flash.events.Event;
 
    public class MyEvent extends Event
    {
 
        public static const MY_TYPE:String = "myType";
 
        public function MyEvent(type:String, bubbles:Boolean=false,
                cancelable:Boolean=false)
        {
            super(type, bubbles, cancelable);
        }
    }
} 

Das ist nur ein kleines Beispiel.

[silentx]

Danke für die Informationen
Nur glaube ich das ich mich nicht klar ausgedrückt habe, ich wollte nur
wissen wie ich in einer Klasse einen Event aktivieren kann. Dies kann man
mit ActionScript 3 anscheinend sehr einfach machen (Anhand deines Beispiels
Omega). Ist auch gleich gut um meine speziellen Events zu erstellen.

Danke vielmals

[headkit]

sieht sehr interessant aus.
ich muss auch endlich mal rausfinden, was bubbles sind und wie man eine as3-anwendung optimal designed.

hat jemand ne liste von tutorials oder gleich ein kleines feines video-tut?

[oppec]

www.gotoandlearn.com

find ich schön

[schinki_]

Vielleicht kann das ja helfen.
Siehe Anhang....habe nicht kommentiert da der Code sooo einfach ist das es jeder mit ein wenig Lust zur Sache verstehen kann...
Einfach starten und ins Ausgabefenster schauen....


lg

[hmpf]

Ein Event löst man so aus:

dispatchEvent(new Event('myEventType')); 

Was bubbles sind, ist hier ganz gut erklärt: http://www.adobe.com/devnet/actionsc...dling_as3.html

[headkit]

jups, vielen dank!
hatte mich über WE auch schon etwas eingelesen...