addEventListener auf eine nicht instantiierte Klasse anwenden

[Mattcheck]

Hallo,

ich entwickle gerade eine Adobe Air Datein mit Flash Professional und den Code bearbeite ich mit FlashBuilder.
Man kann in dem Programm mehrere Einstellungen tätigen. Dazu habe ich gedacht, dass ich eine "Setting" Klasse erstelle, die nicht instantiiert wird. Diese soll über eine "public static function" namens "save" verfügen. Sobald man also einen Knopf drückt wird die Stativ.save - Methode aufgerufen.
Diese Funkion soll dann ein Event "dispatchen", damit an anderer Stelle diese ändernung der Einstellung bemerkt wird.
Bis hier hin funktioniert auch alles. Jetzt kommt das Problem.
Ich möchte über Setting.addEventListener(...) das Event abfragen.

Ich denke das Problem ist, dass Settings kein Objekt sondern eine Klasse ist auf die man nicht direkt zugreifen kann.

Was gibt es für mögliche Lösungen?

Danke schonmal im Vorraus und ich hoffe ich habt es alle verstanden ansonsten kann ich auch den Code mit schicken aber es geht ja nur ums Prinzip!

Gruß Matti

[padavan]

ich würde die save-methode garnicht in der static-klasse machen

ich seh die static-klasse mehr als datencontainer (model) und das speichern würde eher dem controller zufallen, oder?

lass mich auch gern berichtigen...

edit: zur frage, glaub nicht dass du ohne instanz nen listener hinzufügen kannst..sschon probiert?

[shin10]

Hi,

bist du mit dem Singleton-Pattern vertraut?

mfg

sx

[Martin Kraft]

Ich habe mir vor einiger Zeit für diesen Zweck mal eine Klasse gebastellt (die ein Singleton ist, für den ich auch schon meine Prügel bezogen habe ):

PHP-Code:

package net.martinkraft.utils {
    import flash.events.Event;
    import flash.events.EventDispatcher;
    
    /**
     * @author Martin Kraft
     */
    
    public class StaticEventDispatcher extends EventDispatcher{
        
        ////
        
        private static var _instance:StaticEventDispatcher;
        
        ///////////////////////////////////////////
        
        public function StaticEventDispatcher( si:SingleInstance ) {
            super();
        }
        
        ///////////////////////////////////////////
        
        // Instance functions to static
        
        static public function addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = true):void {
            instance.addEventListener(type, listener, useCapture, priority, useWeakReference);
        }
        
        static public function dispatchEvent(event:Event):Boolean {
            return instance.dispatchEvent(event);
        }
        
        static public function hasEventListener(type:String):Boolean {
            return instance.hasEventListener(type);
        }
        
        static public function removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void {
            instance.removeEventListener(type, listener, useCapture);
        }
        
        static public function willTrigger(type:String):Boolean {
            return instance.willTrigger(type);
        }
        
        ////
        
        static public function get instance():StaticEventDispatcher { 
            if(!_instance) _instance = new StaticEventDispatcher( new SingleInstance() );
            return _instance;
        }
        
    }
}

internal class SingleInstance {
    /// protects Singleton
    public function SingleInstance():void { }
} 


[Omega Psi]

Nächste Woche gibt es dazu einen Artikel von mir ... also, warum man einen Singleton vermeiden kann und seine Projekte gar noch skalierbar hält.

[shin10]

Muss ich dafür die Zeit oder die Süddeutsche kaufen?

[Omega Psi]

Ach so, ne ... ich hab eine neue Domain.

[Martin Kraft]

Wir sind gespannt

[shin10]

Zitat von Omega Psi

Ach so, ne ... ich hab eine neue Domain.

Sowas hast du doch schon vor 6 Monaten behauptet.

[Omega Psi]

Ach so.. hm... ne, wirklich ... vielleicht. Jetzt habe ich sie aber wirklich ...

[shin10]

Na ich tu da ja auch schon seit über nem Jahr rum hatte aber zumindest letzte Woche endlich einen Einfall, der Potential genug hat um tatsächlich mal fertig zu werden bevor ich mich langweile ... mal sehen.