[AS3] Problem mir eigenen Event für Klasse

[julianeS.85]

ich glaub ich solltes sein lassen ...

hab jetzt:

• Event.bubbles, Event.cancelable, and Event.currentTarget : Ruben’s blog
• Digital Media For Artists - ActionScript3: Ereigniskonzept und Eventhandler - eine kurze Einführung
• Introduction to event handling in ActionScript 3.0 | Adobe Developer Connection

durchgelesen, hoert sich auch ganz schluessig an, nur will es einfach nicht

Wenn deine Klassen DisplayObjecte sind, kannst du beim dispatchen bubbles auf true setzten, dann geht das Event durch die ganze DisplayListe.

Genau das will ich

Mein Ansatz auf den letzten Beispiel:

hoerer.as

PHP-Code:

package classes
{
    import flash.events.Event;
    import flash.events.EventDispatcher;
    import flash.display.*;
    public class Hoerer extends MovieClip
    {
        public function Hoerer()
        {

        }
        public function addDispatcher():void
        {
            addEventListener(Events.STARTE, startByEvent);
        }
        public function startByEvent(e:Events)
        {
             trace("startByEvent - Dispatcher: " + e.currentTarget);
        }
    }
} 


main.as //beinhaltet die Klasse Ausloeser

PHP-Code:

package classes
{
    //Imports
    import flash.display.*;
    import flash.events.*;
    import flash.events.EventDispatcher;
    
    public class Main extends Sprite
    {
        public function Main()
        {
        
        }
        public function erstellen()
        {
            var meinAusloeser:Ausloeser = new Ausloeser();
            this.addChild(meinAusloeser);
            meinAusloeser.ausloesen();
        }
    }        
} 


ausloeser.as

PHP-Code:

package classes
{
    //Imports
    import flash.display.*;
    import flash.events.*;
    import flash.events.EventDispatcher;
    
    public class Ausloeser extends Sprite
    {
        public function Ausloeser()
        {
            //Hier soll der Dispatcher für Hoerer abgegeben werden
        }
        public function ausloesen()
        {
            dispatchEvent(new Events(Events.STARTE, null));
        }
    }        
} 


events.as

PHP-Code:

//subclass semster
package classes
{
    // Import der Flash Eventklasse
    import flash.events.*;

    public class Events extends Event
    {
        // Eventarten, bekanntes Beispiel: MouseEvent.CLICK
        public static const STARTE:String = "STARTE";
 
        // Variable in denen wir zusätzliche Eventdaten speichern können
        public var _data:Object;
 
        // Der Konstruktor
        public function Events(type:String, data:Object, bubbles:Boolean=true, cancelable:Boolean=false) 
        {
            super(type, bubbles, cancelable);
            _data = data;
            trace("Konstruktor von Events");
            trace("TYPE: " + type);
        }

        override public function clone():Event
        {
            return new Events( this.type, this.data, this.bubbles, this.cancelable); 
        }

        public function get data():Object
        {
            return _data;
        }
    }
} 


main.as

PHP-Code:

import classes.Hoerer;
import classes.Ausloeser;
import classes.Main;
import classes.Events;
import flash.events.*;
import flash.events.EventDispatcher;

var meinHoerer:Hoerer = new Hoerer();
stage.addChild(meinHoerer);
meinHoerer.addDispatcher(); 

var meinMain:Main = new Main();
stage.addChild(meinMain);
meinMain.erstellen(); 


[Lukas78]

Sorry etwas unklar ausgedrückt, müssen nicht nur DisplayObjecte sein sondern auch in der DisplayListe stehen. Also irgendwo mit addChild hinzugefügt werden.

Also irgendwo noch den Hoerer in die DisplayListe setzten dann sollte es gehen.

Das durchreichen der Events ist allerdings die etwas sauberere Lösung.

[julianeS.85]

mit stage.addChild(meinHoerer); fuege ich doch meinHoerer als Kindknoten der Buehne hinzu, somit sollte er doch in der DisplayList stehen, oder seh ich das falsch?

trace(stage.numChildren)

