dispatch und listen über die stage?

[litchi]

Hallo,

ich hatte versucht ein Event aus meiner Hauptklasse zu dispatchen ...

stage.dispatchEvent(new Event("newPosition"))

.. und diesen in einer Klasse (die für Starling benutzt wird) von der stage aus über einen Listener zu empfangen.

stage.addEventListener("newPosition",newPos);

Dieser kommt jedoch irgendwie nicht an. Verstehe ich hier was falsch? Ich hab den Weg über die Stage genommen weil mir die Struktur zur Starling steuernden Klasse nicht klar war (Klassen-Typ wird an Starling Objekt bei der Erzeugung übergeben).

Danke für jede Hilfe

litchi

[Martin Kraft]

Wahrscheinlich dispatchst Du das Event bevor der Listener registriert wurde?!

[litchi]

Leider nicht, den Listener gibt es vor dem dispatchen. Hab mal ein Trace an der Stelle eingefügt, listener taucht zuerst auf. Die Events beruhen momentan auch noch auf Mausbewegungen, werden also permanent geschickt.

Die Empfängerklasse ist ein Starling-sprite. Kann das zu Problemen führen? Nun haben die Starling Klassen ja nicht so die direkte Verbindung zu normalen Flash DisplayObjekten .

[milchreis]

stage in der Dokumentklasse != stage in Starling

Doku:
Starling Framework Reference

[litchi]

Sehe gerade es wird auch die Starling Event Klasse beim Empfänger benutzt. *Kopfkratz* Mal sehen wie ich da hin komme.

Edit: ah ok, andere Stage Klasse. Muss ich mir da so was wie ne Event-Klasse basteln damit die kommunizieren können?

[Martin Kraft]

Zitat von litchi

ah ok, andere Stage Klasse. Muss ich mir da so was wie ne Event-Klasse basteln damit die kommunizieren können?

Nö, das hat mit dem Event selbst nichts zu tun, sondern nur mit dem EventDispatcher, über den es ausgelöst wird. Wenn stage in Starling ein anderes Objekt ist als in der DisplayList, dann kannst beim einen logischerweise nicht das Event empfangen, das Du im anderen auslöst.

Du musst Dir deshalb entweder überlegen, wie Du in Starling an die stage der Anzeigeliste rankommst, oder Dir ein anderes global verfügbares Objekt suchen. Ich habe mir für solche Fälle mal folgende Klasse zusammengebastelt:

package net.martinkraft.utils {
    import flash.events.Event;
    import flash.events.EventDispatcher;
    
    /**
     * @author Martin Kraft
     */
    
    public class StaticEventDispatcher extends EventDispatcher{
        
        ////
        
        private static var _instance:StaticEventDispatcher;
        
        ///////////////////////////////////////////
        
        public function StaticEventDispatcher( si:SingleInstance ) {
            super();
        }
        
        ///////////////////////////////////////////
        
        // Instance functions to static
        
        static public function addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = true):void {
            instance.addEventListener(type, listener, useCapture, priority, useWeakReference);
        }
        
        static public function dispatchEvent(event:Event):Boolean {
            return instance.dispatchEvent(event);
        }
        
        static public function hasEventListener(type:String):Boolean {
            return instance.hasEventListener(type);
        }
        
        static public function removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void {
            instance.removeEventListener(type, listener, useCapture);
        }
        
        static public function willTrigger(type:String):Boolean {
            return instance.willTrigger(type);
        }
        
        ////
        
        static public function get instance():StaticEventDispatcher { 
            if(!_instance) _instance = new StaticEventDispatcher( new SingleInstance() );
            return _instance;
        }
        
    }
}
 
internal class SingleInstance {
    /// protects Singleton
    public function SingleInstance():void { }
} 

...und für den enthalten Singleton auch schon meine Prügel bezogen

[litchi]

Ja an so was dachte ich.

