mit MovieClipLoader Bild laden!!

[katimp]

ich versuche in einer Klasse mit dem MovieClipLoader ein Bild zu laden...ich habs nicht hinbekommen:
Was stimmt nicht an folgendem Code?

class createPicture extends MovieClip {

static var container:MovieClip;

function createPicture(){
_root.createEmptyMovieClip("container",_root.getNe xtHighestDepth());
var mcLoader:MovieClipLoader = new MovieClipLoader();
var lauscher:Object=new Object();
lauscher.onLoadInit=function(ziel_mc){
ziel_mc._width=500;
ziel_mc._height=300;
}
mcLoader.addListener(lauscher);
mcLoader.loadClip("./images/bild2.jpg",container);

}
}

[Omega Psi]

Hier mal ein etwas ausführlicherer Ansatz:

/** */
class MyMovieClip extends MovieClip {
    /** */
    private var content:MovieClip;
    /** */
    private var mymoviecliploader:MyMovieClipLoader;
    /** */
    private var url:String;
    /** */
    public function MyMovieClip() {
        //super();
        trace("class MyMovieClip: constructor");
        this.mymoviecliploader = new MyMovieClipLoader();      
        if (url != undefined) {
            this.url = url;
            this.buildContent();
        }
    }
    /** */
    public function onLoad() {
        trace("class MyMovieClip: listener onLoad");
        this._visible = false;
    }
    /** */
    public function buildContent():Void {
        trace("class MyMovieClip: function buildContent");
        this.content = this.createEmptyMovieClip("content", this.getNextHighestDepth());
        this.mymoviecliploader.loadClip2Target(this.url, this.content);
    }
    /** */
    public function show():Void {
        trace("class MyMovieClip: function show");
        this._visible = true;
    }
} 

/** */
class MyMovieClipLoader extends MovieClipLoader {
    
    /** */
    public function MyMovieClipLoader() {
        trace("class MyMovieClip: constructor");
        super();
    }
    /** */
    public function loadClip2Target(url:String, target:MovieClip) {
        trace("class MyMovieClipLoader: function loadClip2Target");
        this.loadClip(url, target);
    }
    /** */
    public function onLoadInit(target) {
        trace("class MyMovieClipLoader: listener onLoadInit");
        target._parent.show();
    }
} 

Wenn du eine Klasse schreibst, die von MovieClipLoader erbt, kannst du verschiedene Ansätze verfolgen, um viele Bilder zu laden. Entweder du bleibst in dieser Variante oder du schreibst eine Funktion function loadClips2Targets(urls:Array, targets:Array):Void (oder mit der Signatur function loadClips2Targets(new Array(new Array(url, target), new Array(url, target))):Void - also einem zweidimensuionalen Array).

Anbei noch die Sourcen.

[Omega Psi]

Um nochmal auf deinen Code einzugehen:

1. Ist das Symbol mit einem MovieClip verknüpft?
2. Wieso ist container static?
3. Nimm mal das './' weg in der Pfadangabe.

[[RK]]

Auch wenn ich jetzt ein wenig ins OFF-Topic gehe. Aber gibt es eig. in dem Forum sowas wie ein ActionScript FAQ, mit Links zu ein paar Tutorials oder so?
Zb. gibt es oft mehrmals täglich Fragen bzz. des MovieClipLoader und in den meisten der Fälle ist es auch immer die gleiche Frage, bzw. der gleiche Fehler. Ich mein auch wenn F1 die meisten Probleme da lösen sollte, bzw. die Suchfunktion - so wär evt. noch so ein kleines FAQ ganz praktisch.

[Omega Psi]

Naja, in einem kleinen FAQ würden keine anderen Sachen stehen, als in F1. In großen FAQs geht's dann vllt schon in das Grundverständnis von Objekt-orientierter Programmierung.

• Bezug auf das initiale Problem des Threads: Wieso beispielsweise erben viele von MovieClip, aber nicht von MovieClipLoader?
  - Würde man das einigermaßen konsequent durchziehen, würden auch viele Scope-Probleme einfach wegfallen. Man hätte einen besseren Überblick im Code und die Wiederverwendbarkeit von Klassen wäre auch effizienter gewährleistet.

Ich fänd einen FAQ echt gut, und würde mich auch gerne daran beteiligen, die Frage ist halt: für wen dieser FAQ geschrieben wird.

[[RK]]

Man könnte zb. für die Anfänger zu jeden Artikel entsprechende Verweise auf die Livedocs von Adobe geben, bzw. Stichworte um in der Hilfe nachschlagen zu können. Ich wäre jedenfalls auch sehr an ein solches FAQ interessiert.

[katimp]

