Denkfehler in Klasse zur Maskenerstellung

[twietee]

Hiho!

in einem anderen Thread bin ich durch tatkräftige Hilfe von Forenmitgliedern von funktionalem Spaghetti-Code zur Erstellung einer Klasse zur Maskenanwendung geführt worden.

Das ist dabei herausgekommen:

PHP-Code:

// 
// call: 
// meinMaskiertesBild = new DynamicMaskedImage("imagePath", "maskPath", targetMC); 
// 
class DynamicMaskedImage { 
    var i:Number = 0;
    var imgMC:MovieClip; 
    var maskMC:MovieClip; 
    var target:MovieClip; 
    var imgLdr:MovieClipLoader; 
    var imgLdrLst:Object; 
    var maskLdr:MovieClipLoader; 
    var maskLdrLst:Object; 
    var imgPath:String; 
    var maskPath:String; 
    // 
    // constructor 
    // 
    function DynamicMaskedImage(iP:String, mP:String, t:MovieClip) { 
        imgPath    = iP; 
        maskPath   = mP; 
        target     = t;
        imgMC      = target.createEmptyMovieClip("image_" + i, target.getNextHighestDepth()); 
        maskMC     = target.createEmptyMovieClip("mask_" + i++, target.getNextHighestDepth()); 
        imgLdr     = new MovieClipLoader(); 
        maskLdr    = new MovieClipLoader(); 
        imgLdrLst  = new Object(); 
        maskLdrLst = new Object(); 
        imgLdrLst.onLoadInit = onImageDone(this); 
        imgLdr.addListener(imgLdrLst); 
        maskLdr.addListener(maskLdrLst); 
        imgLdr.loadClip(imgPath, imgMC); 
        maskLdr.loadClip(maskPath, maskMC); 
    } 
    // 
    // loads mask once img load is done 
    // 
    function onImageDone() { 
        trace("image completely loaded"); 
        maskLdrLst.onLoadInit = finish(this); 
    } 
    // 
    // applies image "processing" 
    // 
    function finish() { 
        trace("mask completely loaded"); 
        trace("imgMC._name: " + imgMC._name);    // "imgMC._name: image_0"
        trace("maskMC._name: " + maskMC._name);  // "maskMC._name: mask_0"
        imgMC.setMask(maskMC); 
        maskMC.blendMode = 3; 
    } 
} 


Ich glaube, da ist immer noch ein Denkfehler drin, da
- die Maske nicht angewendet wird (offensichtlich)
- mgMC.setMask(maskMC) aufgerufen wird, bevor die Bilder "gezeichnet" werden (sehe ich im Debugger), das ist in meinen simpel-Tests, die funktionieren, nicht so...

Ich habe schon versucht, mgMC.setMask(maskMC) am Schluss vom Konstruktor aufzurufen, das hat aber auch nichts gebracht.

Für Anregungen oder Denkanstösse wäre ich sehr dankbar!

Gruss,
T

[Martin Kraft]

Wenn Du Funktionen übergibst darfst Du sie nicht ausführen. Also:

PHP-Code:

var test;
var testFunc = function(){
   return "testReturn";
}

// nicht
test = testFunc();
trace(test); // enthält jetzt den String "testReturn"

// sondern
test = testFunc;
trace(test); // enthält jetzt die Function 


Außerdem solltest Du den Masken-Listener nicht erst hinzufügen, wenn das Bild schon geladen wurde. Denn dann ist die Maske warscheinlich auch schon geladen und der Listener wird nie ausgeführt. Ich hab die Klasse mal etwas umstrukturiert:

PHP-Code:

// 
// call: 
// meinMaskiertesBild = new DynamicMaskedImage("imagePath", "maskPath", targetMC); 
// 
class DynamicMaskedImage { 
    
    public static var imageCount:Number = 0;
    
