zufällig...

[holozän]

Ich muss nochmal mein "Problemchen" ins Forum werfen.
Komme auf keine richtige Lösung und brauch dringend HIIIIILLLLFFEEEEE!

Ich hab 144 Objekte (oder vielleicht besser: Instanzen?).
Per ZUFALL sollen jede Sekunde ZWEI Objekte ausgewählt werden, die dann ihre POSITION tauschen. (Also, zum Beispiel: Obj34 kommt auf Position von Obj72 - und Obj72 auf die Position von Obj34.

Danach geht es automatisch weiter: das nächste Paar. Usw.,usw.

Da wird also nix gelöscht, es werden nur zufällige Paare automatisch (unendlich) ausgetauscht.

Gestartet wir wohl mit: "onClipEvent (enterFrame)... ?
Dann das Array mit den Objekten... mir fehlt der Plan!

Hoffe, das ist einigermaßen verständlich erklärt???

Für nen richtigen Fläsher ist das bestimmt supereasy... oder?

[nullidee]

bitte keine Doppelposts, zeig lieber mal ein .fla, dann macht das vielleicht jemand. Hier gehts weiter.......

Wie der Zufall so will...

[lasic+]

Schreib dir eine Funktion, die den Tausch von zwei random-Objekten vornimmt, dann rufste diese funktion mit setInterval jede sekunde auf...

[:: RK ::]

hi,

hab da mal was gebastelt, vielleicht hilfts dir ja
einfach ins erste Frame kopieren und testen.

this.createEmptyMovieClip("mcContainer", 1);
 tl = this.mcContainer;
 tl._y = 20;
 tl._x = 20;
 //
 MovieClip.prototype.drawBox = function(col, w, h, txt) {
     this.clear();
     this.moveTo(0, 0);
     this.beginFill(col, 100);
     this.lineTo(w, 0);
     this.lineTo(w, h);
     this.lineTo(0, h);
     this.lineTo(0, 0);
     this.endFill();
     this.createTextField("txtNum", 2, 0, 17, 50, 16);
     this.txtNum.text = txt;
 };
 //
 MovieClip.prototype.moveMc = function(targetX, targetY) {
     this.onEnterFrame = function() {
         if ((this._x != targetX) || (this._y != targetY)) {
             if ((this._x>targetX) || (this._y>targetY)) {
                 this._x += Math.floor((targetX-this._x)/8);
                 this._y += Math.floor((targetY-this._y)/8);
             }
             if ((this._x<targetX) || (this._y<targetY)) {
                 this._x += Math.ceil((targetX-this._x)/8);
                 this._y += Math.ceil((targetY-this._y)/8);
             }
         } else {
             delete this.onEnterFrame;
         }
     };
 };
 //
 fncInit = function () {
     for (i=0; i<100; i++) {
         tl.createEmptyMovieClip("mc"+i, i);
         o = tl["mc"+i];
         o.drawBox("0x000000", 50, 50, i);
         o._alpha = 20;
         o._x = (i%10)*(o._width+1);
         o._y = Math.floor(i/10)*(o._height+1);
         o.i = i;
 
     }
     ti = setInterval(function () {
         rN = random(100);
         rN2 = random(100);
         obj1 = [tl["mc"+rN], tl["mc"+rN]._x, tl["mc"+rN]._y];
         obj2 = [tl["mc"+rN2], tl["mc"+rN2]._x, tl["mc"+rN2]._y];
         trace(obj1);
         trace(obj2);
         trace("");
         obj1[0].drawBox("0xFF0000", 50, 50, obj1[0].i);
         obj2[0].drawBox("0xFF0000", 50, 50, obj2[0].i);
         obj1[0].moveMc(obj2[1], obj2[2]);
         obj2[0].moveMc(obj1[1], obj1[2]);
     }, 1000);
 };
 //
 fncInit(); 

[holozän]

Hi ::RK::!

Na da bin ich jetzt gespannt... wenn das klappt spring ich vor Freude an die Decke!
Melde mich wieder,
Grüße von Holozän

[holozän]

Ja, so hab ichs mir gedacht. Nur (doooofe Frage) wie bekomm ich meine Buchstaben bzw. Bildchen in die mcs rein (anstelle der Nummerierung) ???

D.h. ich muss die mcs ja selber erstellen, auf der Bühne platzieren, benennen und in ein Array packen usw. (rein theoretisch hab ichs jetzt geschnallt)... nur die Praxis...?

Wie bastel ich das jetzt in Dein geniales Script rein??? Puh...
Für den letzten kleinen Tip wär ich noch dankbar!

[:: RK ::]

wenn du deinen von hand erstellten MCs eine fotlaufende nummer gibts, also
so wie meins (mc0 ... mc99) dann brauchst kein Array mit den ganzen
instanznamen anzulegen, pack dir einfach das folgendes script und passe die
instanzbezeichnung und den Pfad zu den MCs an.

tl is der Pfad zu deinem ContainerMC, da wo alle anderen drin sind, hast du
keinen kann nimm "this".

tl["mc"+rN] hier musst du lediglich den Prefix, also das vor der fortlaufenden
nummer im Instanznamen anpassen, anstelle von "mc" schreibst du deins rein.

tl = deinContainerMC
  //
  MovieClip.prototype.moveMc = function(targetX, targetY) {
       this.onEnterFrame = function() {
           if ((this._x != targetX) || (this._y != targetY)) {
               if ((this._x>targetX) || (this._y>targetY)) {
                   this._x += Math.floor((targetX-this._x)/8);
                   this._y += Math.floor((targetY-this._y)/8);
               }
               if ((this._x<targetX) || (this._y<targetY)) {
                   this._x += Math.ceil((targetX-this._x)/8);
                   this._y += Math.ceil((targetY-this._y)/8);
               }
           } else {
               delete this.onEnterFrame;
           }
       };
  };
  //
  fncInit = function () {
       ti = setInterval(function () {
           rN = random(100); // die Zahl 100 musst du an die Anzahl der MCs anpassen
           rN2 = random(100);// die Zahl 100 musst du an die Anzahl der MCs anpassen
           obj1 = [tl["mc"+rN], tl["mc"+rN]._x, tl["mc"+rN]._y];
           obj2 = [tl["mc"+rN2], tl["mc"+rN2]._x, tl["mc"+rN2]._y];
           //
           obj1[0].moveMc(obj2[1], obj2[2]);
           obj2[0].moveMc(obj1[1], obj1[2]);
       }, 1000); // hier kannste die zeit einstellen, in MilliSec
  };
  //
  fncInit(); 

probier des mal

[holozän]

Danke ::RK:: !
Ich versuchs gleich mal!

Danke schonmal im Voraus!
melde mich dann aber nochmal...
Holozän

[holozän]

Hallo ::RK:: !
Natürlich auch an alle Anderen...

Muss zugeben, ich kriegs nicht ganz hin.
Wie weise ich meine mcs an, in den "Container" zu springen?

Was müsste ich denn da vor das Script (s.o.) noch hinzusetzen, damit das fluppt.

Für ein Beispiel würden ja schon 4 mcs genügen; dann kapier ich es vielleicht.

Das war so schön in der ersten Version mit der Transparenz und den abgebremsten Bewegungen... jetzt bin ich soooo gespannt, obs auch mit meinen mcs geht?

Darf ich nochmal um ne Hilfe bitten?
Grüße von Holozän

[:: RK ::]

hi,

hier mal n kleines Bsp. mit 4 MC (mc0 ... mc3), alle 4 sind in dem mcContainer.
die hab ich da von hand reingemacht, da is nichts mit "reinspringen"

habs dir als MX Version absgespeichert.

[pokepika]

ich hab noch einen mehr oder weniger bug gefunden. wenn ein Mc 2mal hintereinander bewegt wird, und die erste bewegung noch nicht beendet ist, dann stimmt die end-position nicht mehr.
Hier ein kleiner bugfix:

tl = deinContainerMC;
//
MovieClip.prototype.moveMc = function(targetX, targetY) {
    if( this.move != true )
    {
        this.move = true;
        this.onEnterFrame = function() {
            if ((this._x != targetX) || (this._y != targetY)) {
                if ((this._x>targetX) || (this._y>targetY)) {
                    this._x += Math.floor((targetX-this._x)/8);
                    this._y += Math.floor((targetY-this._y)/8);
                }
                if ((this._x<targetX) || (this._y<targetY)) {
                    this._x += Math.ceil((targetX-this._x)/8);
                    this._y += Math.ceil((targetY-this._y)/8);
                }
            } else {
                delete this.onEnterFrame;
                this.move = false;
            }
        };
    }
};
 
fncInit = function () {
     ti = setInterval(function () {
         anzahl = 100 // Hier Anzahl der MCs anpassen
 
         rN = random(anzahl);
         rN2 = random(anzahl);
         while ( tl["mc"+rN].move == true )
         {
             rN = random(anzahl);
         }
         while ( tl["mc"+rN2].move == true || rN == rN2 )
         {
             rN2 = random(anzahl);
         }
         
         obj1 = [tl["mc"+rN], tl["mc"+rN]._x, tl["mc"+rN]._y];
         obj2 = [tl["mc"+rN2], tl["mc"+rN2]._x, tl["mc"+rN2]._y];
 
         obj1[0].moveMc(obj2[1], obj2[2]);
         obj2[0].moveMc(obj1[1], obj1[2]);
     }, 1000); // Zeit in Millisekunden
};
 
fncInit(); 

[:: RK ::]

ah, genau, hatt ich ja ganz vergessen, danke

[holozän]

Hallo zusammen,
hab mich echt über Eure scripts gefreut. Werde sie gleich mal ausprobieren. Würde Euch ja gerne auch ma n script schreiben, aber ich glaub das dauert nochn Weilchen... bis ich da durchblicke.
Grüße von Holozän
(wie der "Name" schon sagt... hinke noch was hinten an)

[holozän]

Hallo zusammen!!!
Ich hab n ganz doooofes Problem:
Die Anlage hier "untitled.rar" kann ich nicht auf dem Mac entkomprimieren, sprich gebrauchen...

Könnte mir einer von Euch die Datei in ne "zip" verzaubern ????

Das wär suuuper toll!!!!!!

Viele Grüße!
Holozän

[:: RK ::]

hi,

... bittschön