Hab den Code nun in folgenden geändert und es funktioniert leider immer noch nicht!!! wo können den da noch Fehler liegen?

class actionscript.createPicture{

var container:MovieClip;

function createPicture(){
_root.createEmptyMovieClip("container",999);
var mcLoader:MovieClipLoader = new MovieClipLoader();
var lauscher:Object=new Object();
lauscher.onLoadInit=function(ziel_mc){
//ziel_mc._width=500;
//ziel_mc._height=300;
}
mcLoader.addListener(lauscher);
mcLoader.loadClip("images/bild2.jpg",container);

}
}

[Omega Psi]

class CreatePicture { // Klassennamen groß schreiben.
    /** */
    var container:MovieClip;
    function CreatePicture(){
        container = _root.createEmptyMovieClip("container",999); // Du hattest keine Zuweisung auf Container.
        var mcLoader:MovieClipLoader = new MovieClipLoader();
        var lauscher:Object=new Object();
        lauscher.onLoadInit=function(ziel_mc){
            trace("Listener onLoadInit called");
        }
        mcLoader.addListener(lauscher);
        mcLoader.loadClip("images/bild2.jpg",container);
    }
} 

Es bietet sich aber folgende Lösung mehr an:

/** */
class CreatePicture extends MovieClip {
    /** */
    var container:MovieClip;
    /** */
    var contentPath:String;
    /** */
    function CreatePicture() {
        super();
        trace(contentPath);
        // wird via attachMovie übergeben.
        this.container = this.createEmptyMovieClip("container", this.getNextHighestDepth());
        this.contentPath = contentPath;
        this.loadContent(this.container, this.contentPath);
    }
    /** */
    function loadContent(container:MovieClip, contentPath:String):Void {
        trace("function loadcontent");
        var mcLoader:MovieClipLoader = new MovieClipLoader();
        var lauscher:Object = new Object();
        lauscher.onLoadInit = function(ziel_mc) {
            trace("Listener onLoadInit called");
        };
        mcLoader.addListener(lauscher);
        mcLoader.loadClip(contentPath, container);
    }
    /** */
    function onRelease():Void {
        trace(this+", "+this.contentPath);
    }
} 

Wenn du von MovieClip erbst und in einen Container MovieClip die Bilder reinlädst, kannst du elegant ein Verhalten via onRelease() etc über CreatePicture implementieren.

[mojave]

jedesmal ein neues objekt vom mcloader zu erzeugen finde ich unsauber und ist überflüssig.

mal eine grundsätzliche frage: weist du diese klasse einem mc zu? oder willst du eine abstrakte klasse zum laden von bildern schreiben?

[Omega Psi]

Sprichst du mit mir?

[mojave]

der erste satz ging an dich.

der zweite an den/die threadersteller/in

[Omega Psi]

Ja, ist es auch, ich habe nur den Code verbessert und angepasst.

In Verbindung mit XML geht das sehr schön so: .zip

Verwendet in xml: Bilder dynamisch laden. wie? und laden einer SWF via MovieClipLoader loadClip

[mojave]

hier mal eine kleine klasse die du mit deinem mc verknüpfen kannst.
ich würde jedoch einen schritt weiter gehen und die ladefunktionalität in eine eigene klasse auslagern. immer schön die funktionalitäten aufteilen.

PHP-Code:

class PictureMc extends MovieClip {
    
    private var mlLoader:MovieClipLoader;
    private var mlListener:Object;
    
    private var mcHolder:MovieClip;
    
    function PictureMc() {
        super();
        init();
    }
    
    
    private function init():Void
    {
        this.mlLoader = new MovieClipLoader();
        this.mlListener = new Object();
        this.mcHolder = this.createEmptyMovieClip('mcHolder',this.getNextHighestDepth());
        this.initListener();
    } 
    
    private function initListener():Void
    {
        this.mlListener.onLoadInit = function(mcLoaded:MovieClip){
            mcLoaded._width = 600;
            mcLoaded._height = 400;
        };
    }
    
    
    
    public function loadPicture(src:String):Void
    {
        this.mlLoader.loadClip(src,this.mcHolder);
        this.mlLoader.addListener(this.mlListener);
    }
    
    

} 


[katimp]

ich möchte eine abstrakte Klasse zum laden von Bildern schreiben!

[Omega Psi]

Schaue dir mal die .zip-Datei und die angeführten Threads an, in denen ich dazu schrieb. Wie mojave schon anführte. Sowas lagert man lieber aus. du brauchst also mindestens 2 Klassen.

In meinem Beispiel lade ich Pfade aus einer XML und übergieb diese Pfade an eine Klasse, die von MovieClipLoader erbt, um dann Bilder in MovieClips zu laden - alle nacheinander (mit nur einem MovieClipLoader! ).