Childadrray sortieren

[PHPChris]

Hallo liebe Community!
Ich habe ein komisches Problem!

Ich füge in einem Loop Objekte zum Stage hinzu:

var iso:IsoBox;
for(var i:int=1; i<roomy+1; i++)
{
	for(var j:int=1; j<roomx+1; j++)
	{
		iso = new IsoBox();
		iso.addEventListener(MouseEvent.CLICK, isoclicked);
		iso.setSize(cellSize, cellSize, 1);
		iso.styleType = RenderStyleType.SHADED;
		iso.fill = new SolidColorFill(0xFFFFFF, 1);
		iso.moveBy(j*cellSize, i*cellSize, 1);
		iso.name = i + " " + j;
		room.roomScene.addChild(iso);
		room.roomScene.render();
	}
}

Und danach ein anderes Objekt:

_core._myself.setSize(cellSize, cellSize, cellSize);
_core._myself.sprites = [prsxplu];
var myselfx:int = 0;
var myselfy:int = 0;
if(roomdoory == -1){
	myselfy = 0;
}else{
	myselfy = roomdoory + 1;
}
if(roomdoorx == -1){
	myselfx = 0;
}else{
	myselfx = roomdoorx + 1;
}
_core._myself.moveTo(myselfx * cellSize, myselfy * cellSize, 0);
room.roomScene.render();
room.roomScene.addChild(_core._myself);

(Das kursiv gescrhiebene ist nicht weiter wichtig!)

Wenn ich nun die Reihenfolge der Childs des Stages ausgebe, kommt
widererwartens folgende Ausgabe:

var count:int = 0;
while(count <= room.roomScene.numChildren)
{
	trace(room.roomScene.children[count]);
	count++;
}

Ausgabe:

[IsoBox]
[IsoBox]
[IsoBox]
[IsoSprite]
[IsoBox]
[IsoBox]
...
[IsoBox]
[IsoBox]
[IsoBox]

Das dick geschriebene ist das zuletzt eingefügte Objekt!
Zudem wird das Objekt wenn ich das Projekt debugge unter allen anderen Objekten angezeigt:



Kann mir da jemand helfen?

Danke!
Chris.

[milchreis]

Ich kenne mich mit der as3isolib nicht aus (danke das du das gleich dazu geschrieben hast )

ich sehe das Problem in der vermutlich automatisch durchgeführten z-sortierung der Bibliothek:

all deine isoBoxen verschiebst du um 1 auf der z achse
dein _core._myself dingens bleibt auf 0.

[PHPChris]

Hallo,
danke für deine Antwort und sorry dass ich das nicht vorher gesagt habe.

Ich habe jetzt alle möglichen Varianten ausprobiert, per moveBy das Objekt
vor alle anderen Objekte zu krigen, jedoch ändert sich nur die Höhe des Objektes.

Wie kann ich ein Objekt in einer child-Liste über allen anderen anzeigen?

[milchreis]

Zitat von PHPChris

Hallo,
jedoch ändert sich nur die Höhe des Objektes.

ja logisch ändert sich die Höhe, denn das ist ja der Wert, den du änderst.

[PHPChris]

Zitat von PHPChris

Wie kann ich ein Objekt in einer child-Liste über allen anderen anzeigen?

Siehe Zitat...
Das mit dem logisch sein finde ich logischerweise auch logisch

[thomas_E]

@PHPChris, scheinbar gibbet grundsätzlich Probleme mit dem Z-Sorting in ISO-Engines
das hier hilft dir vielleicht weiter, oder die Sorting-funktion ebenfalls für deine Zwecke umschreiben
Issue 10 - as3isolib - depth sorting algorithm not sorting properly in various scenarios - ActionScript 3 Isometric Library - Google Project Hosting

[milchreis]

Thomas war wieder schneller.
Ich hab mir jetzt mal ddiese bibliothek runtergeladen und etwas ruprobiert:

PHP-Code:

