DisplayObject in Array wieder loswerden?

[AIR-Fan]

Guten Tag.

Ich habe eine eigene Klasse geschrieben. In dieser wird ein Bild geladen, in die Bühne geaddet und die y-Koordinate des Bildes verringert sich immer um 7.

Da ich die einzelnen Bilder später ansprechen möchte, werden sie alle in ein Array gepusht:

PHP-Code:

    for (var i:int = 0; i <= maxx; i++)
    {
        mk = new MeineKlasse();
        Ary.push(mk);
        addChild(Ary[i]);
    } 


Da dadurch viele Objekte entstehen, und sie nach einer gewissen Zeit sowieso nicht mehr zu sehen sind, würde ich sie gerne entfernen.
Es klappt weder Ary = new Array(); (hat keinen Effekt) noch removeChild(Ary[i]) (ArgumentError: Error #2025: The supplied DisplayObject must be a child of the caller).

Gibt es da noch eine Möglichkeit?
Das ganze ist eine AIR for iOS-Anwendung.

MfG,
AIR-Fan

[Martin Kraft]

Erst mal das Übliche : Variablen klein schreiben, deklarieren, typisieren und dynamische Zugriffe vermeiden...

import flash.display.DisplayObject;
 
var ary:Array;
var mk:DisplayObject;
 
for (var i:int = 0; i <= maxx; i++) {
    mk = new MeineKlasse();
    ary.push(mk);
    addChild(mk);
} 

Und zum Löschen aus Array und DisplayList kannst Du dann diese Funktion verwenden:

import flash.display.DisplayObject;
 
function removeFromArrayAndDisplayList(i:uint, a:Array):DisplayObject {
    var dob:DisplayObject = a[i] as DisplayObject;
    if (dob) {
        if (dob.parent) dob.parent.removeChild(dob);
        a.splice(i, 1);
    }
    return dob;
}
 
removeFromArrayAndDisplayList(ary, 0); 

[AIR-Fan]

Tja, danke, allerdings wüsste ich dann gerne, wieso das hier nicht funktioniert:

PHP-Code:

for(var i:int = 0; i<maxx;i++)
{
    ary[i].parent.removeChild(ary[i]);                               // Zeile 97
    ary.splice(i, 1);
} 


Es kommt:

TypeError: Error #1010: A term is undefined and has no properties.
	at Function/<anonymous>()[***_fla.MainTimeline::frame2:97]

Probiere ich es ohne Array.splice(), geht es zwar, allerdings wird das Objekt dann ja vom Array nicht enfernt:

PHP-Code:

for(var i:int = 0; i<maxx;i++)
{
    ary[i].parent.removeChild(ary[i]);
}
// Funktioniert 


Das sog. "Übliche" hatte ich in der *.fla sogar richtig, nur hier nicht, da ich die Variablennamen umgeändert hatte, da sie sonst zu uneindeutig gewesen wären.

MfG,
AIR-Fan

[hgseib]

// for(var i:int = 0; i<maxx;i++)
for(var i:int = maxx-1; i>=0; i--)

beim löschen musst du rückwärts zählen, weil spätestens nach dem ersten löschvorgang ist maxx nicht mehr vorhanden.

// grundsätzlich ist es auch nie ein fehler mal was zu testen. z.b.
if (i<ary.length && ary[i] && ary[i].parent) ary[i].parent.removeChild(ary[i]);
// ok, so ist es natürlich übertrieben (halt zum zeigen), aber nicht falsch.

[Omega Psi]

Ich würde es so machen:

function removeChildren(array:Array):void
{
  if (!array || array.length == 0) return;

  for each(var d:DisplayObject in array)
  {
    if (d && d.parent) d.parent.removeChild(d);
  }

  array.length = 0;
}

Ist das gleiche in rot, nur etwas weniger abfragen, Zähler und so ...

[_malte]

oder

PHP-Code:

function removeChildren(array:Array):void {
  while(array && array.length) {
    var d:* = array.pop();
    if (d is DisplayObject && d.parent) d.parent.removeChild(d);
  }
}