bild auf mc in den hintergrund

[greenboy]

hallo,

ich lade ein jpg auf ein mc, danach setze ich mehrere kleine clips auf das mc.
nun sind diese aber leider immer hinter dem jpg, obwohl ich sie später lade und auch noch den childIndex vorreihe. kann mir jemand auf die sprünge helfen?
danke!

public class  Adventkalender extends MovieClip{
        
        public var map_mc:MovieClip = new MovieClip();
        public var maxFlocken:int = 50;
        public var flockenArray:Array = new Array();
        
           public function Adventkalender():void {             
              
              generateFlocken();
              load_map();
              this.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoved);            
           }
           
           private function load_map():void {
              var myLoader:Loader = new Loader();
              //myLoader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, preloading); 
            myLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, setPicMap);
              myLoader.load(new URLRequest('pics/kalender.jpg'));
           }
           
           private function setPicMap(e:Event):void {
              map_mc.x = 0;
              map_mc.y = 0;
              var bitmapfile:Bitmap = Bitmap(e.currentTarget.content);
              map_mc.addChild(bitmapfile);
              addChild(map_mc);
           
           }
           
           private function mouseMoved(e:MouseEvent):void {
                 var sfX:Number  = (map_mc.width/stage.stageWidth);
                 var sfY:Number  = (map_mc.height/stage.stageHeight);
                 map_mc.x =  - (sfX * e.stageX)+e.stageX;
                 map_mc.y = - (sfY * e.stageY)+e.stageY;
           }
           
           
           private function generateFlocken() {
              var i:int = 0;
                 while (i< maxFlocken) {   
           
                       var flo:Flocke = new Flocke();
                       flo.x = int(stage.stageWidth * Math.random());
                       flo.y = int((stage.stageHeight/3) * Math.random());
                       flo.name = i+'flo';
                       flockenArray[i] = flo;                     
                       map_mc.addChild(flockenArray[i]);
                       map_mc.setChildIndex(map_mc.getChildByName(i+'flo'), map_mc.numChildren-1);
                       i++;
                 }
           }            
     }

[hgseib]

wo und wann addChild's du myLoader?

trace("sicher der erste? "+map_mc.numChildren);
map_mc.addChildAt(bitmapfile,0);


gönne deinen flocken ein eigenes sprite


starte generateFlocken() nach dem laden des bildes. also nach setPicMap

[greenboy]

das wars:

map_mc.addChildAt(bitmapfile,0);

dann funkts.
nun, die floggen sind movieclips, die exportiert wurden. das soltle schon so passen. denn wenn ich die map verschiebe, sollen sich die floggen auf ihr auch verschieben. daher hab ich die floggen direkt auf die map gesetzt.

thnx für die hilfe!

[thomas_E]

ich hab deinen Code mal etwas überarbeitet und die Änderungen Kommentiert

PHP-Code:

package //...
{
    import flash.display.DisplayObject;
    import flash.display.Sprite;
    import flash.display.Loader;
    import Flocke;    //package musst du ergänzen, falls nötig
    
    public class Adventkalender extends Sprite    //wieso MC? reicht nicht auch ein Sprite?
    {
        //wieso public? nichts von ausserhalb dieser Klasse 
        //sollte direkt auf diese Eigenschaften zugreifen (können)
        
        //das hinzufügen des Datentyps in den Variablennamen finde ich selten sinvoll
        private var map:Sprite = new Sprite();    //hier reicht in jedem Fall ein Sprite
        private var maxFlocken:int = 50;
        private var flocken:Array = [];    //ich bevorzuge diese Schreibweise; is kürzer :D

        public function Adventkalender():void
        {
            generateFlocken();
            loadMap();
            this.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoved);            
        }

        //in AS wird eigentlich nur camelCase verwendet (ausser bei Konstanten)
        private function loadMap():void
        {
            //myIrgendwas? :-/
            var loader:Loader = new Loader();
            //loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, preloading); 
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, setPicMap);
            loader.load(new URLRequest('pics/kalender.jpg'));
        }

        private function setPicMap(e:Event):void
        {
            //bitte aufräumen
            e.currentTarget.removeEventListener(Event.COMPLETE, setPicMap);
//            e.currentTarget.removeEventListener(ProgressEvent.PROGRESS, preloading); 
            
            map.x = 0;
            map.y = 0;
            //das casten nach Bitmap kannst du dir sparen, es sei denn, du willst hier noch was machen, 
            //wofür du explizit ein Bitmap benötigst (bspw auf bitmapData zugreifen)
            var background:DisplayObject = e.currentTarget.content;
            map.addChildAt(background, 0);
            addChild(map);
        }

        private function mouseMoved(e:MouseEvent):void
        {
            var sfX:Number = (map.width/stage.stageWidth);
            var sfY:Number = (map.height/stage.stageHeight);
            //eigentlich nur Geschmackssache, ich find das so herum schneller ersichtlich was dabei rauskommt
            map.x = e.stageX -(sfX * e.stageX);
            map.y = e.stageY -(sfY * e.stageY);
        }

        //alle Funktionen sollten den Rückgabetyp definert haben.
        private function generateFlocken():void
        {
            //ich find eine for-Schleife hier passender, zumal ich alles für ihren Ablauf im Kopf definiere,
            //und mir in der Schleife keine Gedanken mehr zu machen muss (bspw, dass ich ++i vergesse)
            for(var i:int = 0; i<maxFlocken; ++i){
                var flocke:Flocke = new Flocke();
                    flocke.x = int(stage.stageWidth * Math.random());
                    flocke.y = int((stage.stageHeight/3) * Math.random());
                    //flocke.name; namen sich nur Schall und Rauch, und in AS3 imo überflüssig und kontraproduktiv

                flocken[i] = flocke;
                //du hast hier eine Referenz auf das Objekt selber, also nutz diese auch,
                //und hol diese nicht nochmal aus dem Array
                map.addChild(flocke);
            }
        }            
    }
} 


und jetzt noch eine Anmerkung, wofür benötigst du noch einen Container (map)? eigentlich kannst du map durch this ersetzen.
Oder kommt noch andere Programmlogik hinzu, die diese separaten Sprites nötig macht? Beispielsweise, damit du noch etwas zum AdventsKalender hinzufügst, was sich nicht mitbewegen soll?

nunja, letztlich hat jeder seinen eigenen Programmierstil. schau, was du aus meinen Anmerkungen für dich rausholen kannst/willst

[greenboy]

wow - da sag ich mal VIELEN DANK für die mühe und die hilfreichen tipps.
hab ich was dazugelernt.

nur eines: den konstruktor muss ich public machen, sonst gibts fehlermeldungen...
-> Ein Konstruktor kann nur als 'public' deklariert werden.

[milchreis]

Zitat von greenboy

nur eines: den konstruktor muss ich public machen, sonst gibts fehlermeldungen...
-> Ein Konstruktor kann nur als 'public' deklariert werden.

Thomas meinte nicht den Konstruktor, der kann 1.) nicht private sein (sprachliche Einschränkung) 2.) wäre es in diesem Fall auch nicht sinnvoll, da du ja von außen auf ihn zugreifen willst.
Der Konstruktor in seinem Code ist ja auch public.

Es ging viel mehr um die Variablen, die praktisch niemals public sein sollten.

[greenboy]

alles klar. da hab ich meinen und den ausgebesserten code vertauscht.