Countdown auf Datum mit tagen, stunden, minuten, sekunden

[zeroval]

Es ist zum Verzweifeln. Ich habe einen Countdown installiert, der auf ein bestimmtes Datum runterzählen soll. Und Flash rechnet einfach 30 Tage zuviel. Ich habe drei Scripts ausprobiert. Bei allen dasselbe Problem. Wenn ich einfach 30 Tage abziehen kann und dann sicher sein, dass er sauber runterzählt wäre alles super. Aber ich habe keinen Schimmer WIESO Flash sich um die 30 Tage verrechnet. Hier eines der 3 Scripte:

then = new Date(2011,4,13,9,0,0);
onEnterFrame = function(){
now = new Date(); 
days = (then-now)/1000/60/60/24; 
daysRound = Math.floor(days); 
hours = (then-now)/1000/60/60-(24*daysRound); 
hoursRound = Math.floor(hours); 
minutes = (then-now)/1000/60-(24*60*daysRound)-(60*hoursRound); 
minutesRound = Math.floor(minutes); 
seconds = (then-now)/1000-(24*60*60*daysRound)-(60*60*hoursRound)-(60*minutesRound); 
secondsRound = Math.round(seconds); 

if (daysRound < 10) {
	daysRound = "0"+daysRound
}

if (hoursRound < 10) {
	hoursRound = "0"+hoursRound
}

if (minutesRound < 10) {
	minutesRound = "0"+minutesRound
}

if (secondsRound < 10) {
	secondsRound = "0"+secondsRound
}

countdown = daysRound+":"+hoursRound+":"+minutesRound+":"+secondsRound;

}

Hat jemand eine Idee?

[Martin Kraft]

Ja, Flash zählt die Monate von 0 bis 11 nicht von 1 bis 12.

[zeroval]

Zitat von Martin Kraft

Ja, Flash zählt die Monate von 0 bis 11 nicht von 1 bis 12.

Hmm. Danke erst mal. Ist mir aber nicht ganz klar, wo ich jetzt diesen Monat abziehen muss. Ich kann ja nicht einfach das then-Datum einen Monat runternehmen, oder?

Ich kann ja auch nicht einfach 30 Tage abzählen, da manche Monate ja nicht genau 30 Tage zählen.

Wie ausgleichen?

[Martin Kraft]

Zitat von zeroval

Ich kann ja nicht einfach das then-Datum einen Monat runternehmen, oder?

Wieso nicht?

[zeroval]

Zitat von Martin Kraft

Wieso nicht?

Nagut, dann bau ich das mal so und hoffe in 4 Monaten kommt es gut.

Danke und Gruss, Zero

[zeroval]

Jetzt zeigt er mir einen Tag zuwenig an. Muss wohl wohl mit der variierenden Anzahl Tag in verschiedenen Monaten zu tun haben.

Wieso funktionieren denn bloss alle 3 Scripte gleichwohl nicht. Da müsste doch bereits kompensiert geworden sein?

[enky]

Vll bin ich noch nicht ganz wach, aber deine Sekunden zeigen mir sowohl 60 als auch 00 an. Das wäre pro Minute eine Sekunde zuviel, pro Stunde eine Minute zuviele, pro Tag 24min, auf 29 Tage 696min, also 11,6 Stunden.

[zeroval]

Zitat von enky

Vll bin ich noch nicht ganz wach, aber deine Sekunden zeigen mir sowohl 60 als auch 00 an.

Echt? woran siehst Du denn das?

[enky]

Mhh ich hab dein Script genommen und getestet. Die variable countdown einfach in ein textfeld ausgegeben und dann tickt das so runter bei mir


29:21:04:00
29:21:03:60
29:21:03:00

Wenn ich meine DigitalUhr trauen darf müsste das so runtergehen

29:21:04:00
29:21:03:59
29:21:03:00

[Martin Kraft]

Ich hab Dir den Code mal etwas entrümpelt und sortiert:

PHP-Code:

function generateFactors():Array {
    var a:Array = [365, 24, 60, 60, 1000];
    var b:Array = [];
    var f:Number = 1;
    for(var i = a.length - 1; i >= 0; i--){
        b[i] = f;
        f *= a[i];
    }
    return b;
};

function leadingZeros(n:Number):String{
    var str = String(n);
    while(str.length < 2) str = "0" + str;
    return str;
}

function countItDown(){
    var d:Number = then - new Date();
    
    if(d<=0){
        countdown = "finished";
        clearInterval(intervalId);
    } else {    
        var time:Array = [];
        var t:Number;
        
        for(var i=0; i < factors.length-1; i++){
            t = Math.floor( d / factors[i] );
            time.push( leadingZeros(t) );
            d -= t * factors[i];
        }
        countdown = time.join(":")
    }
    
    trace(countdown);
}

var countdown:String;
var then:Date = new Date(2011, 3, 13, 16, 52, 50);
var factors:Array = generateFactors();
var intervalId:Number = setInterval(countItDown, 1000); 


[zeroval]

Martin, Du bist der Beste. Der Ansatz mit dem interval anstatt dem onEnterFrame hat's natürlich gebracht.

Vielen Dank, allen, die mitgeholfen haben!

[hermaennchen49]

Wie kann ich die Ausgabe einrichten:
"Noch xxx Monate, xxx Tage, xxx Stunden" usw. ??

[pixelslave]

Zitat von hermaennchen49

Wie kann ich die Ausgabe einrichten:
"Noch xxx Monate, xxx Tage, xxx Stunden" usw. ??

Bitte etwas präzieser - eine Ausgabe in Flash bzw. ActionScript kann man nicht einfach so machen...

Wo soll deine Ausgabe stattfinden?
Ansonsten ist das einfach eine Zusammensetzung div. String-Elemente.

var months_left:String = calc.toString() // calc -> berechnung der verbleibenden Monate mit einem numerischen Rückgabewert
var days_left:String = calc.toString() // calc -> berechnung der verbleibenden Tage mit einem numerischen Rückgabewert
var hourss_left:String = calc.toString() // calc -> berechnung der verbleibenden Stunden mit einem numerischen Rückgabewert
var str:String = "Noch " + months_left + " Monate, "  + days_left + " Tage, " + hours_left + " Stunden"; 

Martin

[zeroval]

Zitat von hermaennchen49

Wie kann ich die Ausgabe einrichten:
"Noch xxx Monate, xxx Tage, xxx Stunden" usw. ??

countdown = "Noch "+daysRound+" Tage, "+hoursRound+" Stunden, "+minutesRound+" Minuten, "+secondsRound+" Sekunden";

[hermaennchen49]

Zitat von pixelslave

Bitte etwas präzieser - eine Ausgabe in Flash bzw. ActionScript kann man nicht einfach so machen...

Wo soll deine Ausgabe stattfinden?
Ansonsten ist das einfach eine Zusammensetzung div. String-Elemente.

Martin

Es sollte die Ausgabe in mehreren dynamischen Textfeldern (jeweils für Monate, für Tage usw.) erfolgen.