Antialiasing von Systemschriften mit der FTE?!

[Martin Kraft]

Ich baue gerade einen XML-gefütterten Header mit animierter Schrift, die geglättet dargestellt werden muss, um nicht zu ruckeln. Dummerweise soll darin u.a. chinesischer Text dargestellt werden. Wenn ich den chinesischen Teil der "Arial Unicode" einbette, wächst die SWF jedoch auf indiskutable 6,6 MB. Deshalb versuche ich jetzt das Problem mit einer Systemschrift zu lösen.

Nun bin ich auf diesen Beitrag hier gestoßen, der behauptet, dass mit Hilfe der FlashTextEngine seit FlashPlayer 10 auch Systemschriften geglättet dargestellt werden können.

Also habe ich mich mit Hilfe dieses Artikels mal in das Thema eingearbeitet, schaffe es aber leider nicht, dass den Text geglättet dargestellen zu lassen.

Hier der zugehörige Code:

PHP-Code:

        static public function createText( str:String, color:uint = 0 ):TextLine {
            
            var fontDescription:FontDescription = new FontDescription("_sans", "bold");
            fontDescription.renderingMode = RenderingMode.NORMAL;
            fontDescription.fontLookup = FontLookup.DEVICE;
            
            var format:ElementFormat = new ElementFormat(fontDescription, 14, color); 
            var textElement:TextElement = new TextElement(str, format); 
            var textBlock:TextBlock = new TextBlock(textElement); 
            textBlock.content = textElement;
            
            var textLine:TextLine = textBlock.createTextLine(null, 300);             
            
            return textLine;
        } 


Ist es Generell möglich Systemschriften zu glätten (wenn ja wie?) oder ist das ganze ein Gerücht?

Schon vorab vielen Dank für Eure Hilfe!

P.S.: Ich hab für chinesisch diese folgende Unicode-Range gefunden: 4E00-9FFF. Gibt es ggf. einen kleineren Satz, der für vereinfachtes Chinesisch ausreicht?

[Martin Kraft]

*ThreadNachObenHol* Ist wirklich noch nie jemand auf dieses Problem gestoßen?

Mir leuchtet es generell nicht ganz ein, warum Flash eingebettete Schriften so anders behandelt als auf dem Clientsystem installierte. Die Datenbasis ist schließlich in beiden Fällen dieselbe (eben eine PS, TT oder OpenType-Schrift). Es müßten also alle nötigen Informationen zur Verfügung stehen...

Oder ist die transcodierung der Schriften ins SWF-interne Format so aufwändig, das sie nicht on-the-fly ausgeführt werden könnte?

[Martin Kraft]

*ThreadNochmalNachObenHol* Ich kann mir irgendwie nicht vorstellen, dass ich der Einzige bin, der sich bisher mit diesem Problem beschäftigen musste?!

Mir würde es auch weiterhelfen, wenn ...

• ...mir jemand sagt, dass es definitiv nicht geht, Sytemschriften zu glätten?!
• ...jemand eine andere Lösung weiß, wie man chinesische Zeichen bei vertretbarer Dateigröße für dynamischen Text integriert?

[shin10]

oh hi martin,

danke fürs hochholen. der wär mir durchgewitscht. ich hab das noch nicht gemacht und komm heut auch noch nicht dazu, aber das sieht echt interessant aus. und das beispiel bei insideRIA beweist ja eigentlich, dass es geht ...

ich gehs die tage mal durch und meld mich wieder. bis denne.

mfg

sx

[shin10]

hi,

da bin ich wieder. wahrscheinlich hast du das kleine geheimnis schon raus. Y!! aber mal wieder echt nett, dass sie das nirgends dazuschreiben

PHP-Code:

function createText( str:String, color:uint = 0 ):TextLine
{

    var fontDescription:FontDescription = new FontDescription("_sans","bold");
    fontDescription.renderingMode = RenderingMode.NORMAL;
    fontDescription.fontLookup = FontLookup.DEVICE;

    var format:ElementFormat = new ElementFormat(fontDescription,14,color);
    var textElement:TextElement = new TextElement(str,format);
    var textBlock:TextBlock = new TextBlock(textElement);
    textBlock.content = textElement;

    var textLine:TextLine = textBlock.createTextLine(null,300);

    return textLine;
}

addChild(createText("Bazinga!", 0));
y = 12;//<< da liegt der hase im pfeffer!

var bmpd:BitmapData = new BitmapData(200,200,true,0);
var bmp:Bitmap = new Bitmap(bmpd);
bmp.x = 200;
addChild(bmp);
bmpd.draw(stage, new Matrix(1, 0, 0, 1, 0, 0));
bmp.scaleX = 5;
bmp.scaleY = 5; 