package 
{
    import as3isolib.display.IsoView;
    import as3isolib.display.primitive.IsoBox;
    import as3isolib.display.scene.IsoGrid;
    import as3isolib.display.scene.IsoScene;
    import as3isolib.geom.IsoMath;
    import as3isolib.geom.Pt;
    import eDpLib.events.ProxyEvent;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    
    /**
     * @author milchreis
     */
    public class Main extends Sprite 
    {
        private const CELL_SIZE:Number = 40;
        private var scene:IsoScene;
        private var viewport:IsoView;
        private var grid:IsoGrid;
        private var a:IsoBox;
        
        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }
        
        private function init(e:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);
            // entry point
            
            grid = new IsoGrid();
            grid.showOrigin = false;
            grid.cellSize = CELL_SIZE;
            grid.setGridSize(10, 10);
            
            scene = new IsoScene();
            scene.addChild(grid);
            
            viewport = new IsoView();
            viewport.setSize(stage.stageWidth, stage.stageHeight);
            viewport.centerOnPt(new Pt(200, 200));
            viewport.addScene(scene);
            addChild(viewport);
            
            var b:IsoBox;
            for (var i:int = 0; i < 10; ++i)
            {
                for (var j:int = 0; j < 10; ++j)
                {
                    b = new IsoBox();
                    b.setSize(CELL_SIZE, CELL_SIZE, 5);
                    b.x = i * CELL_SIZE;
                    b.y = j * CELL_SIZE;
                    scene.addChild(b);
                }
            }

            
            a = new IsoBox();
            a.setSize(10, 10, 2 * CELL_SIZE);
            a.z = 5; //wenn a.z < 5, dann gibt's Probleme
            scene.addChild(a);
            
            
            
            scene.render();
            
            stage.addEventListener(MouseEvent.MOUSE_DOWN, onDown);
        }
        
        private function onDown(e:MouseEvent):void 
        {
            var p:Pt = new Pt(mouseX, mouseY);
            IsoMath.screenToIso(p);
            trace(p);
            a.x = p.x;
            a.y = p.y;
            scene.render();
        }
        
    }
    
} 


Eigentlich soll sich der große Block dorthin bewegen, wo die Maus ist.
Aber irgendwie habe ich jetzt auf die Schnelle die Transformation in den isometrischen Raum nicht auf die Reihe bekommen. (mal oben links bissel rumklicken)

Es wird aber deutlich, das die z Position der Figur, wie oben schon geschrieben, entscheidend für das Ergebnis ist.

Wenn du die Höhe der Spielfigur auf einen Wert kleiner 4 änderst kommt Murks raus. Ist auch klar, denn 3dimensional gesehen würden beide Teile dann ineinander stecken. Das lässt sich aber nicht darstellen.

Das die isolib dann gerade falsch rum darstellt, ist nicht schön, das stimmt schon.

Es gilt also was man irgendwann in der Schule mal gelernt hat: "Wo ein Körper ist, kann kein zweiter sein."

[thomas_E]

habs mir nochmal durch den Kopf gehen lassen

Das die isolib dann gerade falsch rum darstellt, ist nicht schön, das stimmt schon.

naja, was heisst falsch herum, wenn du den Block bei z<5 plazierst, verdeckt er nicht nur teile der Kachel, in der er "drinsteckt", sondern wird wiederrum teilweise von der Kachel verdeckt.
a verdeckt b und b verdeckt a. (zumindest stellenweise) wie willst du das auflösen?
Bei Boxen wirst du das noch "relativ" einfach berechnen können, sobald du dir aber die Schuhe seines verdeckten Männchens anschaust läuft das imho auf Techniken wie Ray-Tracing oder Depth-Buffering in einer 3D-Engine hinaus.

@PHPChris
mein Tipp wäre, dein Männchen 0.5 Pixel über dem Boden schweben zu lassen.

_core._myself.moveTo(myselfx * cellSize, myselfy * cellSize, 1.5); //1 px Bodenfliese + 0.5 px Levitation

diese Lösung sollte das Problem mit dem geringsten Aufwand zufriedenstellend lösen; Einfacher als jetzt an der Sorting-Routine rumzuschrauben.

