Sinvolle Steuerung per Actionscript ?

[chrisflasher]

Hallo zusammen,

ich bastel mal wieder ein wenig in Flash rum. Ich habe einen schwarzen Punkt (Instanzname = hero) und 96 Felder (die grauen zählen nicht) mit den jeweilige Kennzeichnungen a1, a2, a3 ...........

hero wird per Actionscript gesteuert:

hero.onEnterFrame=function() {
		
if(Key.isDown(Key.LEFT))
{    
this.play();                           
this._x=this._x-5; 
} 

if(Key.isDown(Key.RIGHT))
{    
this.play();                         
this._x=this._x+5;                  
}

if(Key.isDown(Key.DOWN))  
{    
this.play();                           
this._y=this._y+5;                   
}

if(Key.isDown(Key.UP))
{    
this.play();                          
this._y=this._y-5;                
}
}

Ich habe mit einem "hitTest" versucht das wenn hero bei manchen Feldern (beispielsweise c6) anstösst stehen bleibt, jedoch weiß ich nicht wirklich wie ich den Code so schreibe, das hero, egal in welche Richtung er gesteuert wird stehen bleibt sobald er auf das Feld c6 trifft.

Mit Variablen hat es leider auch nicht funktioniert.

Gibt es für diese Angehensweise einen einfacheren Lösungsweg ?
Sollte ich die Steuerung anders schreiben ?
Wie geht man einen solchen Aufbau am besten an ?

Über Rückantworten würde ich mich freuen

Gruß

Chirsflasher

[shin10]

Hi,

das ist jetzt zwar AS3 und ... Geschmackssache ... ziemlich oldschool, aber mal schauen. Vielleicht gefällt dir sowas ja.

PHP-Code:

import flash.display.Sprite;
import flash.events.KeyboardEvent;
stage.align = "TL";

const SPRITE_SIZE:int = 32;
const HERO_SPEED:int = 4;
const MAP_HEIGHT:int = 8;
const MAP_WIDTH:int = 10;

var hindernisse:Array = [];

function createBox(x:int, y:int, o:Boolean=false):void
{
    if(x==0 || x==MAP_WIDTH-1 || y==0 || y==MAP_HEIGHT-1) o = true;
    var s:Sprite = new Sprite();
    s.graphics.lineStyle(1, 0);
    s.graphics.beginFill(o ? 0xCCCCCC : 0xFFFFFF);
    s.graphics.drawRect(0, 0, SPRITE_SIZE, SPRITE_SIZE);
    s.graphics.endFill();
    s.x = SPRITE_SIZE * x;
    s.y = SPRITE_SIZE * y;
    hindernisse[x] +=  o ? 1<<y : 0;
    addChild(s);
}

for (var posx:int=0; posx < MAP_WIDTH; posx++)
{
    hindernisse[posx] = 0;
    for (var posy:int=0; posy < MAP_HEIGHT; posy++)
    {
        createBox(posx, posy, Math.random()<.1);
    }
}

var hero:Sprite = new Sprite();
hero.graphics.lineStyle(1, 0);
hero.graphics.beginFill(0xFF0000);
hero.graphics.drawCircle(SPRITE_SIZE*.5, SPRITE_SIZE*.5, SPRITE_SIZE*.5);
hero.graphics.endFill();
hero.x = hero.y = SPRITE_SIZE;
addChild(hero);


stage.addEventListener(KeyboardEvent.KEY_DOWN, kdh);
function kdh(e:KeyboardEvent):void{
    if(e.keyCode == 37 && !(hindernisse[int((hero.x-HERO_SPEED ) / SPRITE_SIZE)] & (1 << int(hero.y / SPRITE_SIZE)))     && !(hindernisse[int((hero.x-HERO_SPEED ) / SPRITE_SIZE)] & (1 << int((hero.y+(SPRITE_SIZE-1)) / SPRITE_SIZE))) )    hero.x -= HERO_SPEED;
    if(e.keyCode == 39 && !(hindernisse[int((hero.x+SPRITE_SIZE) / SPRITE_SIZE)] & (1 << int(hero.y / SPRITE_SIZE)))    && !(hindernisse[int((hero.x+SPRITE_SIZE) / SPRITE_SIZE)] & (1 << int((hero.y+(SPRITE_SIZE-1)) / SPRITE_SIZE))) )    hero.x += HERO_SPEED;
    if(e.keyCode == 38 && !(hindernisse[int(hero.x / SPRITE_SIZE)] & ((1 << int((hero.y-HERO_SPEED ) / SPRITE_SIZE))))    && !(hindernisse[int((hero.x+(SPRITE_SIZE-1)) / SPRITE_SIZE)] & ((1 << int((hero.y-HERO_SPEED ) / SPRITE_SIZE)))) )    hero.y -= HERO_SPEED;
    if(e.keyCode == 40 && !(hindernisse[int(hero.x / SPRITE_SIZE)] & ((1 << int((hero.y+SPRITE_SIZE) / SPRITE_SIZE))))    && !(hindernisse[int((hero.x+(SPRITE_SIZE-1)) / SPRITE_SIZE)] & ((1 << int((hero.y+SPRITE_SIZE) / SPRITE_SIZE)))) )    hero.y += HERO_SPEED;
} 


mfg

sx

[chrisflasher]

ich habe inzwischen ein Prinzip gefunden das mir gut gefällt =)

Tile based games

Trotzdem danke für die Antwort