Funktionszugriff in einer AS-Klasse

[apfelbonbon]

Ich habe eine AS-Klasse mit folgendem Inhalt:

PHP-Code:

class Test {

    function doIt():Void {
                
         mc.onRollOver = function() {
         doA();
         }

             mc.onRollOut = function() {
          doB();
          }
    }
    
       function doA():Void {
              trace("tue A");
        }

        function doB():Void {
              trace("tue B");
       }
} 


Es wird aber, wenn die jeweiligen Ereignisse eintreten, weder doA() noch doB() ausgeführt. Auch ein this.doB(); oder _root.doB(); ändert daran nichts. Gebe ich statt doA() zum Beispiel die nicht vorhandene Funktion doC(); ein, sagt er mir, dass diese Funktion nicht existiert. Also hat er ja offenbar doA() gefunden, führt sie aber nicht aus. Warum?

[Martin Kraft]

Dir ist aber schon klar, was Klassen eigentlich sind und dass diese üblicherweise einen Konstruktor haben?! Falls nicht solltest Du das mal nachlesen und Dir dann diese Fragen beantworten:

• Wer oder was ruft die Funktion doIt auf?
• Gibt es ein mit dieser Klasse verknüpftes Bibliothekssymbol?
• Wenn ja, gibt es in diesem Symbol eine Instanz namens mc?
• Instanziierst Du diese Klasse überhaupt? Wenn ja wie?

[apfelbonbon]

Ja, ich habe nur den relevanten Teil hier rein kopiert. Die ist sehr viel größer und es funktioniert auch alles, so, wie es soll. Nur eben diese Funktionszuweisung nicht.

Hätte ja sein können, dass ich grundsätzlich etwas falsch gemacht habe. Dann muss ich noch mal selbst nachschauen, woran es liegt. Trotzdem vielen Dank für die Hilfe (nicht nur hier).

[hgseib]

was das auch sein soll, es ist komisch ;-)

class Test {
function doIt():Void {
mc.onRollOver = function() {
doA();
}

wo kommt dieses mc her?
und wenn du dein onRollOver ausführst, dann bist du 'im' mc und das ist keine Test-classe somit kann es auch keine funktionen dieser klasse kennen. ohje ist das lange her, in AS2 musst du delegieren. such mal danach im forum. oder dem mc den scope geben .. unschön.

steige lieber und unbedingt auf AS3 um!


function doIt():Void {
mc.scope=this;
mc.onRollOver = function() {
this.scope.doA();
}

[thomas_E]

da fänd ich ne closure schöner, als irgenwelche Movieclips mit Eigenschaften zuzumüllen, nur damit die Methoden sich darauf besinnen, wo sie hingehören.

PHP-Code:

function doIt():Void
{
    var _this = this;
    mc.onRollOver = function() {
        _this.doA();
    }

    mc.onRollOut = function() {
        _this.doB();
    }
} 


tja, ja. ist schon gut, dass die Sprache sich weiterentwickelt hat.

[apfelbonbon]

Zitat von thomas_E

da fänd ich ne closure schöner, als irgenwelche Movieclips mit Eigenschaften zuzumüllen, nur damit die Methoden sich darauf besinnen, wo sie hingehören.

PHP-Code:

function doIt():Void
{
    var _this = this;
    mc.onRollOver = function() {
        _this.doA();
    }

    mc.onRollOut = function() {
        _this.doB();
    }
} 


tja, ja. ist schon gut, dass die Sprache sich weiterentwickelt hat.

Damit funktioniert's, danke!

[SaKiN]

Hallo,

ah ja, der gute alte Dauerbrenner Delegate... nach so vielen Jahren immer noch für Einiges an Verwirrung gut

Versuch mal das:

import mx.utils.Delegate;

class Test 
{
    public var mc:MovieClip;
	
    function doIt():Void 
    {
         mc.onRollOver = Delegate.create(this, doA);
         mc.onRollOut = Delegate.create(this, doB);
    }
    
    function doA():Void 
    {
    	trace("tue A");	
    }

    function doB():Void 
    {
        trace("tue B");
    }
}

Das Warum und Wieso erfährst du hier.

Viele Grüße,
SaKiN