Typewriter Text markierbar?

[PB2011]

Hallo liebe Flasher,

ich bin neu hier im Forum und habe von AS auch nicht so wirklich Ahnung. Ich erstelle Flashbanner in einer Agentur und hab mir aus dem Forum hier einen Typewriter-Effekt gesucht, der auch super funktiuoniert (AS2).

Das Problem dabei ist das der Text in der .swf-Datei markierbar ist, und das sollte nicht sein. Wie und wo kann ich das deaktivieren? Hab hier leider noch nichts dazu gefunden...

Außerdem liegt auf der oberen Ebene ein ClickTag, der die Verlinkung zu externen Seiten ermöglicht. Dieser ist an der Stelle, an der der Typewriter liegt, überdeckt (nicht gut!). Woran liegt das?

Und kann man die Typewriter-Animation loopen?


Hier mal der Code:

PHP-Code:

var meinText = "ich diene nur zur\nDemonstration eines\ntypeWriter-Effektes";
    x = 10;
    y = 60;
    
    //leeren MC erstellen
    this.createEmptyMovieClip("container",1)
    
    //Textfeld erstellen
    this.createTextField("tw",1,x,y,140,400);
    
    //Startzeit setzen
    startTime = getTimer()/1000;
    
    var len = meinText.length;
    var i = 0;
    
    //kontinuierlicher onEnterFrame-Event
    _root.onEnterFrame = function(){
        
        //solange der Text noch nicht vollständig angezeigt wird...
        if (i<len) {  
        
            //...nächsten Character zeigen
            tw.text += meinText.charAt(i);  
            
            //und Zähler erhöhen
            i++;  
        }
        else{//beendet
           delete this.onEnterFrame;//den Event wieder löschen
        }
    }  
    
    var container:MovieClip = _root.createEmptyMovieClip("container", _root.getNextHighestDepth()); 


Besten Dank schon einmal im Voraus für eure Hilfe!

[Martin Kraft]

Willkommen im Flash Forum!

• Zitat von PB2011

  Das Problem dabei ist das der Text in der .swf-Datei markierbar ist, und das sollte nicht sein. Wie und wo kann ich das deaktivieren? Hab hier leider noch nichts dazu gefunden...

  Wie ein Blick in die Referenz zeigt, hat jedes Textfield die Eigenschaft selectable über die man das einstellen kann:
  PHP-Code:

  var textField =  createTextField("tw", 1, x, y, 140, 400);
textFiled.selectable = false; 


• Zitat von PB2011

  Außerdem liegt auf der oberen Ebene ein ClickTag, der die Verlinkung zu externen Seiten ermöglicht. Dieser ist an der Stelle, an der der Typewriter liegt, überdeckt (nicht gut!). Woran liegt das?

  Um das zu beantworten, müsste man den Code des Links sehen und wissen auf welches Objekt Du ihn gelegt hast.
  
  

• Zitat von PB2011

  Und kann man die Typewriter-Animation loopen?

  Man kann fast alles Wie soll sie denn loopen? Einfach wieder von vorne anfangen (sieht irgendwie blöd aus oder?) oder erst wieder Buchstabe für Buchstabe verschwinden?
  
  
• Wieso erstellst Du eigentlich zwei leere MovieClips, die Du dann nicht verwendest?
  
  
• Außerdem solltest Du vermeiden MovieClips und onEnterFrames auf _root zu legen. In der Regel kannst Du das _root. einfach weglassen.

Zitat von PB2011

ich [...] habe von AS auch nicht so wirklich Ahnung. Ich erstelle Flashbanner in einer Agentur und hab mir...

Bitte verzeih mir, dass ich mir dazu einen Kommentar nicht verkneifen kann:
Wer mit Flash sein Geld verdient, sollte ActionScript wenigstens in den Grundzügen beherrschen!
Die unzähligen Scriptfehler in irgendwelchen Bannern verderben den Ruf von Flash und schädigen damit die Leute die wirklich professionell damit umgehen. Wenn Dein Chef also von Dir verlangt, mit diesem Programm zu arbeiten, sollte er Dir also auch eine AS-Schulung oder wenigstens ein vernünftiges Buch finanzieren!


P.S.: Bitte setz Deinen Code hier im Forum in [PHP]-Tags (so wie ich es für Dich getan habe), dann kann man ihn besser lesen!

[PB2011]

Hallo,

vielen Dank für die schnelle Antwort, funktioniert prima! Dadurch, das der Text jetzt nicht mehr markierbar ist, hat sich auch das Problem mit dem ClickTag erledigt, nix wird mehr überdeckt :-)!
Der liegt in einer transparenten Schaltfläche über dem gesamten Banner in der obersten Ebene.

PHP-Code:

on(release) {
getURL(clickTag, "_self");
} 


Mit einer Animation, wo Buchstabe für Buchstabe wieder verschwinden, das ist doch quasi die Umkehrung, oder? Würde sicher gut passen...

Bisher hab ich die Banneranimation immer über Zeitleistensteuerung gemacht, Tweening und so weiter. Wollte einfach mal etwas Neues ausprobieren. Und ein Typewriter-Effekt, wo jeder Buchstabe per Hand animiert wird, ist doch ziemlich umständlich :-)

