Variable in onEnterFrame nicht verfügbar

[ninja]

Hallo,

ich habe folgendes Problem:
ich erstelle in der onData Funktion von LoadVars mehrere Movieclips und weise diesen die Variable film_id zu:

PHP-Code:

for(c=0;c<_global.filmArray.length;c++) {
        tmpString = _global.filmArray[c].split("-");
        createEmptyMovieClip('bild'+c+'container',c);
        _root['bild'+c+'container'].loadMovie("../img/film_thumbs/"+tmpString[1]);
        _root['bild'+c+'container'].film_id = tmpString[0];
        trace ('FILM ID : ' +_root['bild'+c+'container'].film_id);
        _root['bild'+c+'container']._alpha = 50;
        _root['bild'+c+'container']._xscale = 50;
        _root['bild'+c+'container']._yscale = 50;
        _root['bild'+c+'container']._y=0;
        _root['bild'+c+'container']._x=px;
        px+=110;    
    } 


Dies funktioniert auch wie erwartet, trace gibt die korrekten Werte aus.
Nun möchte ich in der OnEnterFrame Funktion auf diese Variable wie folgt zugreifen:

PHP-Code:

onEnterFrame = function() {
var c2:Number = 0; 
    do {
        _root['bild'+c2+'container']._x-=speed;
        _root['bild'+c2+'container'].onPress = function() {
            trace (this.film_id);
        }
        _root['bild'+c2+'container'].onRollOver = function() {
            this._alpha = 100;
        }
        _root['bild'+c2+'container'].onRollOut = function() {
            this._alpha = 50;
        }
                ........................
                ................
                .......
        c2++;
    } while (c2 < filmArray.length)

} 


Was mache ich falsch, trace gibt immer "undefined" aus?

Viele Dank vorab
Viele Grüße
Rolf

[RustyCake]

Ich schätze mal, das wird beim laden des Contents überschrieben.

Instanzen der LoadVars-Klasse erzeugen asynchronen Code, d.h. ein Response steht erst nach einer beliebig langen Zeit über eine Callback-Funktion zur Verfügung. Wenn du jetzt schon vor dem Response versuchst auf Daten zuzugreifen, sind die natürlich nicht definiert. Starte den onEnterFrame-Event also erst aus der Callback-Funktion heraus, also bspw. aus einem LoadVars.onLoad.

[RustyCake]

Glaube mir, die "ID = i" wird beim laden gelöscht
Lösung wäre einen Container im Container, die ganzen var's auf den äusseren zu tackern, und in den inneren laden.

[Edith]
Am besten Du probierst des mal aus.

PHP-Code:

//So gehts nicht//////////////////////////////////////////////////////////////////////////////////
this.createEmptyMovieClip("control",this.getNextHighestDepth());
this.createEmptyMovieClip("con",this.getNextHighestDepth());
this.con.loadMovie("clown.jpg");
this.con.i = 1;
trace("this.con.i in Timeline = "+this.con.i);//this.con.i in Timeline = 1
this.control.onEnterFrame = function() {
    if (_root.con._width>0) {
        trace("_root.con.i in control_mc = "+_root.con.i);//_root.con.i in control_mc = undefined
        delete this.onEnterFrame;
    }
};

btn.onPress = function() {
    trace("_root.con.i in control_btn = "+_root.con.i);//_root.con.i in control_btn = undefined
};
//So gehts//////////////////////////////////////////////////////////////////////////////////////
this.createEmptyMovieClip("control",this.getNextHighestDepth());
this.createEmptyMovieClip("con",this.getNextHighestDepth());
this.con.createEmptyMovieClip("con_in_con",this.getNextHighestDepth());
this.con.con_in_con.loadMovie("clown.jpg");
this.con.i = 1;
trace("this.con.i in Timeline = "+this.con.i);//this.con.i in Timeline = 1;
this.control.onEnterFrame = function() {
    if (_root.con.con_in_con._width>0) {
        trace("_root.con.i in control_mc = "+_root.con.i);//_root.con.i in control_mc = 1;
        delete this.onEnterFrame;
    }
};

btn.onPress = function() {
    trace("_root.con.i in control_btn = "+_root.con.i);//_root.con.i in control_btn = 1;
}; 


[/Edith]

[ninja]

Hallo Rusty,

Zitat von RustyCake

Lösung wäre einen Container im Container, die ganzen var's auf den äusseren zu tackern, und in den inneren laden.

ja, das war die Lösung.

Vielen Dank
Viele Grüße
Rolf