sagt mir auch nach dem ich stage.addChild(meinHoerer); ein Child mehr

[Lukas78]

Jep hatte ich überlesen. Mmh dann weiß ich es auch nicht so recht.

Events die bubblen versuche ich eigentlich immer zu meiden, die marodieren dann gerne durch die ganze DisplayListe und lösen Sachen aus die sie nicht sollen. Oder aber wie in deinem Fall tauchen nicht auf und man kann nicht verfolgen ob und wo sie hängen bleiben und warum.

Blick auch nicht ganz durch dein Konstrukt durch und ehrlich gesagt ist es mir noch etwas schleierhaft welchen Sinn das hat. Wirkt so ein wenig umständlich bis unsauber.

[julianeS.85]

Okay Lukas, ich hab jetzt deinen anderen Vorschlag mit dem durchreichen genommen und funktioniert auf anhieb! Nochmal vielen Dank auch für deine Geduld *daumenhoch*

Blick auch nicht ganz durch dein Konstrukt durch und ehrlich gesagt ist es mir noch etwas schleierhaft welchen Sinn das hat. Wirkt so ein wenig umständlich bis unsauber.

Ja meine Anwendung ist sicher auch umständlich³, sind aber mein ersten Gehversuche mit Actionscript. Ich bin nur rroh wenns läuft alles andere wird sicher mit der Zeit und dem studieren von Quellcode anderer Entwickler

Ich verusch es jetzt mal in meine Anwendung zu integrieren ...

[mohj]

Events bubblen nur nach oben und nicht durch die gesamte DisplayList. D.h. der Event geht vom Dispatcher durch alle Parents davon. Demzufolge registriert der Listener in der Hörer Klasse kein Event, da sich die Auslöser Klasse nicht innerhalb der Hörer Klasse befindet.

Du kannst in der addDispatcher Methode der Hörer Klasse die Listener an die stage hängen, dann funktionierts auch mit dem Bubblen.

[Omega Psi]

Das Bubbling funktioniert nicht, weil Hörer nicht der parent von Auslöser ist. Um Events bubblen zu lassen muss es eine Hierarchie von DisplayObjects geben. In deinem Fall addest du die Elemente nur zur stage. Das hat gar keinen Effekt. Das ist einer der Gründe, warum man nicht direkt mit der stage arbeiten sollte. Es macht of wenig Sinn.

Mein Tipp: mal das Kapitel für Event handling in der Referenz lesen.

Anbei ein Beispiel für Event bubbling.

package fs.components
{
 
  import flash.display.Sprite;
  import flash.events.MouseEvent;
  import flash.utils.getQualifiedClassName;
 
  public class Button extends Sprite
  {
 
    public function Button()
    {
      super();
      addEventListener(MouseEvent.CLICK, onClick);
 
      graphics.beginFill(0);
      graphics.drawRoundRect(0, 0, 100, 100, 10, 10);
      graphics.endFill();
    }
 
    private function onClick(event:MouseEvent):void
    {
      trace(getQualifiedClassName(this) + ".onClick [type:" + event.type + "]");
      trace("\t[currentTarget:" + event.currentTarget + ", target:" + event.target + "]");
    }
  }
} 
 

package fs.components
{
 
  import flash.display.Sprite;
  import flash.events.MouseEvent;
  import flash.utils.getQualifiedClassName;
  
  public class Application extends Sprite
  {
 
    private var _button:Button;
 
    public function Application()
    {
      super();
 
      addEventListener(MouseEvent.CLICK, onClick);
      _button = new Button();
      addChild(_button);
    }
 
    private function onClick(event:MouseEvent):void
    {
      trace(getQualifiedClassName(this) + ".onClick [type:" + event.type + "]");
      trace("\t[currentTarget:" + event.currentTarget + ", target:" + event.target + "]");
    }
  }
} 
 

package
{
 
  import flash.display.Sprite;
 
  import fs.components.Application;
 
  public class AppExample extends Sprite
  {
 
    private var _application:Application;
 
    public function AppExample()
    {
      _application = new Application();
      addChild(_application);
    }
  }
}