Wir haben auch 2 Bücher hier, aber das ist alles AS3, und die Banner sollen weiterhin mit AS2 veröffentlicht werden.

Danke nochmals!

[PB2011]

Huhu,

hab schon überall nachgeschaut, hier im Forum und auch in der Referenz, aber ich konnte noch nichts finden was in etwa der Umkehrung des Typewriter-Effekt entspricht... Also dass die Buchstaben nach und nach wieder verschwinden, quasi als Ende der Animation.
Und dann sollte es wieder von vorn losgehen... Hat jemand nen Tipp?

Danke!

[Martin Kraft]

Hiermit tippt sich Dein Text bis zum Ende aller Tage rein und raus:

PHP-Code:

var typeSpeed:Number = 1;
var typeLength:Number = 0;
onEnterFrame = function(){
    
    typeLength += typeSpeed;
    if ( ( typeLength > meinText.length && typeSpeed > 0 ) || ( typeLength <= 0 && typeSpeed < 0 ) ) typeSpeed = -typeSpeed;
    
    tw.text = meinText.substr(0, typeLength);
    
} 


[PB2011]

Danke!!! Aber ich glaub ich bin echt zu blöd :-) An welche Stelle muss das? Hab das Script auch überarbeitet und die nicht notwendigen Sachen rausgeschmissen.

Hatte das bei kontinuierlicher onEnterFrame-Event eingefügt, da passiert gar nix, und dann den letzten Teil rausgelöscht, da war der Text aber ganz weg...

Sieht jetzt so aus:

PHP-Code:

var meinText = "Ich diene nur zur\nDemonstration eines\ntypeWriter-Effektes";
    x = 10;
    y = 60;
        
    //Textfeld erstellen
    var textField = this.createTextField("tw",1,x,y,140,400);
    textField.selectable = false;
    tw.textColor = 0xff0000;
        
    //Startzeit setzen
    startTime = getTimer()/500;
    
    var len = meinText.length;
    var i = 0;
    
    //kontinuierlicher onEnterFrame-Event
    onEnterFrame = function(){
        
        //solange der Text noch nicht vollständig angezeigt wird...
        if (i<len) {  
        
            //...nächsten Character zeigen
            tw.text += meinText.charAt(i);  
            
            //und Zähler erhöhen
            i++;  
        }
        else{//beendet
           delete this.onEnterFrame;//den Event wieder löschen
        }
    } 


[Martin Kraft]

Komplett sähe das so aus:

PHP-Code:

var meinText:String = "Ich diene nur zur\nDemonstration eines\ntypeWriter-Effektes";
var textField:TextField = this.createTextField("fw", getNextHighestDepth(), 10, 60, 140, 400);
textField.selectable = false;

var typeSpeed:Number = 1;
var typeLength:Number = 0;
onEnterFrame = function(){
    
    typeLength += typeSpeed;
    if ( ( typeLength > meinText.length && typeSpeed > 0 ) || ( typeLength <= 0 && typeSpeed < 0 ) ) typeSpeed = -typeSpeed;
    
    textField.text = meinText.substr(0, typeLength);
    
} 


[PB2011]

Arrrggg! Sorry dass ich nerve
Wenn ich das komplett ersetze erscheint gar kein Text... Kommt das in nen Movieclip? Oder einfach in ein Schlüsselbild, wie bisher?

PHP-Code:

var meinText:String = "Ich diene nur zur\nDemonstration eines\ntypeWriter-Effektes";
var textField:TextField = this.createTextField("tw", 1, 10, 60, 140, 400);
textField.selectable = false;
tw.textColor = 0xff0000;

var typeSpeed:Number = 1;
var typeLength:Number = 0;
onEnterFrame = function(){
    
    typeLength += typeDir;
    if ( ( typeLength > meinText.length && typeSpeed > 0 ) || ( typeLength <= 0 && typeSpeed < 0 ) ) typeSpeed = -typeSpeed;
    
    tw.text = meinText.substr(0, typeLength);
    
} 


Muss da noch irgendwas umbenannt werden?

[Martin Kraft]

Ups - sorry. Ich hatte eine Variable umbenannt (typeDir > typeSpeed) und dabei vergessen sie an allen Stellen zu ändern.

Du solltest bei Codebeispielen hier im Forum immer versuchen diese nach zuvollziehen und zu verstehen, dann hättest Du diesen Fehler wahrscheinlich auch alleine gefunden Copy'n'Paste allein bringt Dich nicht weiter!

Ich hab den Code jedenfalls oben korrigiert. Hier ist er nochmal komplett:

PHP-Code:

var meinText:String = "Ich diene nur zur\nDemonstration eines\ntypeWriter-Effektes";
var textField:TextField = this.createTextField("fw", getNextHighestDepth(), 10, 60, 140, 400);
textField.selectable = false;

var typeSpeed:Number = 1;
var typeLength:Number = 0;
onEnterFrame = function(){
    
    typeLength += typeSpeed;
    if ( ( typeLength > meinText.length && typeSpeed > 0 ) || ( typeLength <= 0 && typeSpeed < 0 ) ) typeSpeed = -typeSpeed;
    
    textField.text = meinText.substr(0, typeLength);
    
} 


[PB2011]

Dankeeee!!! Jetzt klappt alles!!!