XML Verarbeitung

[Quasimorrow]

Hallo Gemeinde

Ich habe ein Problem beim verarbeiten eines XMLs. Ich lade das XML, nur kann ich danach auf keines der Nodes, Childs oder deren Values zugreifen, ich bekomme einfach keine Werte aus dem XML gelesen.

Hier das XML (heißt "audience.xml") :

<?xml version="1.0" encoding="UTF-8"?>
<audience>
	<link id="admin">
		<url>admin.html</url>
		<target>_TOP</target>
	</link>
	<link id="faq">
		<url>faq.html</url>
		<target>_SELF</target>
	</link>
	<link id="web">
		<url>web.html</url>
		<target>_PARENT</target>
	</link>
	<link id="php">
		<url>php.html</url>
		<target>_BLANK</target>
	</link>
</audience>

und das ActionScript dazu:

var MyVars:XML = new XML();
MyVars.load("./audience.xml");

trace("Nodes: " + MyVars.childNodes.length );

MyVars.onLoad = function() {
	// Define Vars
	var MyAdmin = MyVars.firstChild.childNodes[0];
	var MyFaq   = MyVars.firstChild.childNodes[1];
	var MyWeb   = MyVars.firstChild.childNodes[2];
	var MyPhp   = MyVars.firstChild.childNodes[3];
	
	admin_trg = MyAdmin.childNodes[1].nodeValue;
	admin_wdo = MyAdmin.childNodes[2].nodeValue;
	faq_trg = MyFaq.childNodes[1].nodeValue;
	faq_wdo = MyFaq.childNodes[2].nodeValue;
	web_trg = MyWeb.childNodes[1].nodeValue;
	web_wdo = MyWeb.childNodes[2].nodeValue;
	php_trg = MyPhp.childNodes[1].nodeValue;
	php_wdo = MyPhp.childNodes[2].nodeValue;
}

Leider sind alle Variablen welche in der onLoad Funktion definere "undefined". Ein trace -auf welchen Node auch immer- bringt immer die Meldung "undefined". So bringt auch der oben stehende Trace als Ausgabe "Nodes : 0"

Beim debuggen des SWFs kann ich aber erkennen das er das XML vollständig einliest.

Wer kann helfen?

[~pyropete~]

So:

// Define Vars
var MyAdmin = this.firstChild.childNodes[0].nodeValue; 

[Quasimorrow]

Hi pyropete.

Leider kein Erfolg. Ein Zugriff über das Schema

        trace("Values: " + MyVars.firstChild.childNodes[0].nodeValue);

bringt wieder als Ergebniss "undefined".

Wenn ich in der Flash-Hilfe nachlese finde ich ein kleines Beispiel welches mir alle Nodes im XML durchläuft uns ausgibt:

if (MyVars.firstChild.hasChildNodes()) {
	// use firstChild to iterate through the child nodes of rootNode
        for (var aNode:XMLNode = MyVars.firstChild.firstChild; aNode != null; aNode=aNode.nextSibling) {
        if (aNode.nodeType == 1) {
            trace(aNode.nodeName+":\t"+aNode.firstChild.nodeValue);
        }
    }
} else {
	trace("No Nodes found");
}

Ich bekomme: No Nodes found. Was also bedeuten würde das ich keine Nodes im XML habe. Aber die sind ja definitv da?!?

[Omega Psi]

Du greifst auf die Daten zu, bevor diese Überhaupt geladen sind, deswegen bekommst du undefined.

var audienceArray:Array = new Array();
var xml:XML = new XML();
xml.ignoreWhite = true;
xml.load("./audience.xml");
xml.onLoad = function() {
    for (var i:Number = 0; i<this.firstChild.childNodes.length; i++) {
        var linkObject:Object = new Object();
        linkObject["id"] = this.firstChild.childNodes[i].attributes["id"];
        linkObject["url"] = this.firstChild.childNodes[i].childNodes[0].firstChild.nodeValue;
        linkObject["target"] = this.firstChild.childNodes[i].childNodes[1].firstChild.nodeValue;
        audienceArray[i] = linkObject;
    }
    startApplication(audienceArray);
}
function startApplication(audienceArray:Array):Void {
    for (var i=0; i<audienceArray.length; i++) {
        trace("Linkobject: "+i);
        for (var j:String in audienceArray[i]) {
            trace("\t"+j+": "+audienceArray[i][j]);
        }
    }
} 

Im Anhang eine schlankere XML, in der ich die Kindknoten <url /> und <target /> in attribute auslagerte um so etwas schöner die Objekte zu füllen.