BitmapData ... transparenz "stanzen"

[Master Wu]

EDIT: gerade komm ich selber auf ne Idee ... BLENDMODE!!!!
So sollte es doch klappen, ich tests mal, sorry schonmal


Moin, mal wieder ne recht spezielle Frage:

- Ich hab eine BitmapData, die mit farbigen pixeln gefüllt ist.
- Nun will ich einen Kreis da "rausstanzen", der also dann transparent sein soll.

mit BitmapData.draw könnte man super einen Kreis, den man vorher in einen Sprite gemalen hat, da reinkopieren, nur hab ich keine Idee, wie man da ein transparentes "Loch" reinkopieren kann?

Ich hab dann einen weissen Kreis reinkopiert und wollte den dann per BitmapData.threshold auf Transparent stellen.
Geht prinzipiell, aber ich bekomme keine weichen Kanten hin, threshold macht entweder voll transparent oder garnix.

Ich habs jetzt mal temporär so gelöst, dass ich per getPixel32 und setPixel32 bei solchen Pixeln, die nicht komplett schwarz sind, den Grauwert als Alphawert einsetze. Es geht hierbei um eine Maske. Also ich wandle praktisch eine s/w-maske in eine alpha-Maske um.

Die Pixel-für-Pixel Variante ist leider sehr performancefressend.
Man könnte es wohl mit einem custom Pixelbender-Filter beschleunigen, trotzdem meine Frage, ob es nicht auch einen sauberen schnellen Weg per BitmapData-Befehlen gibt, um transparente Löcher ins BMD zu stanzen, auf den ich nur nicht komme

Hoffe der Post ist nicht zu verwirrend, danke schonmal für eure Anregungen

[shin10]

hi,

sollte so klappen

PHP-Code:

import flash.display.BitmapData;
import flash.display.BitmapDataChannel;
import flash.display.BlendMode;
import flash.display.Bitmap;
import flash.display.Sprite;
import flash.display.Shape;
import flash.geom.Point;
import flash.geom.ColorTransform;

var bmpdPic:BitmapData = new BitmapData(mcBild.width,mcBild.height,true,0);
bmpdPic.draw(mcBild);
var bmpPic:Bitmap = new Bitmap(bmpdPic);
addChild(bmpPic);

var c:Shape = new Shape();
c.graphics.beginFill(0xFFFFFF, 1);
c.graphics.drawRect(0, 0, 200, 200);
c.graphics.drawCircle(50, 50, 50);
c.graphics.endFill();

var bmpdCircle:BitmapData = new BitmapData(bmpdPic.width,bmpdPic.height,true,0);
bmpdCircle.draw(c);
bmpdPic.copyChannel(bmpdCircle, bmpdCircle.rect, new Point(c.x, c.y), BitmapDataChannel.ALPHA, BitmapDataChannel.ALPHA); 


mfg

sx

[Master Wu]

Ah, BitmapDataChannel ... auch ne gute Idee!
Dankeschön!

[shin10]

zumindest werden die kanten sauberer als mit BlendMode.ERASE, der wohl ohne anti-aliaste kanten arbeitet. oder bist du da noch auf was anderes gestoßen?

[Master Wu]

ERASE funzt auch, du musst aber erst die "Stanzform" in eine BitmapData "drawen", und das daraus erstellte Bitmap dann per ERASE in die andere BitmapData "drawen"

Direkt nen Sprite oder so per ERASE reinmalen killt das AntiAliasing.

PHP-Code:

package  
{
    import flash.display.Sprite;
    import flash.display.BitmapData;
import flash.display.BitmapDataChannel;
import flash.display.BlendMode;
import flash.display.Bitmap;
import flash.display.Sprite;
import flash.display.Shape;
import flash.geom.Point;
import flash.geom.ColorTransform; 
    /**
     * ...
     * @author me
     * 
     */
    public class BlendModeTests extends Sprite
    {
        
        private var _imgBmd:BitmapData;
        private var _stanzBmd:BitmapData;
        
        public function BlendModeTests() 
        {
            
            _imgBmd = new BitmapData(1000, 1000, true, 0x00000000);
            
            _imgBmd.floodFill(0, 0, 0xffff0000);
            var imgBm:Bitmap = new Bitmap(_imgBmd);
            //imgBm.blendMode = BlendMode.LAYER;
            addChild(imgBm);
            
            var spr:Sprite = new Sprite();
            spr.graphics.beginFill(0xffff0000, 1);
            spr.graphics.drawCircle(100, 100, 40);
            
            _stanzBmd = new BitmapData(400, 400, true, 0x00000000);
            _stanzBmd.draw(spr);
            var stanzBm:Bitmap = new Bitmap(_stanzBmd);
            
            
            _imgBmd.draw(stanzBm, null, null, BlendMode.ERASE);
        
            
        }
        
    }

}