AS 2.0 in AS 3.0 umwandeln

[Illtras]

Guten Abend Leute,
und ein schönes neues Jahr

Und wie sagt man so schön. Neues Jahr, neue Probleme. Hab da ne Datei gefunden welche aber mit AS 2.0 erstellt wurde. Die müsste ich aber in AS 3.0 umwandeln und hab da keine Ahnung wie das klappen sollte. Die AS 3.0-Datei sollte gleich wie die AS 2.0-Datei funktionieren.

Hab schonmal probiert es in AS 3.0 umzuwandeln aber der Effekt wird dann nicht mehr korrekt ausgeführt.

Im Anhang hab ich beide Dateien eingefügt. Beide mit CS5 erstellt und um sicher zu gehen hab ich auch die SWF-Dateien eingefügt.

Hoffe jemand kann mir beim Problem behilflich sein.

mfg
Illtras

[Illtras]

hier auch die beiden codes

der AS 2.0 Code:

PHP-Code:

    C_hitLeft_x = circleHit._x - 6;
    C_hitTop_y = circleHit._y + 6;
    C_hitRight_x = circleHit._x + 6;
    C_hitBottom_y = circleHit._y - 6;

    drag_me.onPress = function() {

        startDrag(this, false);

    }

    drag_me.onRelease = function() {

        stopDrag();
        if (this._x < C_hitRight_x && this._x > C_hitLeft_x && this._y < C_hitTop_y && this._y > C_hitBottom_y) {

            this.gotoAndStop(5);

        }
        else {

            this.gotoAndStop(3);

        }

    }

    drag_me.onReleaseOutside = function() {

        stopDrag();

    } 


und der AS 3.0 Code:

PHP-Code:

import flash.events.MouseEvent;
var C_hitLeft_x:Number = circle_mc.x - 6;
var C_hitTop_y:Number = circle_mc.y + 6;
var C_hitRight_x:Number = circle_mc.x + 6;
var C_hitBottom_y:Number = circle_mc.y - 6;
drag_mc.addEventListener (MouseEvent.MOUSE_DOWN, startDragFunktion);
drag_mc.addEventListener (MouseEvent.MOUSE_UP, stopDragFunktion);
function startDragFunktion (e:MouseEvent):void
{
     e.target.startDrag ();
}
function stopDragFunktion (e:MouseEvent):void
{
     stopDrag ();
     if (e.target.x < C_hitRight_x && e.target.x > C_hitLeft_x && e.target.y < C_hitTop_y && e.target.y > C_hitBottom_y)
     {
        e.target.gotoAndStop (5);
     }
     else
     {
        e.target.gotoAndStop (3);
     }
} 


es funktioniert auch beim 1. mal aber wenn ich den kreis aus dem target wieder entferne färbt er sich zwar wieder zurück aber wenn man ihn wieder ins target zieht passiert nichts mehr. in der AS 2.0 datei aber funktioniert es…

-.-

[thomas_E]

ich kann auf Anhieb keinen Fehler im Code erkennen. Und ich kann die FLA-Datei nicht öffnen, ich habe noch kein CS5 !!!

ich würde lediglich den Code etwas aufräumen:

import flash.events.MouseEvent;
import flash.geom.Rectangle;
 
//ist übersichtlicher als 4 Variablen
var C_bounds:Rectangle = new Rectangle(circle_mc.x - 6, circle_mc.y - 6, 12, 12);
 
drag_mc.addEventListener(MouseEvent.MOUSE_DOWN, startDragFunktion);
drag_mc.addEventListener(MouseEvent.MOUSE_UP, stopDragFunktion);
function startDragFunktion(e:MouseEvent):void
{
    e.currentTarget.startDrag();
}
 
function stopDragFunktion(e:MouseEvent):void
{
    stopDrag ();
//  eine Variable ist besser als immer über e.target||e.currentTarget zu gehen; und typsicher
    var mc:MovieClip = MovieClip(e.currentTarget);
 
//  if(mc.x > C_bounds.left && mc.x < C_bounds.right && mc.y > C_bounds.bottom && mc.y < C_bounds.top )
//  oder:
    if(C_bounds.contains(mc.x, mc.y))
    {
        mc.gotoAndStop(5);
    }
    else
    {
        mc.gotoAndStop(3);
    }
} 

und schau dir doch mal den Unterschied zwischen e.target && e.currentTarget an!

[Illtras]

thx für die antworten… wow der code funktionieren thx
hab die animation des kreises nochmals verschachtelt und das war der fehler.

nochmals danke…

mfg
Illtras

[RustyCake]

Und wer hats gefunden

[thomas_E]

Zitat von Illtras

hab die animation des kreises nochmals verschachtelt und das war der fehler.

grundsätzlich ist das ja kein Fehler. nur wenn das der Fehler war, dann solltest du dir erst recht den Unterschied zwischen e.target und e.currentTarget ansehen!

Zitat von RustyCake

Und wer hats gefunden

kapier ich net

[RustyCake]

Das umschreiben in AS3 hab ich gemacht, hat aber erst nicht funktioniert, bis ich den Fehlerhaften Clip gefunden hab.

[Illtras]

achso ^^

hehehe… ja die datei hat schon von anbeginn funktioniert nur dass es mir die animation immer blockiert hat. DAS war der fehler. deswegen hab ich sie nochmals neu eingestellt und jetzt funktionierts.

also alle beiden funktionieren weil ichs mit beiden probiert habe



unentschieden also RustyCake