[milchreis]

Zitat von thomas_E

a verdeckt b und b verdeckt a. (zumindest stellenweise) wie willst du das auflösen?

eben das wollte ich deutlich machen.

Zitat von thomas_E

mein Tipp wäre, dein Männchen 0.5 Pixel über dem Boden schweben zu lassen.

hatte ich auch erst gedacht, dann wollte ich es aber lieber nochmal probieren. (siehe meinen code oben)

dort scheint soweit alles glatt zu gehen, wenn die z Position gleich der Bodenhöhe ist. (in meinem Fall 5, bei Chris 1)

so lange also kein ineinander eindringen statt findet, ist die Idometrie wohl in trockenen Tüchern

[PHPChris]

So!
Danke für alle Antworten!
Es klapp jetzt einigermassen.

Aber:
Wenn ich einen Tween benutze tritt der Fehler weiterhin auf:

Tweener.addTween(_core._myself, { x:targetX, y:targetY, delay:speed * i , time:speed, transition:"linear" } );

Mache ich etwas falsch?

Ich habe es schon mit folgendem probiert:

Tweener.addTween(_core._myself, { x:targetX, y:targetY, z:1.5, delay:speed * i , time:speed, transition:"linear" } );

Danke für Eure Hilfe!

[thomas_E]

das die Figur komplett verdeckt ist?
wie hast du das mit dem rendern eingerichtet? ENTER_FRAME? dann versuch mal folgendes:

PHP-Code:

stage.addEventListener(Event.EXIT_FRAME, reRender);
function reRender(e:Event):void
{
    room.roomScene.render()
} 


afaik sollte das nach allen ENTER_FRAME Events ausgeführt werden, also auch nach dem Zeitgeber von Tweener.

wo genau ist der Registrierungspunkt der Figur? unten?

[PHPChris]

Du bist mein Mann!
Danke für die Hilfe!

Hat geholfen xD

-Lösung-

-> Alle IsoBoxen auf z = 1 setzen
-> Das IsoSprite (Die Figur) auf z = 1.5 setzen (Sodass sie schwebt)
-> Wenn man einen Tweener benutzt den Loop nicht mit ENTER_FRAME sondern mit EXIT_FRAME verwenden!

var isoBox:IsoBox = new IsoBox();
//Eingenschaften
isoBox.z = 1;

var isoSprite:IsoSprite = new IsoSprite();
//Eigenschaften
isoSprite.z = 1.5;

stage.addEventListener(Event.EXIT_FRAME, reRender);

function reRender(e:Event):void
{
	isoScene.render();
}

THX an milchreis & thomas_E

Chris.

[milchreis]

Jetzt bin ich verwirrt, schließlich sind doch deine IsoBoxen 1 hoch, oder?
Wenn man die in eine Höhe von (z Position) 1 setzt, dannn müsste man sich doch, um wirklich über ihnen zu sein, auf z = 2 stellen.

Warum sind überhaupt die Boxen auf z = 1?

@Thomas, das ist interessant, ich konnte mir bisher nie einen konkreten Anwendungsfall für ExitFrame überlegen.

[PHPChris]

Du das weiss ich auch nicht :/
ICh bin nur froh dass es funzt

[thomas_E]

Warum sind überhaupt die Boxen auf z = 1?

Du das weiss ich auch nicht :/
ICh bin nur froh dass es funzt

rofl
Edit: je öfter ich das lese, desto mehr schmeiss ich mich weg
ich meinte eigentlich auch, dass die boxen bei z=0 bleiben sollten, damit deren Oberkante bei z: 1 liegt, aber wenn es so für ihn funzt, wieso debattieren?

@Thomas, das ist interessant, ich konnte mir bisher nie einen konkreten Anwendungsfall für ExitFrame überlegen.

im nachhinein, bin ich mir auch nicht mehr ganz sicher, ob der Rendervorgang noch im selben Frame durchgeführt (eher dargestellt) wird, oder ob die Grafik nun der Datenlage um 1 Frame hinterherhinkt, aber ich denke, das ist verschmerzbar.