aber die gute nachricht: dein code hat immer funktioniert.

mfg

sx

EDIT: geil. danke!

editEDIT: allerdings merk ich gerade, dass er auch glättet, wenn ich ein normales textfeld beim antialiasing auf devicefont stell
bin ich jetzt deppert??

[Martin Kraft]

Hi shin10!

Cool, dass Du Dich nochmal mit meinem Problem beschäftigt hast. Allerdings ist mir nicht so ganz klar, was Du z.B. mit diesem Code bewirkst:

PHP-Code:

y = 12;//<< da liegt der hase im pfeffer! 


Wäre schön, wenn Du das etwas erläutern könntest. Das BmpData verwendest Du ja nur um das AntiAliasing zu vergrößern?!

[Martin Kraft]

Auch ich hab da mittlerweile etwas weitergeforscht aber noch keine Zeit gefunden das hier zusammen zu schreiben - Sorry.

Ich habe also bei Adobe diesen Thread gefunden, dessen wohl wichtigster Satz der hier ist:

Zitat von Jeff Mott | Flash Platform Engineering

Device fonts not only reside on the local system, they are rendered by the OS and not by the player. The player does not currently have the capability to render them internally. Obviously nothing is impossible, and this capability may be added to a future player.

Systemfonts werden also in der FTE entsprechend der Betriebssystemeinstellungen geglättet. Dieses AntiAliasing hat also nichts mit den bekannten AntiAliasingModes NORMAL oder ADVANCED zu tun

Und gerade das ist in meinem Fall das Problem. Ich hätte die normale Flash-Schriftenglättung gebraucht, um eine flüssige Animation zu erzeugen.

Darum habe ich mir folgenden Workaraound ausgedacht: Ich zeichne den un- bzw. falschgeglätten Text leicht vergrößert in ein BitmapData und ersetze ihn dann durch ein entsprechend wieder herunterskaliertes Bitmap. Wie im Ergebnis zu sehen, ist das Ergebnis ist zwar nicht ideal, garantiert aber eine halbwegs ruhige Bewegung.

Hier ist der zugehörige Code, der grundsätzlich mit jedem DisplayObject funktionieren sollte, dass ruckelt, weil es sich an Pixeln ausrichtet (z.B. DropShadow-Filter):

PHP-Code:

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.DisplayObject;
import flash.display.DisplayObjectContainer;
import flash.display.PixelSnapping;

static public function toSmoothBitmap( dob:DisplayObject, replace:Boolean = false, scale:Number = 1.1 ):Bitmap {
    
    var rect:Rectangle = dob.getBounds(dob);        
    var bmpData:BitmapData = new BitmapData(rect.width*scale, rect.height*scale, true, 0);
    bmpData.draw(dob, new Matrix(scale, 0, 0, scale, -rect.x, -rect.y));
    
    var bmp:Bitmap = new Bitmap(bmpData, PixelSnapping.NEVER, true);

    var pob:DisplayObjectContainer = dob.parent;    
    if (replace && pob) {
        pob.addChildAt(bmp, pob.getChildIndex(dob) );
        bmp.x = dob.x + rect.x;
        bmp.y = dob.y + rect.y;
        bmp.alpha = dob.alpha;
        bmp.scaleX = 1 / scale;
        bmp.scaleY = 1 / scale;                
        pob.removeChild(dob);
    } else {
        bmp.scaleX = bmp.scaleY = 1 / scale;
    }
    
    return bmp;
} 


[shin10]

Wäre schön, wenn Du das etwas erläutern könntest. Das BmpData verwendest Du ja nur um das AntiAliasing anzuzeigen?!

ja, das bitmap war nur um zu schaun ob es funktioniert. die sache mit dem y war, dass ich mich erstmal wahnsinnig gewundert hab, dass der code auf der von dir angeführten seite bei mir "gar nichts" bewirkt hat. tatsächlich liegt scheinbar die textzeile, wenn sie auf y=0 liegt, über dem bühnenrand und ich hab nur nicht gesehen, dass text erzeugt wird. also hab ich kurzerhand die ganze bühne runtergeschoben.

wenn ich dich jetzt aber so hör war das wohl weniger dein problem als meins. wär bei dir wohl auch zu einfach gewesen. da scheuer ich mir doch gleich eine
dass das antialiasing aber betriebssystemabhängig ist und so für animation nichts als rotz ist, hatte ich noch gar nicht geschnallt. wirklich schade.

deine lösung sieht aber doch ganz gut aus. gerade bei so langsamen bewegungen wirds in flash ja seltenst besser, als das was ich da seh. und das ohne einbettung. wer will da meckern

mfg

sx

edit: die großen kreise sind noch ganz leicht angeschnitten, seh ich gerade...