scope in As2, Eventmethode

[milchreis]

nabend, bloß mal so aus Neugier:

Ich hatte gerade diesen thread gelesen:
Position von dynamischen Buttons in root

Es geht um eine Art tooltip, also ein Objekt reagiert auf Mouseevents anderer Objekte.

In As3 gedanklich beheimatet, wurde ich daran erinnert, das in As2 der scope in einer Eventmethode auf das jeweilige Objekt wechselt.

Wie greift man denn aus so einer Funktion auf die Klasse in der die Funktion definiert wurde (bzw. auf deren Eigenschaften) zu?

//Bleistift:

PHP-Code:

import flash.geom.Rectangle;
import flash.geom.Point;

class RectCursor
{
    private var FRAME:Number = 5;
    
    private var _c:MovieClip;
    private var _currRect:Rectangle;
    
    public function RectCursor (cursor:MovieClip)
    {
        _c = cursor;
        
        _currRect = null;
    }
    
    public function addMc(mc:MovieClip):Void
    {
        mc.onRollOver = over;
        mc.onRollOut = out;
    }
    
    private function over():Void
    {
        trace(_c); //undefined     =(
        
        _currRect = addFrame(bounds2Rect(MovieClip(this).getBounds(_c._parent)), FRAME);
        
        draw();
    }
    
    private function out():Void
    {
        _currRect = null;
        
        draw();
    }
    
    private function bounds2Rect(obj:Object):Rectangle
    {
        return new Rectangle(obj.xMin, obj.yMin, obj.xMax - obj.xMin, obj.yMax - obj.yMin);
    }
    
    private function addFrame(rect:Rectangle, frame:Number):Rectangle
    {
        rect.x -= frame;
        rect.y -= frame;
        rect.width += 2*frame;
        rect.height += 2*frame;
        
        return rect;
    }
    
    private function draw():Void
    {
        _c.clear();
        
        if (!_currRect) return;
        
        _c.lineStyle(1, 0);
        _c.moveTo(_currRect.left, _currRect.top);
        _c.lineTo(_currRect.right, _currRect.top);
        _c.lineTo(_currRect.right, _currRect.bottom);
        _c.lineTo(_currRect.left, _currRect.bottom);
        _c.lineTo(_currRect.left, _currRect.top);
        
    }
} 


Ich kann in der "over" Funktion nicht auf die Klasseneigenschaft "_c" zugreifen, da sich der scope ändert. =(

Ich bin über den AsBroadcaster gestolpert, der wohl so eine Art EventDispatcher wrapper darstellt.

PHP-Code:

    public function addMc(mc:MovieClip):Void
    {
        AsBroadcaster.initialize(mc);
        mc.addListener(this);
        mc.onRollOver = function () {this.broadcastMessage("over", this)};
        mc.onRollOut = function () {this.broadcastMessage("out")};
    }
    
    private function over(target:MovieClip):Void
    {
        
        trace (_c); // defined =)
        
        
        _currRect = addFrame(bounds2Rect(target.getBounds(_c._parent)), FRAME);
        
        draw();
    } 


So funktioniert's.

Macht man das so in As2?
Ich habe noch nie etwas von dem Broadcaster gehört, das Problem sollte ja aber öfter auftreten, oder?

PS: fand das eher OT und hab deshalb nen neuen thread aufgemacht.

[thomas_E]

Mike Chambers hat wohl was ähnliches gebaut, unter mx.utils.Delegate
und davon hab ich schon paarmal gehört

ich für meinen Teil würd das über ne closure lösen:

PHP-Code:

public function addMc(mc:MovieClip):Void
{
    var __this = this;
    mc.onRollOver = function () { __this.over(mc); };
    mc.onRollOut = function () { __this.out(mc); };
}

mit oder ohne dem mc als Parameter, je nachdem was ich benötige 


oder nach dem 3. mal wo ich sowas bauen muss, würde ich etwas bauen, dass ich ähnlich händeln kann wie das Event-system in As3.
auch mit dem Hintergrund, dass in AS2 immer nur ein Event-Listener /Objekt und Event hinzugefügt werden kann, und alte einfach überschrieben werden.

[milchreis]

Aha.
Die lokalen Variablen der Funktion in der die Funktion definiert wurde, sind also in beiden Funktionen verfügbar.

hier auch was ähnliches von keith:

Scope in AS2 Classes revisited, again. | BIT-101

[Omega Psi]

Ja, wenn du meine alten AS2 Beispiele anschaust, sieht das genauso aus.

Das Scoping ist aus JavaScript übernommen. Die Methoden nutzen Method Closures, um den Kontext, in dem Sie definiert wurden zu persistieren.

[milchreis]

Zitat von Omega Psi

zu persistieren.

Das hast du aber schön gesagt

Da bin ich ja froh, das dieses drollige Konzept überwunden wurde.

[Omega Psi]

War das .. Ironie?

[Omega Psi]

Btw.: das Konzept wurde nicht verworfen und wird auch in anderen Programmiersprachen verwendet. Das ist sollte man als Programmierer verstanden haben.

[Martin Kraft]

Zitat von milchreis

Da bin ich ja froh, das dieses drollige Konzept überwunden wurde.

Das sagst Du ausgerechnet jetzt, wo wir Adobe-sei-dank alle wieder mit JS rumwursteln sollen?!

[milchreis]

Zitat von Omega Psi

War das .. Ironie?

Nein. Schön zwischen methods, closures, scope, events etc. auch mal einen deutschen Ausdruck zu finden.

Zitat von Omega Psi

Btw.: das Konzept wurde nicht verworfen und wird auch in anderen Programmiersprachen verwendet. Das ist sollte man als Programmierer verstanden haben.

Nicht generell verworfen. Aber in diesem Anwendungsfall finde ich es angenehmer, einen Listener anhängen zu können.