    public var imgMC:MovieClip; 
    public var maskMC:MovieClip;
    public var imgLdr:MovieClipLoader; 
    public var maskLdr:MovieClipLoader;
    // 
    // constructor 
    //
    public function DynamicMaskedImage(imgPath:String, maskPath:String, target:MovieClip) {
        
        imgMC      = target.createEmptyMovieClip("image_" + imageCount, target.getNextHighestDepth());         
        imgLdr     = new MovieClipLoader();
        imgLdr.addListener( {
            onLoadComplete: onImageDone
        } );
        imgLdr.loadClip(imgPath, imgMC);
        
        maskMC     = target.createEmptyMovieClip("mask_" + imageCount, target.getNextHighestDepth()); 
        maskLdr    = new MovieClipLoader();        
        maskLdr.addListener( {
            onLoadComplete: finish
        } );    
        maskLdr.loadClip(maskPath, maskMC); 
        
        imageCount++;
    }
    //
    //
    public function onImageDone() { 
        trace("image completely loaded");
    }     
    // 
    // applies image "processing" 
    // 
    public function finish() { 
        trace("mask completely loaded"); 
        trace("imgMC._name: " + imgMC._name);    // "imgMC._name: image_0"
        trace("maskMC._name: " + maskMC._name);  // "maskMC._name: mask_0"
        imgMC.setMask(maskMC);
        maskMC.blendMode = 3; 
    } 
} 


Ob letztlich das hier etwas bringt, wage ich zu bezweifeln:

PHP-Code:

imgMC.setMask(maskMC);
maskMC.blendMode = 3; 


Wenn Du etwas zu einer Maske machst wird es unsichtbar, weshalb es keinerlei Auswirkungen haben dürfte, wenn Du dann einen Blendmode zuweist.

[twietee]

Hallo Martin!

...und vielen Dank für deine Antwort!

Leider funktioniert das Snippet so nicht... Mal ein paar Fragen/Kommentare:

Zitat von Martin Kraft

Wenn Du Funktionen übergibst darfst Du sie nicht ausführen. Also:

PHP-Code:

var test;
var testFunc = function(){
   return "testReturn";
}

// nicht
test = testFunc;
trace(test); // enthält jetzt den String "testReturn"

// sondern
test = testFunc;
trace(test); // enthält jetzt die Function 


bei //nicht meintest du test = testFunc() richtig? Also mit Klammern funktioniert es nicht?!

Das Problem hier ist, dass ohne ein Übergeben von this die Klasse die "Referenz auf sich selbst" vergisst, also alle initiierten Variablen und Objekte nach dem Laden des ersten Bildes futsch sind...

Zitat von Martin Kraft

Außerdem solltest Du den Masken-Listener nicht erst hinzufügen, wenn das Bild schon geladen wurde. Denn dann ist die Maske warscheinlich auch schon geladen und der Listener wird nie ausgeführt.

Die Idee war ja gerade, erst das Bild zu laden, dann die Maske zu laden, und nach Abschluss beider Sachen, die Maske zu setzen, weil eine Maske nicht auf nicht-fertig-geladene Objekte angewendet werden kann... und, soweit ich das verstanden hab, werden die callbacks auf z.B. onLoadInit immer ausgeführt, wenn die Ereignisse eintreten... es sollte also nicht passieren, dass ein Listener nie ausgeführt wird! Oder irre ich mich

Und im Debugger sehe ich, dass -- in der Version von mir -- "alles" ausgeführt und nur die Maske nicht angewendet wird. Meine Vermutung!!! ist, dass die Bilder zu spät gezeichnet werden... ...und das in der Klassenlogik geändert werden muss...

Zitat von Martin Kraft

Ich hab die Klasse mal etwas umstrukturiert...

Vielen Dank für die Arbeit, die du dir gemacht hast!
Leider kann mein Compiler nichts mit diesen Statements anfangen:

PHP-Code:

 maskLdr.addListener( {
            onLoadComplete: finish;
        } ); 


...ist das AS 3.0 Syntax? Ich bin nämlich noch auf AS 2.0 / Flash 8.

Zitat von Martin Kraft

Ob letztlich das hier etwas bringt, wage ich zu bezweifeln:

PHP-Code:

imgMC.setMask(maskMC);
maskMC.blendMode = 3; 


