allgemeine Fragen zur Nutzung von LoadVars innerhalb "eigener" Klasse

[norn]

Hallo zusammen,

ich hätte ein paar kurze banale Fragen an euch.

Warum geht das:

...
loadvar = new LoadVars();
loadvar.onLoad = load;
loadvar.load('...');
}
    
public function load (success :Boolean) :Void {
...

aber das nicht:

...
loadvar = new LoadVars();
loadvar.onLoad = function () { load(); };
loadvar.load('...');
}
    
public function load (success :Boolean) :Void {
...

und wieso kann ich load keine Methode aufrufen:

...
loadvar = new LoadVars();
loadvar.onLoad = load;
loadvar.load('...');
}
    
public function load (success :Boolean) :Void {
finish();
....

und wie kann ich folgendes Problem lösen:

In der Methode load werden Daten aus PHP in einen Array gepackt.
Diesen Array möchte ich in mySources zurückgeben.

public var data_container :Array;
...

public function mySources () :Array {
...
loadvar = new LoadVars();
loadvar.onLoad = load;
loadvar.load('...');
...
return data_container;
}
    
public function load (success :Boolean) :Void {
...
data.container.push(...);
}

Ich würde mich sehr freuen wenn ihr mir helfen könntet.

Ich bin eigentlich Designer und kein Programmierer. Deshalb
entschuldigt die banalen Fragen.

[shorty]

Ui, ich vermute du möchtest die ganze Geschichte in eine Klasse auslagern, richtig? Am besten Du hältst dir erstmal vor augen das Actionscript asynchron abgearbeitet wird, was soviel bedeutet wie das Du auf den Inhalt deines LoadVars-Objektes erst zugreifen kannst, wenn es vollständig geladen ist. Ein ganz simples Beispiel könnte wie folg aussehen.

file: Test.as

PHP-Code:

import mx.utils.Delegate

class Test
{
    
    private var data   : Array
    private var status : String
    private var source : LoadVars
    
    /**
     * Constructor
     */
    function Test ()
    {
        data = new Array ()
        status = null
        source = new LoadVars ()
        source.onLoad = Delegate.create ( this, onLoad )
    }
    
    /**
     * oeffentlich Methoden, getter und setter
     */
    public function get result () : Array
    {
        if ( status == 'complete' )
        {
            return data
        }
        else
        {
            return null
        }
    }
    
    public function load ( url : String ) : Void
    {
        source.load ( url )
    }
    
    /**
     * private Methoden
     */
    private function onLoad ( success : Boolean ) : Void
    {
        if ( success )
        {
            trace ( 'Daten sind angekommen' )
            parseSource()
        }
        else
        {
            trace ( 'Error: 404 - file not found' )
        }
    }
    
    private function parseSource () : Void
    {
        trace ( 'Parsen lauft' )
        /**
         *
         * inhalt parsen
         *
         */
        status = 'complete'
        trace ( 'Parsen beendet, ab jetzt liefert get result einen wert' )
    }
    
} 


Instanzierung der Klasse sieht so aus

PHP-Code:

var foo : Test = new Test ()
foo.load ( 'file.txt' )
// etwas zeit verstreicht ...
trace ( foo.result ) 


Fragen zu Delegate beantwortet die Suchfunktion. Des weitern ist die Klasse, so wie sie jetzt ist nur bedingt zu gebrauchen, da du von außen ohne eine permanente Abfrage von result nie bescheid weist wann Du auf die Daten zugreifen kannst. Abhilfe schaft ein Eventlistener/dispatcher.

[norn]

Hallo Shorty,

vielen Dank für deine Hilfe.

Das klappt soweit wirklich gut. Ich habe mir die
Sache mit EventDispatcher auch angelesen, aber
so ganz habe ich nicht verstanden, wie ich ihn
hier anwenden kann.

Könntest du mir vielleicht an Hand deines Beispiels
mal zeigen, wie ich mit Hilfe des EventDispatchers
prüfen kann wann die data verfügbar ist.

Das wäre super.

[Ahrsib]

Aussagekräftige Betreffs, bitte!
Auch banale Fragen lassen sich spezifizieren.
In deinem Fall tust du es ja auch.

Ahrsib
... some kind of facility-manager.

[shorty]

@Ahrsib - thanksAndDone( )


file: Test.as incl Eventdispatcher

PHP-Code:

import mx.utils.Delegate
import mx.events.EventDispatcher

class Test
{
    
    private var data   : Array
    private var status : String
    private var source : LoadVars
     
     private var dispatchEvent     : Function
     public var addEventListener   : Function
     public var removeEventListener: Function
    
    /**
     * Constructor
     */
    function Test ()
    {
        data = new Array ()
        status = null
        source = new LoadVars ()
        source.onLoad = Delegate.create ( this, onLoad )
          EventDispatcher.initialize( this )
    }
    
    /**
     * oeffentlich Methoden, getter und setter
     */
    public function get result () : Array
    {
        if ( status == 'complete' )
            return data
        else
            return null
    }
    
    public function load ( url : String ) : Void
    {
        source.load ( url )
    }
    
    /**
     * private Methoden
     */
    private function onLoad ( success : Boolean ) : Void
    {
        if ( success )
        {
            trace ( 'Daten sind angekommen (' + unescape(source.toString()) + ')' )
            parse()
        }
        else
        {
            trace ( 'Error: 404 - file not found' )
        }
    }
    
    private function parse () : Void
    {
        trace ( 'Parsen lauft' )
        // ->
          for ( var i:String in source )
          {
              if ( i != 'onLoad' )
                      data.push( source[ i ] )
          }
          // <-
        status = 'complete'
        trace ( 'Parsen beendet, ab jetzt liefert result einen wert, und der event onResut wird getriggert ...' )
          dispatchEvent( {type:'onResult', target:this} )
    }
    
} 


timeline

PHP-Code:

var handle : Object = new Object ()
handle.onResult = function ( e : Object )
{
    trace ( '[RESULT]\t' + e.target.result )
    // oder trace ( foo.result )
}

var foo : Test = new Test ()
foo.addEventListener( 'onResult', handle )
foo.load ( 'file.txt' ) 


[shorty]

Eine weitere Möglichkeit besteht darin, die LoadVars Klasse zu erweitern.

file: Test.as extends LoadVars

PHP-Code:

import mx.events.EventDispatcher;

class Test extends LoadVars
{
    private var data:Array;
    
    private var dispatchEvent:Function;
    public var addEventListener:Function;
    public var removeEventListener:Function;

    function Test ()
    {
        super ()
        data = new Array ();
        EventDispatcher.initialize ( this );
    }

    public function get result () : Array
    {
        return data
    }

    private function onData ( raw : String ) : Void
    {
        if ( raw ) parse ( raw )
        //if ( raw ) parseAssoc ( raw )
    }
    
    /**
     * parse index based array
     */
    private function parse ( str : String ) : Void
    {
        var a:Array = str.split('&')
        for ( var i:String in a ) if ( a[i] ) data.push ( a[i].split('=')[1] )
        dispatchEvent ({type:'onResult', target:this});
    }
    
    /**
     * parse associative array
     */
    private function parseAssoc ( str : String ) : Void
    {
        var a:Array = str.split('&')
        for ( var i:String in a ) if ( a[i] ) data[ a[i].split('=')[0] ] = a[i].split('=')[1]
        dispatchEvent ({type:'onResult', target:this});
    }
} 


timeline

PHP-Code:

var handle : Object = new Object ()
handle.onResult = function ( e : Object )
{
    trace ( '[RESULT]' + e.target.result )
    // oder, um an die werte des assoziativen arrays zu gelangen:
    // -> trace ( '[RESULT]' + e.target.result.<var name> )
}

var foo : Test = new Test ()
foo.addEventListener( 'onResult', handle )
foo.load ( 'file.txt' ) 


viele Wege führen nach Rom, such Dir einfach den für dich passendsten raus


lg,
shorty

[norn]

Vielen Dank für deine Hilfe! Das klappt tip top.

[norn]

Ich habe doch nochmal 2 kurze Fragen:

class X {
   public var y;

public function X() {
   y = new Y();
} 

}

class Y {
   public var z;

public function X() {
   z = new Z();
} 

}

class Z {
....

dispatchEvent({type:onClose, target:this});

......

1.

Kann ich die Benachrichtung vom Event in Klasse Z irgendwie in Klasse X zur Verfügung bekommen?

2.

Kann ich in Klasse X eine Varibale definieren, die ich überall zur Verfügung habe, ohne sie ständig übergeben zu müssen?

Danke nochmal für eure Hilfe!