Objekt entfernt sich von Mouse-cursor

[ciroco]

Hallo zusammen,

seit langem hab ich mal wieder eine Frage oder besser gesagt folgendes Problem:

Ich habe hier etwas gebastelt, wo sich Movieclips vom Cursor entfernen sollen
sobald dieser näher kommt. Ich möchte gern das die mc zum Uhrsprungspunkt
zurück wandern; bisher gehen diese nämlich ihren eigenen weg quer über die Bühne.

Im endeffekt versuche ich sowas nachzubauen:
Ruhr® ? TeamworkCity (Logo oben rechts)


Wäre super wenn mir jemande dabei helfen könnte.

Lieben Gruß
Jens

[thomas_E]

aM laboratory inklusive Sourcecode.
der einzige Unterschied ist, André Michelle berechnet "paar" Partikel mehr, als auf der verlinkten Seite.

[Martin Kraft]

Zitat von ciroco

Im endeffekt versuche ich sowas nachzubauen:
Ruhr® ? TeamworkCity (Logo oben rechts)

Da wandert aber nichts vom Cursor weg Das sind räumlich positionierte und gemeinsam rotierende Punkte.

[milchreis]

Zitat von Martin Kraft

Da wandert aber nichts vom Cursor weg Das sind räumlich positionierte und gemeinsam rotierende Punkte.

F5

Ein Effekt ist ein Forcefield, vermutlich was ciroco meinte.

[ciroco]

Hallo,

erstmal vielen Dank für eure Antworten und eure Bemühungen.
Das Beispiel sieht Hammer aus, aber die Sourcedatei (Fla) haben sie natürlich nicht beigepackt.

Ich habe meine Datei nochmal hochgeladen (als CS4 Version)

Mein Beispiel ist (glaube ich) einfacher.

Hoffe ihr könnt es öffnen und mir dann sagen was ich falsch gemacht habe

Gruß

[thomas_E]

aber die Sourcedatei (Fla) haben sie natürlich nicht beigepackt

doch, genau deshalb hab ich das Beispiel ja gepostet. nur ist das da keine FLA-Datei, sondern eine AS-Datei. und auch wenn der SC dort AS3 ist, so konnte ich die entsprechende Passage 1:1 abschreiben.

Hoffe ihr könnt es öffnen und mir dann sagen was ich falsch gemacht habe

du hast vergessen dir zu merken, wo du losgegangen bist, und zeigst auch keinerlei Neigung dahin zurückzukehren.
Somit läufst du immer nur weg, wenn dir die Maus zu nahe kommt.
Wenn ich das so anmerken darf, keine förderliche Eigenschaft für jemanden der in der IT-Branche arbeitet (ein MovieClip)

PHP-Code:

//der Effekt
MovieClip.prototype.startPanicMouse = function(distanz:Number, tempo:Number, damp:Number){
    var target:MovieClip = this;
    if(target.stopPanicMouse) target.stopPanicMouse();
    
    var tx:Number = target._x;    //Startposition, da will ich hin
    var ty:Number = target._y;
    var vx:Number = 0;            //Geschwindigkeit, als Vektor
    var vy:Number = 0;
    
    var dPow2 = distanz * distanz;    //das muss ich nicht jeden Frame berechnen
    
    //der alte Handler. es wäre nicht nett, einfach so etwas zu überschreiben
    var efHandler:Function = target.onEnterFrame;
    
    target.onEnterFrame = function(){
        var dx:Number = target._parent._xmouse - tx;
        var dy:Number = target._parent._ymouse - ty;
        var d:Number = dx*dx+dy*dy;
        if(d < dPow2){
            d = Math.sqrt(d);
            vx -= dx / d;
            vy -= dy / d;
        }
        
        dx = tx - target._x;
        dy = ty - target._y;
        
        vx += dx * tempo;
        vy += dy * tempo;
        
        if(damp){
            vx *= damp;
            vy *= damp;
        }
        
        target._x += vx;
        target._y += vy;
        
        if(efHandler) efHandler.call(target);
    }
    
    target.stopPanicMouse = function(){
        target._x = tx;
        target._y = ty;
        target.onEnterFrame = efHandler;
        delete target.stopPanicMouse;
    }
}




stop();

//ein zusätzlicher EnterFrame-Handler, der nicht gelöscht wird
btn1.onEnterFrame = function(){
    this._rotation += 2;
}

//panicMouse ein / Ausschalten
this.onMouseUp = function(){
    if(btn1.stopPanicMouse){
        btn1.stopPanicMouse();
    }else{
        btn1.startPanicMouse(100, .02, .95);
    }
}