Wenn Du etwas zu einer Maske machst wird es unsichtbar, weshalb es keinerlei Auswirkungen haben dürfte, wenn Du dann einen Blendmode zuweist.

Das ist nur noch ein Überbleibsel von Verzweiflungstests -- du hast aber natürlich vollkommen Recht!

Danke + Gruss,
T

[ING]

Zitat von twietee

Das Problem hier ist, dass ohne ein Übergeben von this die Klasse die "Referenz auf sich selbst" vergisst, also alle initiierten Variablen und Objekte nach dem Laden des ersten Bildes futsch sind...

du könntest auch hundekotze übergeben und es würde genau so laufen problem ist das das event im scope des loaders gefeuert wird, du befindest dich also noch im loader, deshalb kannste auf die klasseneigenschaften nicht mehr zugreifen. wie man das in as2 jetzt richtig löst weiß ich aber auch nicht.

Zitat von twietee

Und im Debugger sehe ich, dass -- in der Version von mir -- "alles" ausgeführt und nur die Maske nicht angewendet wird. Meine Vermutung!!! ist, dass die Bilder zu spät gezeichnet werden... ...und das in der Klassenlogik geändert werden muss...

nein, das problem ist das das alles sofort ausgeführt wird weil, wie schon3 mal erwähnt, du die funktion mit klammern sofort ausführst ohne zu warten, die reihenfolge stimmt natürlich weil die klassenlogik an sich schon richtig ist.

lass dir mal per trace das callback des loader ausgeben, ich wette es ist undefined. statt den mc referenzen lass dir mal deren größe ausgeben, ist garantiert auch 0

[Martin Kraft]

Zitat von ING

du könntest auch hundekotze übergeben ...

Einen Versuch wärs Wert

Im Ernst: Ich hatte diese ganze Scope-Kacke in AS2 schon verdrängt.

Habe Deine Klasse mal entsprechend angepasst:

PHP-Code:

// 
// call: 
// meinMaskiertesBild = new DynamicMaskedImage("imagePath", "maskPath", targetMC); 
// 
class DynamicMaskedImage { 
    
    public static var imageCount:Number = 0;
    
    public var imgMC:MovieClip; 
    public var maskMC:MovieClip;
    
    public var imgLdr:MovieClipLoader; 
    public var maskLdr:MovieClipLoader;
    
    public var loadCount:Number = 0;
    
    // 
    // constructor 
    //
    public function DynamicMaskedImage(imgPath:String, maskPath:String, target:MovieClip) {
        
        var listener:Object = {
            scope: this,
            onLoadComplete: function() {
                this.scope.loadCount++;
                if( this.scope.loadCount>=2 ) this.scope.showFinished();
            }
        }        
        
        imgMC      = target.createEmptyMovieClip("image_" + imageCount, target.getNextHighestDepth());         
        imgLdr     = new MovieClipLoader();
        imgLdr.addListener( listener );
        imgLdr.loadClip(imgPath, imgMC);
        
        maskMC     = target.createEmptyMovieClip("mask_" + imageCount, target.getNextHighestDepth()); 
        maskLdr    = new MovieClipLoader();        
        maskLdr.addListener( listener );    
        maskLdr.loadClip(maskPath, maskMC); 
        
        imageCount++;
    }
    //
    //
    public function showFinished():Void {
        trace("mask completely loaded"); 
        trace("imgMC._name: " + imgMC._name);    // "imgMC._name: image_0"
        trace("maskMC._name: " + maskMC._name);  // "maskMC._name: mask_0"
        imgMC.setMask(maskMC);
        maskMC.blendMode = 3;    
    }
} 


P.S.: Oben waren ein paar Tippfehler drin - habe sie korrigiert.

[twietee]

...uiiiii, unglaublich!

Hatte ja schon fast nicht mehr dran geglaubt, aber ihr seid _großartig_ und ES FUNZT!!!

Da hätte ich auf jeden Fall noch ein paar Wochen dran geknobelt, falls ich überhaupt drauf gekommen wär!

Vielen Dank nochmal!

Gruss,
T