Drag/Drop mit Objekten aus Array

[Louve]

Hallo,
ich habe momentan ein Problem mit Objekten aus einem Array und hoffe ihr könnt mir helfen.
Ich möchte die Objekte aus einem Array per Drag/Drop verschieben können. Allerdings ist wichtig um welches Objekte innerhalb des Arrays es sich handelt, also der aktuelle Ort eines jeden Objektes ist wichtig.


Bisher sieht mein Code für das Drag/Drop folgendermaßen aus:

private function viereckeF (e:TimerEvent):void {

for (var i:Number=0; i<eckArray.length; i++){

(eckArray[i] as MovieClip).buttonMode = true;
(eckArray[i] as MovieClip).addEventListener(MouseEvent.MOUSE_DOWN, startDragging);
(eckArray[i] as MovieClip).addEventListener(MouseEvent.MOUSE_UP, stopDragging);

function startDragging(event:MouseEvent):void
{ offsetX = event.stageX - (eckArray[i] as MovieClip).x;
offsetY = event.stageY - (eckArray[i] as MovieClip).y;
stage.addEventListener(MouseEvent.MOUSE_MOVE, dragObject);
}

function stopDragging(event:MouseEvent):void
{
stage.removeEventListener(MouseEvent.MOUSE_MOVE, dragObject);
}

function dragObject(event:MouseEvent):void
{
(eckArray[i] as MovieClip).x = event.stageX - offsetX;
(eckArray[i] as MovieClip).y = event.stageY - offsetY;
event.updateAfterEvent();
}
}
}



Dies funktioniert aber leider nicht und es kommt wenn ich ein Objekt anklicke zu folgender Fehlermeldung:TypeError: Error #1009: Der Zugriff auf eine Eigenschaft oder eine Methode eines null-Objektverweises ist nicht möglich.
at MethodInfo-356()
Wäre echt super wenn mir jemand einen Tipp geben könnte.
Vielen Dank schonmal!

[Martin Kraft]

Hallo und willkommen im FlashForum!

• Wie wird viereckeF aufgerufen? Wenn das wirklich ein Timer-Event-Listener ist, setzt Du die Listener permanent neu!
  
  
• Funktionen sollten nicht in anderen Funktionen und erst recht nicht in for-Schleifen deklariert werden.
  
  
• Die Variable i enthält in den Unterfunktionen nicht mehr den erwarteten Wert.
  
  
• Statt permanent ein Array-Element zu casten, sollte man mit einer lokalen Variablen vom gewünschten Typ arbeiten.

Hier mal Dein entsprechend korrigierter Code:

PHP-Code:

var objectToDrag:DisplayObject;
var offsetX:Number;
var offsetY:Number;

private function viereckeF (e:TimerEvent):void {
    for (var i:Number=0; i<eckArray.length; i++){
        var mc:MovieClip = eckArray[i] as MovieClip;
        mc.buttonMode = true;
        mc.addEventListener(MouseEvent.MOUSE_DOWN, startDragging);
        mc.addEventListener(MouseEvent.MOUSE_UP, stopDragging);
    }
}

private function startDragging(event:MouseEvent):void {
    objectToDrag = event.currentTarget as DisplayObject;
    
    offsetX = event.stageX - objectToDrag.x;
    offsetY = event.stageY - objectToDrag.y;
    stage.addEventListener(MouseEvent.MOUSE_MOVE, dragObject);
}

private function stopDragging(event:MouseEvent):void {
    stage.removeEventListener(MouseEvent.MOUSE_MOVE, dragObject);
}

private function dragObject(event:MouseEvent):void {
    objectToDrag.x = event.stageX - offsetX;
    objectToDrag.y = event.stageY - offsetY;
    event.updateAfterEvent();
} 


P.S.: Wenn Du Deinen Code als [PHP] markierst, ist er besser lesbar!

[Louve]

Hallo Martin,
erstmal vielen Dank! Jetzt funktioniert es super

Ja ich rufe die Funktion wirklich mit einem Timer auf das ist aber bisher eher provisorisch. Eigentlich möchte ich sie in eine Funktion setzten, welche nur bei Aktualisierungsbedarf aufgerufen wird um für neue Objekte Listener zu erstellen. Diese Funktion hab ich bisher nur noch nicht erstellt.

Vielen Dank auch für die anderen Tipps!