Zufalls Zitate einblenden

[sirclueless]

Hallo,

Ich habe eine Movieclip mit ca 16 Schlüsselbildern erstellt. Jedes Schlüsselbild enthält ein Zitat. Nun möchte ich das wenn das Flash gestartet wird per Zufall eines dieser 16 Zitate aus dem Movieclip langsam eingeblendet wird, dann eine gewisse Zeit lang stehen bleibt und dann wieder ausgeblendet wird. Danach soll sich das ganze wiederholen (also das nächste Zufallszitat eingeblendet werden, eine gewisse Zeit stehen bleiben und wieder ausgeblendet werden,.....usw.)

Kann mir da jemand weiterhelfen, wie ich das via Actionscript realisieren kann ??

Auf der Bühne habe ich 2 Ebenen. In der ersten liegt der Movieclip mit den Zitaten und in der zweiten habe ich nur das Actionscript.
Momentan wählt er zwar per zufall aus aber mit dem einblenden usw. weiss ich nicht wie es funktioniert :-(

gotoAndStop(1);	
mc_zitate.gotoAndStop(Math.ceil(Math.random()* mc_zitate.totalFrames));

trace(mc_zitate.currentFrame);

Kann mir jemand da bitte weiterhelfen??

[sonar]

--> verschoben. Hat nix mit AS2, geschweige denn AS3 zu tun.

[PinkDragon]

MovieClip.prototype.start = function(){
  this._alpha = 0;
  this.gotoAndStop(Math.ceil(Math.random()* this.totalFrames));
  this.onEnterFrame = fadeIn();
}
MovieClip.prototype.fadeIn = function(){
  this._alpha++;
  if(this._alpha >= 100){
    delete this.onEnterFrame;
    this.wait = 1000;
    this.onEnterFrame = show();
  }
}
MovieClip.prototype.show = function(){
  this.wait--;
  if(this.wait <= 0){
    delete this.onEnterFrame;
    this.onEnterFrame = fadeOut();
  }
}
MovieClip.prototype.fadeOut = function(){
  this._alpha--;
  if(this._alpha <= 0){
    delete this.onEnterFrame;
    this.start();
  }
}

mc_zitate.start();

Habe jetzt schon sehr lange nicht mehr mit Flash gearbeitet, aber so könnte es funktionieren. (Bin mir mit den ganzen Prototypen usw. nicht mehr ganz sicher, aber das Grundsystem ist glaube ich verständlich...)

Gruß
PD

[sirclueless]

Hmmmm !Das klingt gut und sieht gut aus mit dem Prototypen. Aber ich weiss nicht wirklich wie ich das verwenden kann und wie ich das benutzen muss. Bin leider noch ein Flashanfänger :-(
Wenn Du mir das mal in meiner Vorlage einbauen könntest und ich sehen kann wie es funktioniert, bin ich bestimmt schlauer. Oder wenn Du mir nur genau erläuterst wie ich diesen Prototypen nutzen kann. Wäre echt super.

[PinkDragon]

Ich würde es dir gerne einbauen, allerdings habe ich kein CS3
Ich weis gar nicht, ob prototypen in FLash CS3 noch aktuell sind...
Um meinen Script zu verwenden, musst du ihn nur abschreiben
Es ist aber ein kleiner Fehler drinnen, schreibe einfach statt

this.onEnterFrame = Funktion();

this.onEnterFrame = Funktion;

Also die Klammern weglassen.

Sollte das Ganze nicht funktionieren, kann ich dir später, wenn du willst, noch ne Lösung mit einer Klasse bieten.

Gruß
PD

[sirclueless]

Funktioniert leider irgendwie nicht. Der Compiler meckert weil die Methoden fadeIn,show und fadeOut nicht definiert sind.
Wie gesagt ich bin über jede Lösung froh die mein Problem lösen tut :-D

[Decrone]

moin

ich hab mal den Code (AS1) von @PinkDragon genommen und ein paar Fehler ausgemerzelt. Sollte eigentlich funktionieren. Das ganze wird zwar per Random ausgewählt aber per Random ausgewählte FrameNr. kann trotzdem doppelt hintereinander vorkommen!

MovieClip.prototype.starten = function(){
    this._alpha = 0;
    this.gotoAndStop(Math.ceil(Math.random()* this._totalframes));
    this.onEnterFrame = fadeIn;
}
MovieClip.prototype.fadeIn = function(){
    this._alpha++;
    if(this._alpha >= 100){
        delete this.onEnterFrame;
        this.wait = 100;
        this.onEnterFrame = shows;
    }
}
MovieClip.prototype.shows = function(){
    this.wait--;
    if(this.wait <= 0){
        delete this.onEnterFrame;
         this.onEnterFrame = fadeOut;
    }
}
MovieClip.prototype.fadeOut = function(){
    this._alpha--;
    if(this._alpha <= 0){
        delete this.onEnterFrame;
        this.starten();
    }
}
 
this.mc_zitate.starten(); 

Gruss Dec

[sirclueless]

Danke für die Hilfe. Bekomme aber immer folgende Fehlermeldung im Compiler und die Zitate laufen ganz schnell nacheinander durch ohne einblenden und sonstiges :-( :

1120: Zugriff auf eine nicht definierte Eigenschaft fadeIn.
1120: Zugriff auf eine nicht definierte Eigenschaft shows.
1120: Zugriff auf eine nicht definierte Eigenschaft fadeOut.

Weiss nicht was ich falsch mac he ! Habe Deinen Code in das erste Bild kopiert und es funktioniert leider nicht. Was mache ich falsch ???

[PinkDragon]

Hmm... dann ist Flash CS3 wohl noch etwas strenger. Probier es mal so:

MovieClip.prototype.starten = function(){
  this._alpha = 0;
  this.gotoAndStop(Math.ceil(Math.random()* this._totalframes));
  this.onEnterFrame = this.fadeIn;
}
MovieClip.prototype.fadeIn = function(){
  this._alpha++;
  if(this._alpha >= 100){
    delete this.onEnterFrame;
    this.wait = 100;
    this.onEnterFrame = this.show;
  }
}
MovieClip.prototype.show = function(){
  this.wait--;
  if(this.wait <= 0){
    delete this.onEnterFrame;
    this.onEnterFrame = this.fadeOut;
  }
}
MovieClip.prototype.fadeOut = function(){
  this._alpha--;
  if(this._alpha <= 0){
    delete this.onEnterFrame;
    this.starten();
  }
}

mc_zitate.starten();

Müsste eigendlich gehen. (Ist nur Decrones Code mit ner kleinen Änderung...)

Gruß
PD

[Decrone]

ansonsten, wenn das mit dem Beispiel von @PinkDragon nicht klappen sollte, dann versuch dieses Skript mal und zur Sicherheit den in Flash8 abgespeicherten Anhang.

PHP-Code:

var framesArr:Array = new Array();

function arr(){
    for(var i=1; i<mc_zitate._totalframes+1; i++){
        framesArr.push(i);
    }
};

function starten(pObj:MovieClip){
      pObj._alpha = 0;
    if(framesArr.length ==  0){
        arr();
        trace("Array gefüllt");
    }
    var frameauswahl:Number = random(framesArr.length);
    trace("Der Inhalt der Array ist: "+framesArr+ " und die Arraylänge ist: "+framesArr.length);
    trace("Per random ausgewählte Index Nr ist: "+frameauswahl+" \nund der Inhalt dieser IndexNr. ist: "+framesArr[frameauswahl]+ " also Frame"+framesArr[frameauswahl]+" wurde ausgewählt\n");
    pObj.gotoAndStop(framesArr[frameauswahl]);
      fadeIn(pObj);
    framesArr.splice(frameauswahl, 1);
};

function fadeIn(pObj:MovieClip){
    pObj.onEnterFrame = function(){
          this._alpha++;
          if(this._alpha >= 100){
            delete this.onEnterFrame;
            this.wait = 100;
            shows(this);
        }
      }
};

function shows(pObj:MovieClip){
    pObj.onEnterFrame = function(){
          this.wait--;
          if(this.wait <= 0){
            delete this.onEnterFrame;
                fadeOut(pObj);
        }
      }
};

function fadeOut(pObj:MovieClip){
    pObj.onEnterFrame = function(){
        this._alpha--;
        if(this._alpha <= 0){
            delete this.onEnterFrame;
            starten(this);
        }
      }
};

starten(mc_zitate); 


Ach übrigends, es wird jetzt auch nicht mehr doppelt abgespielt. Und die trace Ausgabe ist nur zum bessern Verständnis gedacht! Kannste also löschen!

Gruss Dec

[sonar]

Zitat von sirclueless

Danke für die Hilfe. Bekomme aber immer folgende Fehlermeldung im Compiler und die Zitate laufen ganz schnell nacheinander durch ohne einblenden und sonstiges :-( :

1120: Zugriff auf eine nicht definierte Eigenschaft fadeIn.
1120: Zugriff auf eine nicht definierte Eigenschaft shows.
1120: Zugriff auf eine nicht definierte Eigenschaft fadeOut.

Dann stell bitte nicht 'ActionScript 3.0' in den Einstellungen für deine FLA ein, wenn du schon "clueless" bist...

[Decrone]

jep Sonar recht geben müssen

so und hier nochmal die Variante mit setInterval gesteuert und leicht entrümpelt

PHP-Code:

var framesArr:Array = new Array();
var id:Number;

function arr(){
    for(var i=1; i<mc_zitate._totalframes+1; i++){
        framesArr.push(i);
    }
};

function starten(pObj:MovieClip, pTime:Number){
      pObj._alpha = 0;
    if(framesArr.length ==  0){
        arr();
    }
    var frameauswahl:Number = random(framesArr.length);
    pObj.gotoAndStop(framesArr[frameauswahl]);
      fadeIn(pObj, pTime);
    framesArr.splice(frameauswahl, 1);
};

function fadeIn(pObj:MovieClip, pTime:Number){
    pObj.onEnterFrame = function(){
          this._alpha++;
          if(this._alpha >= 100){
            delete this.onEnterFrame;
            id = setInterval(shows, pTime, pObj); 
        }
      }
};

function shows(pObj:MovieClip){
    clearInterval(id);
    fadeOut(pObj);    
};

function fadeOut(pObj:MovieClip){
    pObj.onEnterFrame = function(){
        this._alpha--;
        if(this._alpha <= 0){
            delete this.onEnterFrame;
            starten(this);
        }
      }
};

starten(mc_zitate, 2000);//2000 Millisekunden = 2 Sekunden lesepause 


Gruss Dec

[sirclueless]

JA das war der Fehler ! Hatte Actionscript 3 eingestellt :-(
Bin wirklich Clueless ;-)


Aber das Beispiel hier oben drüber hat noch nen Fehler. Das erste Zitat wird eingeblendet und ausgeblendet. Super. Dann das zweite Zitat wird eingeblendet und bleibt stehen und nichts passiert mehr :-/ Weiss gar net woran das liegen kann.

[Decrone]

upps

hatte vergessen in der Funktion (FadeOut) einen zusätzlichen Parameter mit zu übergeben und die Funktion (shows) hab ich auch entfernt, die brauchen wir ja wirklich nicht! Der Fehler lag aber an der Parameterübergabe.
Jetzt sollte es aber loopen

PHP-Code:

var framesArr:Array = new Array(); 
var id:Number; 

function arr(){ 
    for(var i=1; i<mc_zitate._totalframes+1; i++){ 
        framesArr.push(i); 
    } 
}; 

function starten(pObj:MovieClip, pTime:Number){ 
    pObj._alpha = 0; 
    if(framesArr.length ==  0){ 
        arr(); 
    } 
    var frameauswahl:Number = random(framesArr.length); 
    pObj.gotoAndStop(framesArr[frameauswahl]); 
     fadeIn(pObj, pTime); 
    framesArr.splice(frameauswahl, 1); 
}; 

function fadeIn(pObj:MovieClip, pTime:Number){ 
    pObj.onEnterFrame = function(){ 
        this._alpha++; 
        if(this._alpha >= 100){ 
            delete this.onEnterFrame; 
            id = setInterval(fadeOut, pTime, this, pTime); 
        } 
    } 
}; 

function fadeOut(pObj:MovieClip, pTime:Number){ 
    clearInterval(id);
    pObj.onEnterFrame = function(){ 
        this._alpha--; 
        if(this._alpha <= 0){ 
            delete this.onEnterFrame; 
            starten(this, pTime); 
        } 
      } 
}; 

starten(mc_zitate, 2000);//2000 Millisekunden = 2 Sekunden lesepause 


Gruss Dec

[sirclueless]

Danke !! Vielen Dank.