Bitmap, BitmapData, onEnterFrame und der Speicher

[echo5-7]

Hi,

ich habe ein kleines Script gemacht, dass die Spuren von ein paar Vektor Sprites auf der Bühne verfolgt. Bei jeder Iteration wird die stage abfotografiert und das Foto wieder in den Hintergrund gelegt. Dadurch ergeben sich Bewegungspfade der Sprites.

Mein Problem ist jetzt, dass die Speicherauslastung zu rucklern führt, aber nicht, weil der Speicher irgendwann dicht ist, sondern weil er dicht gemacht wird, sich dann aber wieder entleert. Dieses entleeren sorgt für die Ruckler. Für mich sieht das nach einem Problem der System.gc() aus. Ich versteh allerdings auch nicht, wie das sein kann. Ich überschreib doch das Bitmap immer wieder?

Script sieht so aus:

		private function drawer (ev:Event = null):void {
			var bmpneu : BitmapData = new BitmapData(stage.stageWidth, stage.stageHeight, false, 0x00555555);
			bmpneu.draw(stage);
			var bneu:Bitmap = new Bitmap(bmpneu);
			var tempSprite : Sprite = new Sprite();
			
			tempSprite.addChild(bneu);
			_mySprite.addChild(tempSprite);
			
			if (iterationvar > 0) {
				var ref:Sprite = _mySprite.getChildAt(0) as Sprite;
				_mySprite.removeChildAt(0);
				ref = null;
				System.gc();
				
			}else {
				iterationvar++;
			}
			
		}

Weiß jemand, wo da das Problem liegt?
Danke
echo

[Martin Kraft]

Find die ganze Konstruktion etwas seltsam. Jedes mal neue Instanzen zu erzeugen und dan per getChildAt(0) zu entfernen ist jedenfalls nicht wirklich ressourcenschonend.

Wieso benutzt Du nicht einfach nur 1 BitmapData, dass Du bei Event.ENTER_FRAME einfach leerst und dann die Bühne hineinzeichnest? Die ganze Instanzen-Erzeuger- und Austauscherei wird damit überflüssig!

[echo5-7]

Du meinst Bitmap.bitmapData = bitmapdata.draw(stage);

[Martin Kraft]

Zitat von echo5-7

Du meinst Bitmap.bitmapData = bitmapdata.draw(stage);

Das kann so leider nicht funktionieren, weil draw keinen Rückgabewert hat.

Versuch's mal so:

PHP-Code:

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.IBitmapDrawable;

//...

private var bmpData:BitmapData;
private var bmp:Bitmap;
private var bmpSource:IBitmapDrawable;

//...

private function init():void {
    bmpSource = stage;
    bmpData = new BitmapData(stage.stageWidth, stage.stageHeight, false, 0x00555555);
    bmp = new Bitmap(bmpData);
    addChild(bmp);

    drawBmp();
}

//...

private function drawBmp (ev:Event = null):void {
    bmpData.fillRect(bmpData.rect, 0x00555555);
    bmpData.draw(bmpSource);
} 


[shin10]

hi,

martins code funktioniert so tadellos. nur ein kleiner nachtrag zum verständnis:

der speicher läuft dir voll, weil bitmapdata nicht wie instanzen anderer klassen einfach in der gc landen. die müssen von hand mit dispose() zuvor entleert werden.

mfg

sx

[echo5-7]

jungs, ihr seid klasse! das mit dem dispose muss man auch erstmal wissen. der code funktionert, ich hab nur das fillRect rausgenommen, weil sonst das bmp jedesmal zurück setzt.

nur zum abschließenden verständnis: was macht das IBitmapDrawable jetzt genau? Die Lifedocs geben mir dazu nur das hier aus

Die IBitmapDrawable-Schnittstelle wird von Objekten implementiert, die als source-Parameter der draw()-Methode der BitmapData-Klasse übergeben werden können. Diese Objekt sind vom Typ „BitmapData“ oder „DisplayObject“.

Versteh ich das richtig, dass sobald man ein Object als Source für Ibitmapdrawable definiert, das objekt als pixeldaten im speicher vorbehalten wird, und bei bedarf abgerufen werden kann?

danke
echo

[thomas_E]

Versteh ich das richtig, dass sobald man ein Object als Source für Ibitmapdrawable definiert, das objekt als pixeldaten im speicher vorbehalten wird, und bei bedarf abgerufen werden kann?

nein, die Bilddaten des BitmapData-Objektes liegen im Speicher unkompriomiert vor.


die IBitmapDrawable-Schnittstelle ist keine Schnittstelle in der eigentlichen Bedeutung, sondern sowas wie ein Marker, um die Parameter Typsicher zu machen.
IBitmapDrawable beinhaltet alle DisplayObjekte und BitmapData.
Das Interface wird verwendet um BitmapData und DisplayObject in einer gemeinsamen Gruppe zusammenfassen zu können.


noch ne kleine Rechnung, um dir zu zeigen, wieso dir dein Speicher vollgelaufen ist:
speicherVerbrauch für ein BitmapData-Objekt
speicherVerbrauch = (bmd.width*bmd.height)pixel *32Bit/pixel * 1Byte/8Bit
bei 640*480 Pixel sind das 1228800 Byte oder 1,17MB (pro BitmapData)
und wenn du das 25x pro Sekunde machst, kommst du auf ~30MB/Sekunde die du erzeugst, und die die GC wieder fortschaffen muss.

[echo5-7]

super! danke!