AS3: Variable von contentLoaderInfo-Complete an Funktion übergeben

[Lutzovic]

Hi Flashs,

Ich versuche mich gerade zum ersten mal in AS3 (tock tock),
klappt schon immer besser aber ich checke gerade einen speziellen Part nicht.

Beispiel ist eine Bildergalerie, diese erstellt per for schleife einzelne Movieclips nacheinander aus der Bibliothek (mc fotobox) in einen container auf der Bühne.
Das funktioniert alles auch mit dem laden wunderbar.

mein Problem:

Wie kann ich an die Funktion die von folgendem code ausgelöst wird: (bsp.: 'done')

loader.contentLoaderInfo.addEventListener(Event.COMPLETE, done);

die erstellte Instanz übergeben?

so sieht der ganze Abschnitt aus:
Ich will in Funktion 'done' später eine Skript packen das mir die Bilder an die fotobox Instanz anpasst. So funktioniert das nur mit dem letzten.

//AS3:
for (i = 0; i < bildanzahl; i++)
{
	var myfotobox:fotobox = new fotobox();

	myfotobox.name = "Fotobox"+i;
	trace ("myfotobox : "+myfotobox.name);

	myfotobox.x = raster;
	raster += rastermas;
	container.addChild(myfotobox);
	
	//Bild wird hineingeladen:
	var request:URLRequest = new URLRequest(Bildordner+Fotoarray[i]);
	var loader:Loader = new Loader()
	loader.load(request);
	loader.contentLoaderInfo.addEventListener(Event.COMPLETE, done);
	myfotobox.foto.addChild(loader);
	
	}


function done(event:Event):void {
	trace("loaderCompleteHandler 'done' ausgeführt");
    	trace(event);
	//wie kann ich hier den zu ladenden Movieclip ansprechen?
	//hier soll per Skript die jeweilige Instanz Größe angepasst werden
	}

in AS2 konnte ich das doch recht easy mit der MC variable?

//AS2:
mclListener.onLoadInit = function(mc:MovieClip) {
	trace (mc); // instanzname, Movieclip
	}

Habe schon mit loader.content.name rumgefummelt aber nix besonders erreicht.
Ich denke mal das gibt es einen easy kniff oder?

danke schon mal
Lutz

[bobo_k1]

Zitat von Lutzovic

function done(event:Event):void {
trace("loaderCompleteHandler 'done' ausgeführt");
trace(event.currentTarget.width);
trace(event.currentTarget.height);
}
[/CODE]

so..

[Lutzovic]

Cool bobo_k1,

teste ich direkt mal, klingt aber schon sehr einleuchtend

Danke.

[Lutzovic]

Auslesen hat gut funktioniert, nur verändern nicht.

function done(event:Event):void {
		trace(event.currentTarget.width);
		trace(event.currentTarget.height);
		event.currentTarget.width = 400;
		event.currentTarget.height = 300;
		}

currentTarget und target sind beide schreibgeschützt, ich bekomme folgenden Fehler:

ReferenceError: Error #1074: Unzulässiger Schreibvorgang in schreibgeschützte Eigenschaft width in flash.display.LoaderInfo

Wie kann ich die Eigenschaften der Instanz in meiner Funktion verändern?

Grüße

[bobo_k1]

scaleX und scaleY

[Lutzovic]

Danke Bobo k1,

muss mir das doch nochmal genauer anschauen, den auch scaleX / Y liefert einen Fehler:

ReferenceError: Error #1056: Eigenschaft scaleY in flash.display.LoaderInfo kann nicht erstellt werden.

function done(event:Event):void {

	trace(event.currentTarget.height);
	var faktor:Number = (bildhoehe/event.currentTarget.height);
	trace("Faktor : "+faktor);
	event.currentTarget.scaleY = faktor;
	event.currentTarget.scaleX = faktor;
	
	// auch mal zum test, geht aber auch nicht:
	/*var testsprite:Sprite = event.currentTarget as Sprite;
	trace("Sprite : "+testsprite.height);
	testsprite.scaleY = faktor;
	testsprite.scaleX = faktor;*/
	
	}

Bestimmt noch ein Fehler drin den ich AS3 mäsig noch nicht beachte.

Grüße
Lutz

[bobo_k1]

du musst die content-Property der contentLoaderInfo ansprechen - hier gibts mehr infos flash.display.Loader (ActionScript 3.0)

[RustyCake]

PHP-Code:

loader.content.height = faktor;
loader.content.width = faktor; 


[Lutzovic]

Zitat von bobo_k1

du musst die content-Property der contentLoaderInfo ansprechen - hier gibts mehr infos flash.display.Loader (ActionScript 3.0)

Danke euch beiden,

ich habe es jetzt gepackt,
hatte nach der erneuten loader lektüre erst gecheckt das es neben loader.content auch loaderInfo.content gibt, bobo hatte es ja schon geschrieben.

folgendermasen sieht es jetzt aus und funktioniert:

function done(event:Event):void {

	//Bild wird auf Containergröße gebracht:
	var faktor:Number = (bildhoehe/event.currentTarget.height);
	event.target.loader.scaleX = faktor; 
	event.target.loader.scaleY = faktor;
	
	//hiermit wird zentriert:
	event.target.loader.x = (rastermas/2)-((event.target.width*faktor)/2);
	
	}

Vielen Dank für die Hilfe