ActionScript Interne SWF auf Parent zugreifen

[hothead89]

ich habe folgendes Problem.

Ich habe mit hilfe des Loaders eine externe swf (ext.swf) geladen in den Film haupt.swf.

var var1:loader = new Loader();

an diese SWF wird auch eine userid geschickt die in der haupt.swf vorhanden ist. nach dem verarbeiter aller funktionen in ext.swf soll

erstens:
eine Variable an haupt.swf zurückgegeben werden
zweitens:
die haupt.swf mit play oder nextFrame(), fortgestezt werden.

wie kann ich erstens und zweitens verwirklichen?
Vielen Dank für die Hilfe

[webber]

Das hier dürfte Interessant sein:
Flex 3 - Adobe Flex 3 Help

Da wird im Complete-Handler auf die Haupt-Klasse der swf gecastet.
Funktioniert bei mir aber auch, wenn ich es auf Object caste, da ich die
Klasse nicht im Loader importieren wollte.

Grooce
webber

[hothead89]

das ist irgendwie nicht so richtig nach was ich suche...

ich stelle nun mal folgendes beispiel dar:

main.swf
Bild 1 :

stop();
var test:Loader = new Loader();

var url:URLRequest = new URLRequest();
url.url = "test.swf";

test.load(url);
addChild(test);

Bild2 :

stop();

test.swf
Bild1 enthält eine schaltfläche namens "scha";

scha.addEventListener(MouseEvent.MOUSE_UP, doit, false, 0, true);

function doit(evt:MouseEvent):void{
	???  *1
}

bei ??? *1 sollte dann eben der code hin, der besagt, dass bei main.swf nextFrame(); ausgeführt wird. Was genau muss da hin?

Vielen Dank schon mal

[figure8]

hey, dein bester freund in dem zusammenhang wird wohl dispatchEvent sein.

du kannst dir das so vorstellen: du hast eine wohnung, das ist deine main.swf. in dieser wohnung erstellst du ein zimmer, das wäre deine test.swf. so, nun kann das zimmer machen, was es will - licht anmachen, fenster auf, whatever, ist ein kreatives zimmer jetzt ist es so, dass das zimmer die tür immer zu hat, weil die restliche wohnung garnix davon mitbekommen soll und auch nicht will - wenn man 10 zimmer hat, würde das ja schnell anstrengend werden. du kannst aber dem zimmer sagen "hey, wenn du das licht anmachst, dann sag der wohnung bescheid." - da kommt das eventsystem ins spiel. du kannst der wohnung sagen "pass auf, hör (listen) auf das event "licht anmachen" von zimmer1". und dem zimmer1 sagst du "dispatch das event (sag bescheid), dass du das licht anmachst!" wenn du ein bißchen darüber gelesen hast, wirst du auch über bubbling stolpern, das ist jetzt gerade nicht wichtig, aber damit würdest du sagen "hm, die wohnung allein soll das aber nicht wissen, sondern auch das haus. also geht das event noch weiter nach oben, wenn man sich's haus -> wohnung -> zimmer vorstellt.
wie dem auch sei, wenn dich nur das codesnippet interessiert - das ganze schaut so aus:

// Main.swf
 
// lädt das swf. wenn's fertig ist (Event.COMPLETE) geht's zur nächsten fkt.
loadSWF();
 
function loadSWF():void {
    var swfPath:URLRequest = new URLRequest();
    swfPath.url="ToLoad.swf";
 
    var swfLoader:Loader = new Loader();
    swfLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, addSWF);
    swfLoader.load(swfPath);
}
 
// fügt das swf zur anzeigeliste hinzu und added den eventlistener
function addSWF(event:Event):void {
    var swfContent:* =event.target.content;
    swfContent.addEventListener("goNextFrame", nextFrameHandler);
    addChild(swfContent);
}
 
// wird ausgeführt, wenn das event von der geladenen swf dispatched wird
function nextFrameHandler(event:Event):void {
    nextFrame();
} 

// ToLoad.swf
 
btn.addEventListener(MouseEvent.CLICK, mainNextFrame);
 
// erstellt ein neues event, das bubblen darf und nicht abbrechbar ist.
function mainNextFrame(event:MouseEvent):void {
    var nextFrameEvent:Event = new Event("goNextFrame", true, false);
    dispatchEvent(nextFrameEvent);
} 

hoppla, vertippt

[hothead89]

wow respekt...das mit der wohnung und zimmer und so ist eine super metapher!!! VIELEN DANK! Somit hab ichs verstanden und ausprobiert und siehe da es geht VIELEN DANK nochmal solche beschreibungen liest man gerne

[figure8]

gerngeschehen, freut mich, wenn bei dir das licht angegangen ist.

[jav666]

was 'ne super erklärung! genau das habe ich gesucht!

PHP-Code:

for(var n:int=1;n<=1000;n++)trace("1000 DANK!!!")