Bild laden und Breite abfragen

[der.milco]

Hallo Leute,

ich will in meiner fla-Datei ein Bild in einen MC laden und positionieren. Über die x und y Eigenschaft ist das auch kein Problem.

Da mein Movieclip später allerdings maskiert wird, sehe ich nur einen Ausschnitt von dem geladenen Bild. Ich möchte das geladene Bild in dem Ausschnitt zentrieren.
Dazu muss ich jedoch vor Platzierung des Bildes abfragen, welche Breite und Höhe es in Pixeln hat.

Mein Code bisher:

// MCs anlegen, Bilder einladen und auf Bühne platzieren
var ldr1:Loader = new Loader();
var bild1:MovieClip = new MovieClip();
ldr1.load(new URLRequest("pic1.jpg"));
bild1.x = (200 - ldr1.width) / 2;			// linker Abstand
bild1.y = (150 - ldr1.height) / 2;			// oberer Abstand
bild1.addChild(ldr1);
this.addChild(bild1);

Hier ergeben aber ldr1.width und ldr1.height jeweils 0.

Ich habe auch andere Varianten probiert; entweder erhalte ich auch 0 oder Fehlermeldungen (nicht weit genug geladen oder Eigenschaft nicht verfügbar):
ldr1.content.width
ldr1.contentLoaderInfo.width
ldr1.LoaderInfo.width
ldr1.content.loaderInfo.width

Wie kann ich Breite und Höhe von externen Bitmaps abfragen??
Jemand ne Idee?

[Martin Kraft]

Hallo und willkommen im Forum!

Dein Problem ist, dass Flash die Breite erst kennen kann, wenn das Bild Tatsächlich geladen wurde. Und das geschieht eben nicht in »no-time«

Du musst daher auf das zugehörige COMPLETE-Event warten:

ldr1.contentLoaderInfo.addEventListener(Event.COMPLETE, handleComplete);
function handleComplete(e:Event):void {
    trace(ldr1.width + " / " + ldr1.height);
} 

Diesem MovieClip-Container kannst Du Dir übrigens sparen!

1. MovieClips benötigt man in AS3 generell nur noch, wenn sie tatsächlich Zeitleistenanimationen enthalten. Ansonsten reichen Sprites.
   
2. Und da der Loader selbst ein AnzeigeObjekt ist, benötigt man gar keine Conatiner mehr, sondern kann ihn selbst direkt mit addChild in die Anzeigeliste hängen.

[der.milco]

Hallo Martin,

danke für deine Antwort. Das habe ich schon geahnt, dass ich über den Event.COMPLETE gehen muss. Hätte allerdings gedacht, dass sich das trotzdem irgendwie abfragen lässt, da ich ja auch die Anzahl der geladenen Bytes und der totalen Bytes abfragen kann.
Aber gut: bekomm ich hin.

Zu deinem anderen Hinweis:
Was du nicht wissen konntest ist, dass das Bild etwas später im AS-Code per Tween bewegt werden soll. Für mein bisheriges Verständnis brauche ich doch für einen Tween immer einen MovieClip, oder?
Kann ich einen Sprite auch dynamisch tweenen?

Wenn ich das Bild mit addChild auf die Bühne platziere, kann ich es hinterher nicht mehr ansprechen, um es zu tweenen, richtig?

[Martin Kraft]

Das, was Du da beschreibst, kannst Du auch alles direkt mit dem Loader selbst machen. Der ist ein vollwertiges AnzeigeObjekt. Solange Du also ein Referenz (Variable) auf ihn hast...

Und per AS tweenen kann man sowieso jedes beliebige Objekt.

Der einzige Unterschied zwischen Sprites und MovieClips ist übrigens, dass letztere eine Zeitleiste mit mehreren Frames und die entsprechenden Steuerbefehle besitzen. Ansonsten sind die beiden Klassen identisch.

[der.milco]

Hallo Martin,
so kurz vorm Ziel und schon wieder Probleme! Ich habe den Code umgeschrieben. Allerdings geht es um mehrere Bilder, die die gleiche Funktion verwenden sollen, wenn sie jeweils geladen wurden. Ich schaffe es aber nicht, die Quelle abzufragen.

