Buttontausch

[Mike-S]

Hi,

ich suche nach einer Möglichkeit, einen Button (my_button), der angeklickt wurde, durch einen anderen Button (my_button_grey) zu ersetzen - und zwar dauerhaft.
Wenn möglich, ohne großes Variablen-Rumgeschleppe oder if... Abfragen.

Ist das in AS3 möglich? Ich finde da einfach keinen Einstieg ...

Bin für jeden Hinweis dankbar.

Greets,

MIKE

[milchreis]

Ist das bloß ein visuell anderer button?
Oder möchtest du ihn durch einen Button anderen typs (Klasse) ersetzen, also ein ganz neues Objekt?

[Mike-S]

Der Button sieht nur anders aus (z.B. andere Farben). Ist aber sonst identisch. Er besitzt also ebenfalls einen hover- und einen gedrückt-Zustand

Sinn dahinter: Nach dem 'Abarbeiten' des Buttons soll erkennbar sein, dass er bereits einmal angeklickt worden ist.

MIKE

[thomas_E]

das kannst du bspw lösen, indem du einen MC machst, und den already_pressed zustand auf ein zweiten Frame setzt. und dann nur dann musst du nur beim klicken per gotoAndStop("already_pressed") setzen.

mehr Infos können wir nur geben, wenn du zeigst, wie du die Buttons aufgebaut hast. bspw SimpletButton||MovieClip? Hover-state oder animation oder garnix dergleichen? gibbet einen hitTestState, der sich ebenfalls ändern muss?, etc etc.
wäre vielleicht schon ein ColorTransform || ColorMatrixFilter ausreichend, um die Farbänderung durchzuführen? oder sonst irgendein Filter?

[milchreis]

Wilslt du den Button jetzt aus deinen einzelnen Zuständen zusammen bauen, oder hast du die zwei buttons schon fertig vorliegen?

Für zweiteres könnte man das ganze einfach in einen container packen, der entsprechend die buttons austauscht. Der Konstruktor verlangt nach den beiden Buttons, die du nacheinander haben möchtest.

//in Aktion

PHP-Code:

package 
{
    import flash.display.Sprite;
    import flash.events.Event;
    
    /**
     * ...
     * @author milchreis
     */
    public class Main extends Sprite 
    {
        
        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }
        
        private function init(e:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);
            // entry point
            
            addChild(new MemorialButton(new Box(0), new Box(0xff0000)));
        }
        
    }
    
}
import flash.display.Sprite;

internal class Box extends Sprite
{
        
        public function Box(col:int) 
        {
            super();
            
            graphics.beginFill(col);
            graphics.drawRect(0, 0, 200, 200);
            graphics.endFill();
        }
        
} 


//Button mit Gedächtnis

PHP-Code:

package  
{
    import flash.display.InteractiveObject;
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    
    /**
     * I know what you clicked last frame
     * @author milchreis
     */
    public class MemorialButton extends Sprite
    {
        private var a:InteractiveObject, b:InteractiveObject;
        
        public function MemorialButton(button1:InteractiveObject, button2:InteractiveObject) 
        {
            super();
            
            a = button1;
            b = button2;
            
            addChild(a);
            a.addEventListener(MouseEvent.CLICK, onClick);
        }
        
        private function onClick(e:MouseEvent):void 
        {
            removeChild(a);
            a.removeEventListener(MouseEvent.CLICK, onClick);
            a = null;
            
            addChild(b);
        }
        
    }

} 


[Mike-S]

Super, besten Dank.
Genau, was ich brauche. Noch ein paar Modifikationen ...

Danke!

MIKE

[thomas_E]

dürfte ich folgende kleine Änderung vorschlagen:

PHP-Code:

package  
{
    import flash.display.DisplayObject;    //<==
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    
    /**
     * I know what you clicked last frame
     * @author milchreis
     */
    public class MemorialButton extends Sprite
    {
        private var a:DisplayObject, b:DisplayObject;
        
        public function MemorialButton(button1:DisplayObject, button2:DisplayObject) 
        {
            super();
            
            a = button1;
            b = button2;
            
            addChild(a);
            addEventListener(MouseEvent.CLICK, onClick);    //<==
        }
        
        private function onClick(e:MouseEvent):void 
        {
            removeEventListener(MouseEvent.CLICK, onClick);
            removeChild(a);
            a = null;
            
            addChild(b);
        }  
    }
} 


so kann der Button auch Bitmaps und Shapes verwenden

[milchreis]

aber klar doch! Code ist immer als diskutabel aufzufassen, so wie ein einfacher Textbeitrag.

Hast recht, ist (für den allgemeinen Fall) besser.
Hatte durch die Gegebenheiten die Scheuklappen auf, das nur mit InteractiveObjects zu rechnen ist.