Nach Abschicken hauen die beiden Event Klassen aufeinander.

TypeError: Error #1034: Typumwandlung fehlgeschlagen: flash.events::Event@435fba1 kann nicht in starling.events.Event umgewandelt werden.
at flash.events::EventDispatcher/dispatchEventFunction()
at flash.events::EventDispatcher/dispatchEvent()
at net.martinkraft.utils::StaticEventDispatcher$/dispatchEvent()....


Im Starling-Forum hatte ich gesehen wie jemand sich die Insanz von der Starlington Stage raus sucht und die Funktoin direkt aufruft. Schien aber älter zu seien da dies bei mir nicht gefunzt hat.

[Martin Kraft]

Du musst Dein Event eben auf flash.events.Event typisieren und nicht auf starling.events.Event!

[litchi]

Hmm, stimmt. Kann man denn zwei Klassen mit dem gleichen Namen benutzen? Wenn ich diesen hier mache bekomme ich eine Fehlermeldung dass der Typ nicht eindeutig ist, da ich auch den Starling Event nutze.

private function newPos(e:flash.events.Event):void

[Martin Kraft]

Zitat von litchi

private function newPos(e:flash.events.Event):void

Dieser Code sollte aber eigentlich keine Probleme bereiten?! Du darfst nur keine zweite import-Anweisung schreiben!

P.S.: Ich find diese Namensdopplungen in Starling übrigens ziemlichen Blödsinn. Sowas schafft doch nur Verwirrung! Mit einen entsprechenden Vorsilbe wäre es doch genauso eindeutig gewesen?!

[litchi]

Ok, wenn ich das gleiche mit den Starling Events mache dann geht's.

[Omega Psi]

Zitat von Martin Kraft

Dieser Code sollte aber eigentlich keine Probleme bereiten?! Du darfst nur keine zweite import-Anweisung schreiben!

P.S.: Ich find diese Namensdopplungen in Starling übrigens ziemlichen Blödsinn. Sowas schafft doch nur Verwirrung! Mit einen entsprechenden Vorsilbe wäre es doch genauso eindeutig gewesen?!

Dafür gibt es ja packages, damit man auf so was wie NSObject etc verzichten kann. Das ist schon besser so.

[Martin Kraft]

Zitat von Omega Psi

Dafür gibt es ja packages, damit man auf so was wie NSObject etc verzichten kann. Das ist schon besser so.

Aber gerade bei so Allerweltsklassen (wie Event) sorgt das doch nur für Verwirrung. Mir ist es z.B. ein Rätsel, warum Starling ein eigenes Event-System etabliert, das inkompatibel zu dem der API ist und diese nicht einfach erweitert?! Es würde ja auch niemand auf die Idee kommen eine neue Klasse namens Math zu erzeugen, die nicht typkompatibel ist aber alle Funktionen doppelt?!

Obwohl: Ich schlag mich gerade mit Box2D rum. Die haben auch einfach die Point-Klasse ignoriert und eine eigene Klasse namens b2Vec2 geschrieben - aber die wurde wenigstens nicht identisch benannt.

[litchi]

Jetzt fehlt nur noch die Referenz von Clip der das Event versendet (jetzt wird ja auf die StaticEventDispatcher dispatched), damit ich auf die gewünschten Positonsdaten zugreifen kann. Oder sollte ich mir dazu einen eigenen Event erstellen der die zu übertragenden Daten enthält? Oder gibt es was eleganteres?

[litchi]

Ok, hab mir dann mal ein DataEvent gemacht um beliebige Daten zu übertragen. Dann erübrigt sich auch die doppelte Event Namensgebung.

PHP-Code:

package
{
    import flash.events.Event;
    
    public class DataEvent extends Event
    {
        public var data:Object = {}; 
        public function DataEvent(type:String, bubbles:Boolean=false, cancelable:Boolean=false)
        {
            super(type, bubbles, cancelable);
        }
    }
}