var bild1:Loader = new Loader();
bild1.load(new URLRequest("pic1.jpg"));
bild1.contentLoaderInfo.addEventListener(Event.COMPLETE, fertig);
container.addChild(bild1);

var bild2:Loader = new Loader();
bild2.load(new URLRequest("pic02.jpg"));
bild2.contentLoaderInfo.addEventListener(Event.COMPLETE, fertig);
container.addChild(bild2);

function fertig(event:Event):void {
	trace(event.target);
	if (event.target.name == "bild1") {
		trace(bild1.width + " / " + bild1.height);
	} else if (event.target.name == "bild2") {
		trace(bild2.width + " / " + bild2.height);
	}
}

Hier bekomme ich aber im Ausgabe-Fenster folgende Meldung:

[object LoaderInfo]
ReferenceError: Error #1069: Eigenschaft name für flash.display.LoaderInfo nicht gefunden und es ist kein Standardwert vorhanden.
	at ausschnitt_fla::MainTimeline/fertig()
[object LoaderInfo]
ReferenceError: Error #1069: Eigenschaft name für flash.display.LoaderInfo nicht gefunden und es ist kein Standardwert vorhanden.
	at ausschnitt_fla::MainTimeline/fertig()

Wie kann ich den aufrufenden Loader unterscheiden?

[Martin Kraft]

Das hat gleich mehrere Gründe:

• Zum einen zeigt die event.target in diesem Fall nicht auf den Loader selbst, sondern auf die zugehörige LoaderInfo-Instanz (contentLoaderInfo). Und die besitzt nunmal keinen Eigenschaft namens name. Um an diese zukommen müsste Dein Code also so aussehen:

  LoaderInfo(event.target).loader.name 

  
  
• Zum anderen hat das, was da in name drin steht, nichts mit dem Namen der Variablen zu tun, die auf die betreffende Instanz zeigt (was auch einleuchtet, da ja beliebig viele Variablen auf dieselbe Instanz zeigen können), sondern kann frei vergeben werden und wird bei der Instanziierung vom FlashPlayer mit "instance"+<LaufendeNummer> vorbelegt:

  import flash.display.Sprite;
   
  var ref1:Sprite = new Sprite();
  trace(ref1.name); // -> instance1
   
  var ref2:Sprite = ref1;
  trace(ref2.name); // -> instance1
  trace(ref1 == ref2); // -> true
   
  ref1.name = "test";
  trace(ref1.name+" == "+ref2.name);  // -> test == test 
   

  Nur bei in der Flash IDE selbst erstellten Instanzen entspricht name dem Namen einer auf diese Instanz zeigenden Variablen. Anders als in der statischen Anzeigeliste von AS1/2 sind in AS3 die Instanznamen von der dynamischen Anzeigeliste entkoppelt, weshalb es in den seltensten Fällen überhaupt Sinn macht mit ihnen zu arbeiten. Auf name, getChildByName und Co. kann und sollte man daher in 99% aller Fälle verzichten!

Im Grunde ist das auch alles völlig überflüssig, weil es Dir ja eigentlich nur darum geht, in der Listener-Funktion wieder an eine Referenz auf Deinen Loader zu kommen. Und an die kommst Du so:

var imageLoader:Loader = LoaderInfo(event.target).loader; 

Ein Tipp noch: Immer wenn man anfängt irgendwie seine Objekte durchzunummerieren, ist das ein untrügliches Zeichen dafür, dass man besser mit einem Array arbeiten sollte. Und das sähe in Deinem Fall so aus:

import flash.display.Loader;
import flash.display.LoaderInfo;
import flash.events.Event;
import flash.net.URLRequest;
 
var urlsToLoad:Array = ["pic1.jpg", "pic02.jpg"];
var images:Array = [];
var imageLoader:Loader;
 
for each (var url:String in urlsToLoad) {
    
    imageLoader = new Loader();
    imageLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, handleImageComplete);
    imageLoader.load(new URLRequest(url));
    
    images.push(imageLoader);
    
    container.addChild(imageLoader);
}
 
function handleImageComplete(event:Event):void {
    var imageLoader:Loader = LoaderInfo(event.target).loader;
    trace(imageLoader.width + " / " + imageLoader.height);
}